实用AutoHotkey功能展示

AutoHotkey是什么

AutoHotkey是一个自动化脚本语言。

AutoHotkey有什么用

可以让你用热键操控一切，操作电脑就像在表演魔术

我的口号

  • AutoHotkey！用过都说好！
  • AutoHotekey！无可替代！

我的部分实用AutoHotekey脚本

[仅作参考，实用需修改]

  1. Candy

  2. TC安装缷载
    详情：用Total Commander替换windos默认资源管理器

;TC安装缷载
ScrollLock::
Run,d:\Program Files\TotalCommander\TC安装缷载.ahk,d:\Program Files\TotalCommander
Return
;^ScrollLock::ScrollLock
;直接shift+scrolllock好像系统默认
  1. 使用everything搜索剪切板的内容
    Everything Windows下离不开的本地文件搜索神器
;使用everything搜索剪切板的内容
#q::
Clipboardold=%Clipboardall%
send ^c
run .\Tool\lnk\Everything.lnk -search "%Clipboard%"
/*
WinWait,ahk_class EVERYTHING ahk_exe Everything.exe,,5
ControlFocus,Edit1,ahk_class EVERYTHING
Send,^v
*/
Clipboard=%clipboardold%
return
  1. 中键映射为双击，方便打开文件夹
;中键增强－中键双击
MButton::Click,2
  1. 浏览器中中键双击页面任意地方，关闭当前页面
;Google Chrome-中键关闭
#IfWinActive ahk_class Chrome_WidgetWin_100
mbutton::send ^w
~RButton & LButton::
send ^w
Return
#ifwinactive
  1. 鼠标左键加右键 或 Alt+Capslock联网断网
    对于宽带按时长计费的我来说很方便的。
    详见：宽带连接工具[bat]
;网络连接-按键or鼠标
~LAlt & Capslock::
~Lbutton & Rbutton::
Run,.\Tool\exe\宽带连接\Run宽带连接.exe,.\Tool\exe\宽带连接
KeyWait,LAlt
KeyWait,Lbutton
return
  1. 获取窗口文字
    这个在"弹出错误信息"却无法复制时很有用
