BZOJ 1057：[ZJOI2007]棋盘制作（最大01子矩阵+奇偶性）

                                                      [ZJOI2007]棋盘制作
                                          时间限制: 20 Sec 内存限制: 162 MB
【题目描述】
国际象棋是世界上最古老的博弈游戏之一，和中国的围棋、象棋以及日本的将棋同享盛名。据说国际象棋起源
于易经的思想，棋盘是一个8*8大小的黑白相间的方阵，对应八八六十四卦，黑白对应阴阳。而我们的主人公小Q，
正是国际象棋的狂热爱好者。作为一个顶尖高手，他已不满足于普通的棋盘与规则，于是他跟他的好朋友小W决定
将棋盘扩大以适应他们的新规则。小Q找到了一张由N*M个正方形的格子组成的矩形纸片，每个格子被涂有黑白两种
颜色之一。小Q想在这种纸中裁减一部分作为新棋盘，当然，他希望这个棋盘尽可能的大。不过小Q还没有决定是找
一个正方形的棋盘还是一个矩形的棋盘（当然，不管哪种，棋盘必须都黑白相间，即相邻的格子不同色），所以他
希望可以找到最大的正方形棋盘面积和最大的矩形棋盘面积，从而决定哪个更好一些。于是小Q找到了即将参加全
国信息学竞赛的你，你能帮助他么？
【输入】
第一行包含两个整数N和M，分别表示矩形纸片的长和宽。接下来的N行包含一个N * M的01矩阵，表示这张矩形
纸片的颜色（0表示白色，1表示黑色）。
【输出】
包含两行，每行包含一个整数。第一行为可以找到的最大正方形棋盘的面积，第二行为可以找到的最大矩形棋
盘的面积（注意正方形和矩形是可以相交或者包含的）。
【样例输入】
3 3
1 0 1
0 1 0
1 0 0
【样例输出】
4
6
【提示】
N, M ≤ 2000

分析：

我们发现，如果按题目意思直接按照黑白交替原则做很难解决，但如果转变思路，考虑第一行，我们对2，4，6，8...位置取反（0变1，1变0），这时如果奇数位置上的数与偶数位置上的数字全部相等说明实际情况下01是交错出现的，就是符合要求的棋盘的一行，对于第二行，我们对奇数位置取反，以类似方法操作，以此类推。奇数行偶数列取反，偶数行奇数列取反（其实奇奇和偶偶也行），这时，如果平面上一个矩形包含元素满足全部为0或1，它就是一个符合条件的棋盘。于是转化成了最大子矩阵问题，以0作为障碍求一次，以1作为障碍求一次，最大的矩形即为答案。

 最大正方形其实差不多，所有符合条件正方形必然包含在矩形中，只要当前矩形最小边平方就是当前正方形面积的值了。

代码：

program chess;
var
  a,maxl,minr,h,l,r:array[0..2001,0..2001]of longint;
  n,i,m,j,c,ans1,ans2:longint;
function max(x,y:longint):longint;
begin
  if x>y then max:=x else max:=y;
end;
function min(x,y:longint):longint;
begin
  if x<y then min:=x else min:=y;
end;
procedure work(c:longint);
var i,j,s:longint;
begin
  fillchar(h,sizeof(h),0); fillchar(r,sizeof(r),0); fillchar(l,sizeof(l),0);
  for i:=0 to m+1 do begin a[0,i]:=c; a[n+1,i]:=c; end;
  for i:=1 to n do
   begin
   maxl[i,0]:=0; minr[i,m+1]:=m+1;
   for j:=1 to m do
    if a[i,j]=c then maxl[i,j]:=j else maxl[i,j]:=maxl[i,j-1];
   for j:=m downto 1 do
    if a[i,j]=c then minr[i,j]:=j else minr[i,j]:=minr[i,j+1];
   end;
  for i:=1 to n+1 do
   begin
     for j:=1 to m do
      if a[i-1,j]=c then
       begin
         h[i,j]:=0; l[i,j]:=0; r[i,j]:=m+1;
       end else
       begin
         h[i,j]:=h[i-1,j]+1;
         l[i,j]:=max(l[i-1,j],maxl[i-1,j]);
         r[i,j]:=min(r[i-1,j],minr[i-1,j]);
         s:=(r[i,j]-l[i,j]-1)*h[i,j];
         if s>ans2 then ans2:=s;
         s:=sqr(min(r[i,j]-l[i,j]-1,h[i,j]));
         if s>ans1 then ans1:=s;
       end;
   end;
end;

begin
  readln(n,m);
  for i:=1 to n do begin
   for j:=1 to m do
    begin
      read(a[i,j]);
      if (i mod 2=1)and(j mod 2=0) then a[i,j]:=1-a[i,j];
      if (i mod 2=0)and(j mod 2=1) then a[i,j]:=1-a[i,j];
    end;  readln;
   end;
  work(0); work(1);
  writeln(ans1); writeln(ans2);
end.