BZOJ 1015：[JSOI2008]星球大战starwar（逆向处理+并查集）

                                                   [JSOI2008]星球大战starwar
                                                时间限制: 3 Sec 内存限制: 162 MB
【题目描述】

　　很久以前，在一个遥远的星系，一个黑暗的帝国靠着它的超级武器统治者整个星系。某一天，凭着一个偶然的
机遇，一支反抗军摧毁了帝国的超级武器，并攻下了星系中几乎所有的星球。这些星球通过特殊的以太隧道互相直
接或间接地连接。 但好景不长，很快帝国又重新造出了他的超级武器。凭借这超级武器的力量，帝国开始有计划
地摧毁反抗军占领的星球。由于星球的不断被摧毁，两个星球之间的通讯通道也开始不可靠起来。现在，反抗军首
领交给你一个任务：给出原来两个星球之间的以太隧道连通情况以及帝国打击的星球顺序，以尽量快的速度求出每
一次打击之后反抗军占据的星球的连通快的个数。（如果两个星球可以通过现存的以太通道直接或间接地连通，则
这两个星球在同一个连通块中）。

【输入】
　　输入文件第一行包含两个整数，N (1 < = N < = 2M) 和M (1 < = M < = 200,000)，分别表示星球的
数目和以太隧道的数目。星球用 0 ~ N-1的整数编号。接下来的M行，每行包括两个整数X, Y，其中（0 < = X <>
Y 表示星球x和星球y之间有“以太”隧道，可以直接通讯。接下来的一行为一个整数k，表示将遭受攻击的星球的
数目。接下来的k行，每行有一个整数，按照顺序列出了帝国军的攻击目标。这k个数互不相同，且都在0到n-1的范
围内。
【输出】
　　输出文件的第一行是开始时星球的连通块个数。接下来的N行，每行一个整数，表示经过该次打击后现存星球
的连通块个数。
【样例输入】
8 13
0 1
1 6
6 5
5 0
0 6
1 2
2 3
3 4
4 5
7 1
7 2
7 6
3 6
5
1
6
3
5
7
【样例输出】
1
1
1
2
3
3

 

分析：

如果按正常方法，先将图建好，然后依次删点，并求联通块数量肯定超时，但如果我们倒过来处理，先将所有要破坏的点全破坏，然后倒着将删除的点依次加回去，在这个过程中求联通块数量，会发现用并查集处理非常简单：当加入i节点时，找到所有与之相连的且未破坏的点，一个接一个合并，每合并一个联通块数目就减1，如果这个点与i已经在同一个联通块中，就不用减1。最后结果要加一，因为整个为一个连通块。

注意要考虑到加入的点单独构成连通块的情况。

同时不要忘了，每加入一个点，要把它在布尔数组中变为未破坏的点。

代码：

program starwar;
type
  point=^node;
    node=record
       x:longint; next:point;
    end;
var
  c:array[0..400000]of point;
  a,b,w,f,q:array[0..400000]of longint;
  g,r:array[0..400000]of boolean;
  n,i,m,k,x,y,t,s:longint; p:point;
procedure add(x,y:longint);
var p:point;
begin
  new(p); p^.x:=y; p^.next:=c[x]; c[x]:=p;
end;
function find(x:longint):longint;
var i,j,k:longint;
begin
  i:=x; j:=x;
  while i<>f[i] do i:=f[i];
  while i<>j do begin k:=f[j]; f[j]:=i; j:=k; end;
  exit(i);
end;
procedure work;
var i:longint;
begin
  fillchar(g,sizeof(g),true);
  fillchar(r,sizeof(r),false);
  for i:=0 to n-1 do f[i]:=i;
  s:=0;
end;
begin
  readln(n,m); work;
  for i:=1 to m do
  begin readln(a[i],b[i]); add(a[i],b[i]);add(b[i],a[i]); end;
  readln(k);
  for i:=1 to k do
  begin readln(w[i]); g[w[i]]:=false; end;

  for i:=1 to m do
   if (g[a[i]]=true)and(g[b[i]]=true) then
    begin
      x:=find(a[i]); y:=find(b[i]);
      f[y]:=x;
    end;

  for i:=0 to n-1 do
   if g[i]=true then
   begin x:=find(f[i]); if r[x]=false then begin inc(s); r[x]:=true; end;  end;
  for i:=k downto 1 do
   begin
     q[i]:=s;
     new(p); p:=c[w[i]]; t:=0;  g[w[i]]:=true;
     while p<>nil do
      begin
        x:=p^.x;
        if g[x]=true then
          begin
            y:=find(x); if y<>w[i] then begin inc(t); f[y]:=w[i];  end;
          end;
        p:=p^.next;
      end;
     dec(s,t-1);
   end;
  q[0]:=s;
  for i:=0 to k do writeln(q[i]);
end.