bzoj4011

好题，首先有一个结论，有向无环图的树形图数目=根节点意外入度之积

现在相当于在原图上加一条边问树形图的数目

考虑多出来不合法的方案，一定是成环且包含新加入的边

对于一条路贡献就是∏d[i] [i∉path]

考虑不属于太不和谐，我们设s=∏d[i]

贡献就是s*∏d[i]^(-1)  [i属于path]，这样我们就可以dp了

这里学到了一个新知识，就是线性求出1~p-1对于p的逆元

首先1^(-1)≡1 (mod p)

对于范围内i，有ki+r=p

则ki+r≡0 (mod p) 同乘i^(-1)*r^(-1)

有kr^(-1)+i^(-1)≡0 (mod p)

i^(-1)≡-kr^(-1) （mod p)

则i^(-1)≡-[p div i]*(p mod i)^(-1) (mod p)

这样我们就可以递推了

const mo=1000000007;

type node=record
       po,next:longint;
     end;

var q,c,d,p,f:array[0..100010] of longint;
    ni:array[0..200010] of longint;
    e:array[0..200010] of node;
    x0,y0,ans,i,len,n,m,x,y:longint;

procedure add(x,y:longint);
  begin
    inc(len);
    e[len].po:=y;
    e[len].next:=p[x];
    p[x]:=len;
  end;

procedure shaker;
  var i:longint;
  begin
    ni[1]:=1;
    for i:=2 to m+1 do
      ni[i]:=(-int64(mo div i)*int64(ni[mo mod i]) mod mo+mo) mod mo;
  end;

procedure work;
  var i,h,r,x,y:longint;
  begin
    f[y0]:=ans;
    h:=1;
    r:=0;
    for i:=1 to n do
      if d[i]=0 then
      begin
        inc(r);
        q[r]:=i;
      end;

    while h<=r do
    begin
      x:=q[h];
      f[x]:=int64(f[x])*int64(ni[c[x]]) mod mo;
      i:=p[x];
      while i<>0 do
      begin
        y:=e[i].po;
        f[y]:=(f[y]+f[x]) mod mo;
        dec(d[y]);
        if d[y]=0 then
        begin
          inc(r);
          q[r]:=y;
        end;
        i:=e[i].next;
      end;
      inc(h);
    end;
  end;

begin
  readln(n,m,x0,y0);
  for i:=1 to m do
  begin
    readln(x,y);
    add(x,y);
    inc(d[y]);
    inc(c[y]);
  end;
  shaker;
  ans:=1;
  inc(c[y0]);
  for i:=2 to n do
    ans:=int64(ans)*int64(c[i]) mod mo;
  if y0=1 then
  begin
    writeln(ans);
    halt;
  end;
  work;
  writeln((ans-f[x0]+mo) mod mo);
end.