bzoj4127

肯定是树链剖分+线段树，关键是怎么维护

绝对值和这个东西显然不能简单的合并标记

因为对于负数，加之后绝对值和是变小的

那我们考虑对负数和非负数数分别维护

下面的问题就是经过操作如果负数变成了正数怎么办

注意每次加的都是正数，这意味着这样的变化最多发生n次，

每个数发生这种变化，我们就用push到底即可，这样最多nlogn的

所以我们只要在维护一个区间最大负数即可

const inf=10000000000000;
type node=record
       po,next:longint;
     end;
     link=record
       s0,s1,mx:int64;
       s:longint;
     end;

var tree:array[0..100010*4] of link;
    lazy:array[0..100010*4] of int64;
    e:array[0..100010*2] of node;
    top,fa,a,b,c,d,p,s:array[0..100010] of longint;
    t,i,x,y,ch,z,len,n,m:longint;

function max(a,b:int64):int64;
  begin
    if a>b then exit(a) else exit(b);
  end;

procedure swap(var a,b:longint);
  var c:longint;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

procedure add(x,y:longint);
  begin
    inc(len);
    e[len].po:=y;
    e[len].next:=p[x];
    p[x]:=len;
  end;

procedure dfs1(x:longint);
  var i,y:longint;
  begin
    i:=p[x];
    s[x]:=1;
    while i<>0 do
    begin
      y:=e[i].po;
      if s[y]=0 then
      begin
        fa[y]:=x;
        d[y]:=d[x]+1;
        dfs1(y);
        s[x]:=s[x]+s[y];
      end;
      i:=e[i].next;
    end;
  end;

procedure dfs2(x:longint);
  var q,i,y:longint;
  begin
    inc(t);
    c[x]:=t;
    b[t]:=x;
    i:=p[x];
    q:=0;
    while i<>0 do
    begin
      y:=e[i].po;
      if c[y]=0 then
        if s[y]>s[q] then q:=y;
      i:=e[i].next;
    end;
    if q<>0 then
    begin
      top[q]:=top[x];
      dfs2(q);
    end;
    i:=p[x];
    while i<>0 do
    begin
      y:=e[i].po;
      if c[y]=0 then
      begin
        top[y]:=y;
        dfs2(y);
      end;
      i:=e[i].next;
    end;
  end;

procedure update(i:longint);
  begin
    tree[i].s0:=tree[i*2].s0+tree[i*2+1].s0;
    tree[i].s1:=tree[i*2].s1+tree[i*2+1].s1;
    tree[i].s:=tree[i*2].s+tree[i*2+1].s;
    tree[i].mx:=max(tree[i*2].mx,tree[i*2+1].mx);
  end;

procedure build(i,l,r:longint);
  var m:longint;
  begin
    if l=r then
    begin
      if a[b[l]]>=0 then
      begin
        tree[i].s0:=a[b[l]];
        tree[i].s:=1;
        tree[i].mx:=-inf;
      end
      else begin
        tree[i].s1:=a[b[l]];
        tree[i].mx:=a[b[l]];
      end;
    end
    else begin
      m:=(l+r) shr 1;
      build(i*2,l,m);
      build(i*2+1,m+1,r);
      update(i);
    end;
  end;

procedure modi(i,len:longint; z:int64);
  begin
    inc(lazy[i],z);
    inc(tree[i].mx,z);
    inc(tree[i].s0,int64(tree[i].s)*z);
    inc(tree[i].s1,int64(len-tree[i].s)*z);
  end;

procedure push(i,l,r:longint);
  var m:longint;
  begin
    m:=(l+r) shr 1;
    modi(i*2,m-l+1,lazy[i]);
    modi(i*2+1,r-m,lazy[i]);
    lazy[i]:=0;
  end;

procedure down(i,l,r:longint);
  var m:longint;
  begin
    if l=r then
    begin
      tree[i].s0:=tree[i].mx;
      tree[i].s:=1;
      tree[i].mx:=-inf;
      tree[i].s1:=0;
    end
    else begin
      m:=(l+r) shr 1;
      if lazy[i]<>0 then push(i,l,r);
      if tree[i*2].mx>=0 then down(i*2,l,m);
      if tree[i*2+1].mx>=0 then down(i*2+1,m+1,r);
      update(i);
    end;
  end;

procedure ins(i,l,r,x,y:longint);
  var m:longint;
  begin
    if (x<=l) and (y>=r) then
    begin
      if tree[i].mx+z>=0 then
      begin
        inc(lazy[i],z);
        inc(tree[i].mx,z);
        down(i,l,r);
      end
      else modi(i,r-l+1,z);
    end
    else begin
      if lazy[i]<>0 then push(i,l,r);
      m:=(l+r) shr 1;
      if x<=m then ins(i*2,l,m,x,y);
      if y>m then ins(i*2+1,m+1,r,x,y);
      update(i);
    end;
  end;

function get(i,l,r,x,y:longint):int64;
  var m:longint;
      s:int64;

  begin
    if (x<=l) and (y>=r) then exit(tree[i].s0+abs(tree[i].s1))
    else begin
      if lazy[i]<>0 then push(i,l,r);
      m:=(l+r) shr 1;
      s:=0;
      if x<=m then s:=s+get(i*2,l,m,x,y);
      if y>m then s:=s+get(i*2+1,m+1,r,x,y);
      exit(s);
    end;
  end;

procedure work(x,y:longint);
  var f1,f2:longint;
  begin
    f1:=top[x];
    f2:=top[y];
    while f1<>f2 do
    begin
      if d[f1]>=d[f2] then
      begin
        ins(1,1,n,c[f1],c[x]);
        x:=fa[f1];
        f1:=top[x];
      end
      else begin
        ins(1,1,n,c[f2],c[y]);
        y:=fa[f2];
        f2:=top[y];
      end;
    end;
    if c[x]>c[y] then swap(x,y);
    ins(1,1,n,c[x],c[y]);
  end;

function ask(x,y:longint):int64;
  var f1,f2:longint;
  begin
    ask:=0;
    f1:=top[x];
    f2:=top[y];
    while f1<>f2 do
    begin
      if d[f1]>=d[f2] then
      begin
        ask:=ask+get(1,1,n,c[f1],c[x]);
        x:=fa[f1];
        f1:=top[x];
      end
      else begin
        ask:=ask+get(1,1,n,c[f2],c[y]);
        y:=fa[f2];
        f2:=top[y];
      end;
    end;
    if c[x]>c[y] then swap(x,y);
    ask:=ask+get(1,1,n,c[x],c[y]);
  end;


begin
  readln(n,m);
  for i:=1 to n do
    read(a[i]);
  for i:=1 to n-1 do
  begin
    readln(x,y);
    add(x,y);
    add(y,x);
  end;
  dfs1(1);
  top[1]:=1;
  dfs2(1);
  build(1,1,n);
  for i:=1 to m do
  begin
    read(ch,x,y);
    if ch=1 then
    begin
      readln(z);
      work(x,y);
    end
    else begin
      readln;
      writeln(ask(x,y));
    end;
  end;
end.