STM32 —— 串口通信1 Hello Windows
STM32 —— 串口通信1 Hello Windows
实验要求
- 完成一个STM32的USART串口通讯程序（查询方式即可，暂不要求采用中断方式），要求：
（1）设置波特率为 115200，1 位停止位，无校验位
（2）STM32 系统给上位机（win10）连续发送 “hello windows！” 。win10 采用“串口助手”工具接收
- 在没有示波器条件下，可以使用 Keil 的软件仿真逻辑分析仪功能观察管脚的时序波形，更方便动态跟踪调试和定位代码故障点。 请用此功能观察串口输出波形，并分析时序状态正确与否
串口通信 Hello Windows 原理
前面，我在另一篇博客中已经介绍了一些串口通信以及 USART 的原理，这里就不在多说，直接介绍单片机串口通信的实现原理
由于实验只需要我们发送信息，并不需要进行中断，对于 STM32 实现这种串口通信的原理很简单，就是通过一个串口不断的向上位机发送信息，然后在上位机通过 USB 转 TTL 代替串口进行接受即可
HAL 库实现
配置
首先，我们同样的选择 STM32F103C8T6 芯片，然后需要配置外设晶振 RCC ，前面与流水灯步骤完全相同
在我们配置好上述步骤之后，我们需要配置 USART1 作为这次使用的串口输出，配置如下：
时钟配置如下：
代码设计
由于我们只需要发送，不需要考虑中断之类的问题，所以我们直接使用串口发送函数进行循环发送即可
普通串口发送函数官方说明如图：
发送代码如下：
uint8_t str[] = "Hello ppqppl !\r\n";
HAL_UART_Transmit(&huart1, str, sizeof(str),0xFFFF);
// 函数中的参数分别为：使用的串口(协议)，要传输的字符串，需要的空间，超时时间
注意：在 C 语言中，换行只需要 \n 即可输出回车并换行，但是在 STM32 中不同，换行需要输出回车和换行，即 \r\n
使能 USART1 全局中断
对于串口输出 Hello Windows 还有一种方法，就是使用默认中断发送函数，然后设置中断全局开启即可，设置如下：
其他设置不变，发送代码如下：
uint8_t str[] = "Hello ppqppl !\r\n";
HAL_UART_Transmit_IT(&huart1, str, sizeof(str));
这里是让 USART1 串口中断，然后通过中断发送指令取进行发送，按照实验要求，我们需要一直发送数据，但是如果我们没有上述设置，仅仅是使用中断发送指令的话，就会出现如下情况：
不断发送，单数我们看不到，数据都是存储在缓冲区，只有我们每次按下 Reset 键才能看到当前已经发送的数据，并且需要每次按下 Reset 按键才能更新上位机接受的数据
所以，需要按照上述配置，使能中断，让单片机 USART1 对应的串口一直处于中断状态，这样就能够保证上位机可以不需要按下 Reset 就能一直收到数据
重写 printf 函数
如果我们需要重写 printf 函数，达到可以通过 printf 向上位机发送数据，就要选用我们的系统内置 C 语言的库：
然后引用对应的头文件，重写 printf 函数即可
代码如下：
// 引用头文件
#include <stdio.h>
// 重写 printf 函数
// 标准库版
int fputc( int ch, FILE *f ){
USART_SendData(USART1,(u8) ch );
while(USART_GetFlagStatus(USART1,USART_FLAG_TXE)==RESET);
return ch;
}
// HAL 库版
int fputc(int ch,FILE *f)
{
uint8_t temp[1]={ch};
HAL_UART_Transmit(&huart1,(uint8_t *)&ch,1,0xFFFF); //UartHandle是串口的句柄
return ch;
}
// 寄存器版
int fputc(int ch, FILE *f)
{
while((USART1->SR&0X40)==0)
//循环发送，直到发送完毕
USART1->DR = (u8) ch;
return ch;
}
// 串口发送
printf("Hello ppqppl !\r\n")
汇编实现
这里的汇编代码引用网上最常见的一个汇编串口发送 Hello ppqppl 的程序，程序中的发送信息的位置很明显，很容易能够找到并修改发送的内容
;RCC寄存器地址映像
RCC_BASE EQU 0x40021000
RCC_CR EQU (RCC_BASE + 0x00)
RCC_CFGR EQU (RCC_BASE + 0x04)
RCC_CIR EQU (RCC_BASE + 0x08)
RCC_APB2RSTR EQU (RCC_BASE + 0x0C)
RCC_APB1RSTR EQU (RCC_BASE + 0x10)
RCC_AHBENR EQU (RCC_BASE + 0x14)
RCC_APB2ENR EQU (RCC_BASE + 0x18)
RCC_APB1ENR EQU (RCC_BASE + 0x1C)
RCC_BDCR EQU (RCC_BASE + 0x20)
RCC_CSR EQU (RCC_BASE + 0x24)
;AFIO寄存器地址映像
AFIO_BASE EQU 0x40010000
AFIO_EVCR EQU (AFIO_BASE + 0x00)
AFIO_MAPR EQU (AFIO_BASE + 0x04)
AFIO_EXTICR1 EQU (AFIO_BASE + 0x08)
AFIO_EXTICR2 EQU (AFIO_BASE + 0x0C)
AFIO_EXTICR3 EQU (AFIO_BASE + 0x10)
AFIO_EXTICR4 EQU (AFIO_BASE + 0x14)
;GPIOA寄存器地址映像
GPIOA_BASE EQU 0x40010800
GPIOA_CRL EQU (GPIOA_BASE + 0x00)
GPIOA_CRH EQU (GPIOA_BASE + 0x04)
GPIOA_IDR EQU (GPIOA_BASE + 0x08)
GPIOA_ODR EQU (GPIOA_BASE + 0x0C)
GPIOA_BSRR EQU (GPIOA_BASE + 0x10)
GPIOA_BRR EQU (GPIOA_BASE + 0x14)
GPIOA_LCKR EQU (GPIOA_BASE + 0x18)
;GPIO C口控制
GPIOC_BASE EQU 0x40011000
GPIOC_CRL EQU (GPIOC_BASE + 0x00)
GPIOC_CRH EQU (GPIOC_BASE + 0x04)
GPIOC_IDR EQU (GPIOC_BASE + 0x08)
GPIOC_ODR EQU (GPIOC_BASE + 0x0C)
GPIOC_BSRR EQU (GPIOC_BASE + 0x10)
GPIOC_BRR EQU (GPIOC_BASE + 0x14)
GPIOC_LCKR EQU (GPIOC_BASE + 0x18)
;串口1控制
USART1_BASE EQU 0x40013800
USART1_SR EQU (USART1_BASE + 0x00)
USART1_DR EQU (USART1_BASE + 0x04)
USART1_BRR EQU (USART1_BASE + 0x08)
USART1_CR1 EQU (USART1_BASE + 0x0c)
USART1_CR2 EQU (USART1_BASE + 0x10)
USART1_CR3 EQU (USART1_BASE + 0x14)
USART1_GTPR EQU (USART1_BASE + 0x18)
;NVIC寄存器地址
NVIC_BASE EQU 0xE000E000
NVIC_SETEN EQU (NVIC_BASE + 0x0010)
;SETENA寄存器阵列的起始地址
NVIC_IRQPRI EQU (NVIC_BASE + 0x0400)
;中断优先级寄存器阵列的起始地址
NVIC_VECTTBL EQU (NVIC_BASE + 0x0D08)
;向量表偏移寄存器的地址
NVIC_AIRCR EQU (NVIC_BASE + 0x0D0C)
;应用程序中断及复位控制寄存器的地址
SETENA0 EQU 0xE000E100
SETENA1 EQU 0xE000E104
;SysTick寄存器地址
SysTick_BASE EQU 0xE000E010
SYSTICKCSR EQU (SysTick_BASE + 0x00)
SYSTICKRVR EQU (SysTick_BASE + 0x04)
;FLASH缓冲寄存器地址映像
FLASH_ACR EQU 0x40022000
;SCB_BASE EQU (SCS_BASE + 0x0D00)
MSP_TOP EQU 0x20005000
;主堆栈起始值
PSP_TOP EQU 0x20004E00
;进程堆栈起始值
BitAlias_BASE EQU 0x22000000
;位带别名区起始地址
Flag1 EQU 0x20000200
b_flas EQU (BitAlias_BASE + (0x200*32) + (0*4))
;位地址
b_05s EQU (BitAlias_BASE + (0x200*32) + (1*4))
;位地址
DlyI EQU 0x20000204
DlyJ EQU 0x20000208
DlyK EQU 0x2000020C
SysTim EQU 0x20000210
;常数定义
Bit0 EQU 0x00000001
Bit1 EQU 0x00000002
Bit2 EQU 0x00000004
Bit3 EQU 0x00000008
Bit4 EQU 0x00000010
Bit5 EQU 0x00000020
Bit6 EQU 0x00000040
Bit7 EQU 0x00000080
Bit8 EQU 0x00000100
Bit9 EQU 0x00000200
Bit10 EQU 0x00000400
Bit11 EQU 0x00000800
Bit12 EQU 0x00001000
Bit13 EQU 0x00002000
Bit14 EQU 0x00004000
Bit15 EQU 0x00008000
Bit16 EQU 0x00010000
Bit17 EQU 0x00020000
Bit18 EQU 0x00040000
Bit19 EQU 0x00080000
Bit20 EQU 0x00100000
Bit21 EQU 0x00200000
Bit22 EQU 0x00400000
Bit23 EQU 0x00800000
Bit24 EQU 0x01000000
Bit25 EQU 0x02000000
Bit26 EQU 0x04000000
Bit27 EQU 0x08000000
Bit28 EQU 0x10000000
Bit29 EQU 0x20000000
Bit30 EQU 0x40000000
Bit31 EQU 0x80000000
;向量表
AREA RESET, DATA, READONLY
DCD MSP_TOP ;初始化主堆栈
DCD Start ;复位向量
DCD NMI_Handler ;NMI Handler
DCD HardFault_Handler ;Hard Fault Handler
DCD 0
DCD 0
DCD 0
DCD 0
DCD 0
DCD 0
DCD 0
DCD 0
DCD 0
DCD 0
DCD 0
DCD SysTick_Handler ;SysTick Handler
SPACE 20 ;预留空间20字节
;代码段
AREA |.text|, CODE, READONLY
;主程序开始
ENTRY
;指示程序从这里开始执行
Start
;时钟系统设置
ldr r0, =RCC_CR
ldr r1, [r0]
orr r1, #Bit16
str r1, [r0]
;开启外部晶振使能
;启动外部8M晶振
ClkOk
ldr r1, [r0]
ands r1, #Bit17
beq ClkOk
;等待外部晶振就绪
ldr r1,[r0]
orr r1,#Bit17
str r1,[r0]
;FLASH缓冲器
ldr r0, =FLASH_ACR
mov r1, #0x00000032
str r1, [r0]
;设置PLL锁相环倍率为7,HSE输入不分频
ldr r0, =RCC_CFGR
ldr r1, [r0]
orr r1, #(Bit18 :OR: Bit19 :OR: Bit20 :OR: Bit16 :OR: Bit14)
orr r1, #Bit10
str r1, [r0]
;启动PLL锁相环
ldr r0, =RCC_CR
ldr r1, [r0]
orr r1, #Bit24
str r1, [r0]
PllOk
ldr r1, [r0]
ands r1, #Bit25
beq PllOk
;选择PLL时钟作为系统时钟
ldr r0, =RCC_CFGR
ldr r1, [r0]
orr r1, #(Bit18 :OR: Bit19 :OR: Bit20 :OR: Bit16 :OR: Bit14)
orr r1, #Bit10
orr r1, #Bit1
str r1, [r0]
;其它RCC相关设置
ldr r0, =RCC_APB2ENR
mov r1, #(Bit14 :OR: Bit4 :OR: Bit2)
str r1, [r0]
;IO端口设置
ldr r0, =GPIOC_CRL
ldr r1, [r0]
orr r1, #(Bit28 :OR: Bit29)
;PC.7输出模式,最大速度50MHz
and r1, #(~Bit30 & ~Bit31)
;PC.7通用推挽输出模式
str r1, [r0]
;PA9串口0发射脚
ldr r0, =GPIOA_CRH
ldr r1, [r0]
orr r1, #(Bit4 :OR: Bit5)
;PA.9输出模式,最大速度50MHz
orr r1, #Bit7
and r1, #~Bit6
;10：复用功能推挽输出模式
str r1, [r0]
ldr r0, =USART1_BRR
mov r1, #0x271
str r1, [r0]
;配置波特率-> 115200
ldr r0, =USART1_CR1
mov r1, #0x200c
str r1, [r0]
;USART模块总使能 发送与接收使能
;71 02 00 00 2c 20 00 00
;AFIO 参数设置
;Systick 参数设置
ldr r0, =SYSTICKRVR
;Systick装初值
mov r1, #9000
str r1, [r0]
ldr r0, =SYSTICKCSR
;设定,启动Systick
mov r1, #0x03
str r1, [r0]
;NVIC
;ldr r0, =SETENA0
;mov r1, 0x00800000
;str r1, [r0]
;ldr r0, =SETENA1
;mov r1, #0x00000100
;str r1, [r0]
;切换成用户级线程序模式
ldr r0, =PSP_TOP
;初始化线程堆栈
msr psp, r0
mov r0, #3
msr control, r0
;初始化SRAM寄存器
mov r1, #0
ldr r0, =Flag1
str r1, [r0]
ldr r0, =DlyI
str r1, [r0]
ldr r0, =DlyJ
str r1, [r0]
ldr r0, =DlyK
str r1, [r0]
ldr r0, =SysTim
str r1, [r0]
;主循环
main
ldr r0, =Flag1
ldr r1, [r0]
tst r1, #Bit1
;SysTick产生0.5s,置位bit 1
beq main ;0.5s标志还没有置位
;0.5s标志已经置位
ldr r0, =b_05s
;位带操作清零0.5s标志
mov r1, #0
str r1, [r0]
bl LedFlas
mov r0, #'H'
bl send_a_char
mov r0, #'e'
bl send_a_char
mov r0, #'l'
bl send_a_char
mov r0, #'l'
bl send_a_char
mov r0, #'o'
bl send_a_char
mov r0, #' '
bl send_a_char
mov r0, #'p'
bl send_a_char
mov r0, #'p'
bl send_a_char
mov r0, #'q'
bl send_a_char
mov r0, #'p'
bl send_a_char
mov r0, #'p'
bl send_a_char
mov r0, #'l'
bl send_a_char
mov r0, #'!'
bl send_a_char
mov r0, #'\n'
bl send_a_char
b main
;子程序 串口1发送一个字符
send_a_char
push {r0 - r3}
ldr r2, =USART1_DR
str r0, [r2]
b1
ldr r2, =USART1_SR
ldr r2, [r2]
tst r2, #0x40
beq b1
;发送完成(Transmission complete)等待
pop {r0 - r3}
bx lr
;子程序 led闪烁
LedFlas
push {r0 - r3}
ldr r0, =Flag1
ldr r1, [r0]
tst r1, #Bit0
;bit0 闪烁标志位
beq ONLED ;为0 打开led灯
;为1 关闭led灯
ldr r0, =b_flas
mov r1, #0
str r1, [r0]
;闪烁标志位置为0,下一状态为打开灯
;PC.7输出0
ldr r0, =GPIOC_BRR
ldr r1, [r0]
orr r1, #Bit7
str r1, [r0]
b LedEx
ONLED
;为0 打开led灯
ldr r0, =b_flas
mov r1, #1
str r1, [r0]
;闪烁标志位置为1,下一状态为关闭灯
;PC.7输出1
ldr r0, =GPIOC_BSRR
ldr r1, [r0]
orr r1, #Bit7
str r1, [r0]
LedEx
pop {r0 - r3}
bx lr
;异常程序
NMI_Handler
bx lr
HardFault_Handler
bx lr
SysTick_Handler
ldr r0, =SysTim
ldr r1, [r0]
add r1, #1
str r1, [r0]
cmp r1, #500
bcc TickExit
mov r1, #0
str r1, [r0]
ldr r0, =b_05s
;大于等于500次 清零时钟滴答计数器 设置0.5s标志位
;位带操作置1
mov r1, #1
str r1, [r0]
TickExit
bx lr
ALIGN
;通过用零或空指令NOP填充,来使当前位置与一个指定的边界对齐
END
注意：由于单片机通过汇编程序串口通信向上位机发送的内容编码是 ASNI ，而串口测试助手只能够解析 UTF-8 和 GB18030 (中文)编码，所以接收到的单片机发送的数据是乱码
烧录
在运行串口通信相关程序的时候，Boot0、Boot1 的设置与前面流水灯程序运行时的配置有所不同，下面会给出详细讲解
Boot详解
| 启动模式选择引脚 | 启动模式 | 说明 | |
|---|---|---|---|
| BOOT1 | BOOT0 | ||
| X | 0 | 主闪存存储器 | 主闪存存储器被选为启动区域 |
| 0 | 1 | 系统存储器 | 系统存储器被选为启动区域 |
| 1 | 1 | 内置 SRAM | 内置 SRAM 被选为启动区域 |
| 1 | 0 | USART | 调用串口相关程序 |
Flash memory 启动方式
第一种方式 Boot0 = 0
启动地址：0x08000000 是 STM32 内置的 Flash，一般我们使用 JTAG 或者 SWD 模式下载程序时，就是下载到这个里面，重启后也直接从这启动程序，基本上都是采用这种模式，STM32 的 FLASH 可以擦出 10 万次，所以不用担心芯片哪天会被擦爆
System memory 启动方式
第二种方式 boot0 = 1；boot1 = 0
启动地址：0x1FFF0000 从系统存储器启动，这种模式启动的程序功能是由厂家设置的。
一般来说，这种启动方式用的比较少。系统存储器是芯片内部一块特定的区域，STM32 在出厂时，由 ST 在这个区域内部预置了一段 BootLoader， 也就是我们常说的 ISP 程序， 这是一块 ROM ，出厂后无法修改。一般来说，我们选用这种启动模式时，是为了从串口下载程序，因为在厂家提供的 BootLoader 中，提供了串口下载程序的固件，可以通过这个 BootLoader 将程序下载到系统的 Flash 中。但是这个下载方式需要以下步骤：
-
将 BOOT0 设置为 1，BOOT1 设置为 0，然后按下复位键，这样才能从系统存储器启动 BootLoader
-
最后在 BootLoader 的帮助下，通过串口下载程序到 Flash 中
-
程序下载完成后，又有需要将 BOOT0 设置为 GND ，手动复位，这样，STM32 才可以从 Flash 中启动可以看到， 利用串口下载程序还是比较的麻烦，需要跳帽跳来跳去的，非常的不注重用户体验
SRAM 启动方式
第三种方式 boot0 = 1;boot1 = 1
启动地址：0x20000000 内置 SRAM ，既然是 SRAM ，自然也就没有程序存储的能力了，这个模式一般用于程序调试。假如我只修改了代码中一个小小的 地方，然后就需要重新擦除整个 Flash ，比较的费时，可以考虑从这个模式启动代码（也就是 STM32 的内存中），用于快速的程序调试，等程序调试完成后，在将程序下载到 SRAM 中
启动地址
理论上，CM3 中规定上电后 CPU 是从 0 地址开始执行，但是这里中断向量表却被烧写在 0x0800 0000 地址里( Flash memory 启动方式)，那启动时不就找不到中断向量表了？既然 CM3 定下的规矩是从 0 地址启动，SMT32 当然不能破坏 ARM 定下的“规矩”，所以它做了一个启动映射的过程，就是和芯片上总能见到的 BOOT0 和 BOOT1 有关了，当选择从主 Flash 启动模式后，芯片一上电， Flash 的 0x0800 0000 地址被映射到 0 地址处，不影响 CM3 内核的读取，所以这时的 CM3 既可以在 0 地址处访问中断向量表，也可以在 0x0800 0000 地址处访问中断向量表，而代码还是在 0x0800 0000 地址处存储的
接线示例
运行效果
波形检测
波形显示
由于本次我们使用的标志位（目标端口）是 USART1_SR ，所以这里添加如下：
我们使用仿真运行并查看逻辑分析仪，得到波形与输出结果如下：
波形分析
实验要求是不需要使用中断，而是不断的向上位机发送 “Hello Windows！”，所以这里的波形没有上升沿和下降沿，而是全部处于低电平，这里处于哪一个电平完全取决于我们的单片机的触发方式，如果是高电平触发，就会从始至终，电平一直处于高电平状态，本人使用的是低电平触发，所以波形图一直处于低电平状态
烧录中会出现的一些问题
关于 Flash 死锁的解决办法( Flash memory 启动方式 )
开发调试过程中，由于某种原因导致内部 Flash 锁死，无法连接 SWD 以及 JTAG 调试，无法读到设备，可以通过修改 BOOT 模式重新刷写代码。修改为 BOOT0=1，BOOT1=0 即可从系统存储器启动，ST 出厂时自带 Bootloader 程序，SWD 以及 JTAG 调试接口都是专用的。重新烧写程序后，可将 BOOT 模式重新更换到 BOOT0=0，BOOT1=X 即可正常使用。
找到设备但烧录失败
有些人在使用 SWD、JTAG 或者 USB 转 TTL 等设备进行烧录的时候，可能会出现找到设备，但是烧录失败的问题，这种问题并不用担心，只需要使用 STLINK 连接好之后，清除掉单片机芯片上的内容，然后再重新进行烧录，就会解决这些的问题