;获取窗口文字
^F9::
mousegetpos,,,nowwin
WinGetText, Outtxt , ahk_id %nowwin%
Clipboard=%outtxt%
gui,new
gui,font,s12
gui,add,edit,w300 h360,%Clipboard%
gui,show,x180 y200
traytip,,已获取`n%clipboard%
return
  1. 锁定电脑时自动关闭显示器.
~#L::  ; Win+L 热键关闭显示器.
Sleep 1500  ; 让用户有机会释放按键 (以防释放它们时再次唤醒显视器).
; 关闭显示器:
SendMessage, 0x112, 0xF170, 2,, Program Manager  ; 0x112 为 WM_SYSCOMMAND, 0xF170 为 SC_MONITORPOWER.
; 对上面命令的注释: 使用 -1 代替 2 来打开显示器.
; 使用 1 代替 2 来激活显示器的节能模式.
return
  1. 重启资源管理器
    桌面卡死时方便的重启资源管理器
;重启资源管理器
;traytip ,重启资源管理器,按下Alt+R重启资源管理器
!r::
process,close,explorer.exe
sleep 200
run explorer
winwait ,库 ahk_class CabinetWClass,,15
if not errorlevel
winclose ,库 ahk_class CabinetWClass
return
  1. 快速打开快捷方式目标路径
    win7右键有这个功能－－打开文件位置
;打开快捷方式目标路径
#j::
Clipboardold=%Clipboardall%
Send, ^c
FileGetShortcut,%Clipboard%,,lnkdir
run,%lnkdir%
Clipboard=%Clipboardold%
return
  1. 用默认浏览器打开任意链接
;快捷网址
~Numpad0 & Numpad1::run www.weather.com.cn/html/weather/
~Numpad0 & Numpad2::run http://blog.163.com/?fromNavigation
~Numpad0 & Numpad3::run http://www.zhihu.com/
  1. 在任务栏上滚动滚轮来改变系统音量
;系统
\#If MouseIsOver("ahk_class Shell_TrayWnd")
WheelUp::Send {Volume_Up}
WheelDown::Send {Volume_Down}
MouseIsOver(WinTitle) {
    MouseGetPos,,, Win
    return WinExist(WinTitle . " ahk_id " . Win)
}
\#If
  1. 任意窗口置顶
;窗口控制
!a::
MouseGetPos , , , zdwid ,  ; 得到鼠标所在位置窗口的id及控件名称
WinSet, AlwaysOnTop, toggle,ahk_id %zdwid%
WinGet,zd_pd, ExStyle,ahk_id %zdwid%
if (zd_pd & 0x8)  ; 0x8 为 WS_EX_TOPMOST
   ToolTip,窗口已置顶
Else
   ToolTip,窗口已取消置顶
sleep,3000
ToolTip
return
  1. 移除活动窗口的标题栏，获大更大视觉空间
!e::
biaotyic+=1
MouseGetPos , , , btwid ,  ; 得到鼠标所在位置窗口的id及控件名称
if biaotyic>0
{
WinSet, Style, -0xC00000,ahk_id %btwid%; 移除活动窗口的标题栏 (WS_CAPTION).
biaotyic*=-1
}
else
{
WinSet, Style, +0xC00000,ahk_id %btwid%; 恢复活动窗口的标题栏 (WS_CAPTION).
}
return
  1. 任意窗口透明化
!t::
MouseGetPos,,, MouseWin
WinGet, Transparent, Transparent, ahk_id %MouseWin%
;ToolTip Translucency:`t"%Transparent%"`nTransColor:`t%TransColor%
if Transparent!=
WinSet, TransColor, Off, ahk_id %MouseWin%
;关闭透明
else
{
MouseGetPos, MouseX, MouseY, MouseWin
PixelGetColor, MouseRGB, %MouseX%, %MouseY%, RGB
; 似乎有必要首先关闭任何现有的透明度:
WinSet, TransColor, Off, ahk_id %MouseWin%
WinSet, TransColor, %MouseRGB% 192, ahk_id %MouseWin%
}
return
  1. 热字符，快速输入词组或运行程序
;热字符串
#Hotstring EndChars `t`n
;打开文件夹
::tp::
run "D:\My Documents\My Pictures"
traytip,,Run My Picture
return
  1. 打开千千静听
::aa::
run "D:\Program Files\TTPlayer\TTPlayer.exe"
traytip,,Run Music Player
return
  1. 打开QQ
::qq::
run "D:\Program Files\Tencent\QQ\Bin\QQ.exe"
traytip,,Run QQ
return
  1. 利用CCleaner后台清理垃圾
::cc::
run C:\Program Files\CCleaner\CCleaner.exe /auto
traytip,,Run CCleaner
return
  1. 打开cmd
::cmd::
run cmd.exe,%A_desktop%\
traytip,,Run cmd
return
  1. 快速输入邮箱
::yx::
SendInput,somebody@mail.com
return
  1. 利用由 AHK 写成的飞扬魔术键盘，实现任意键盘布局
    飞扬魔术键盘 介绍
::msjp::
run .\飞扬魔术键盘\Bin\飞扬魔术键盘\飞扬魔术键盘.exe
; run .\飞扬魔术键盘\Bin\飞扬魔术键盘\飞扬魔术键盘.exe foobar
; 可用参数指定键盘风格
traytip,,Run 飞扬魔术键盘
return
  1. 切换IP地址
::ip::
run .\Tool\lnk\切换IP.lnk
traytip,,Run 切换IP
return
  1. 截屏保存为图片到文件夹[配合nircmd.exe]
;截屏
^!PrintScreen::
::jp::
run .\Tool\exe\nircmd.exe savescreenshot "D:\My Documents\My Pictures\截屏\~$currdate.yyyyMMdd$-~$currtime.HHmmss$.png"
traytip,,Run 截屏
return
  1. More ...
    　　
    　　

　　
　　
date:2014-12-13

posted @ 2014-12-13 17:18  yufenga  阅读(2586)  评论(0)  编辑  收藏  举报