bzoj3140

首先考虑二维的情况

min(x,y)也就意味着确定最小后，另外一维肯定打满

然后最小那个如果是k的话就相当于用k*1次——这不就是行列覆盖吗，二分图秒之

三维呢？考虑到a*b*c<=5000也就是最小的那维不超过17

那么我们直接穷举那维用哪些，然后另外的就跟二维一样了

注意要优化常数

type node=record
       po,next:longint;
     end;

var e:array[0..200010] of node;
    d:array[0..5010,1..3] of longint;
    p,cx,cy:array[0..5010] of longint;
    v:array[0..5010] of boolean;
    can,f:array[0..18] of boolean;
    x,tt,j,k,len,ans,i,t,a,b,c,a0,b0,c0:longint;

function max(a,b:longint):longint;
  begin
    if a>b then exit(a) else exit(b);
  end;

procedure add(x,y:longint);
  begin
    inc(len);
    e[len].po:=y;
    e[len].next:=p[x];
    p[x]:=len;
  end;

procedure swap(var a,b:longint);
  var c:longint;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

function dfs(x:longint):longint;
  var i,y:longint;
  begin
    i:=p[x];
    while i<>0 do
    begin
      y:=e[i].po;
      if not v[y] then
      begin
        v[y]:=true;
        if (cy[y]=-1) or (dfs(cy[y])=1) then
        begin
          cy[y]:=x;
          cx[x]:=y;
          exit(1);
        end;
      end;
      i:=e[i].next;
    end;
    exit(0);
  end;

function cal(s:longint):longint;
  var i,j:longint;
  begin
    cal:=s;
    len:=0;
    for i:=1 to b do
    begin
      p[i]:=0;
      cx[i]:=-1;
    end;
    for i:=1 to c do
      cy[i]:=-1;
    for i:=1 to t do
      if not f[d[i,a0]] then
        add(d[i,b0],d[i,c0]);
    for i:=1 to b do
      if cx[i]=-1 then
      begin
        for j:=1 to c do
          v[j]:=false;
        cal:=cal+dfs(i);
        if cal>=ans then exit;
      end;
  end;

procedure work(x,s:longint);
  var m:longint;
  begin
    if s>=ans then exit;
    if x=a+1 then
    begin
      m:=cal(s);
      if m<ans then ans:=m;
    end
    else begin
      f[x]:=false;
      work(x+1,s);
      if can[x] then
      begin
        f[x]:=true;
        work(x+1,s+1);
        f[x]:=false;
      end;
    end;
  end;

begin
  readln(tt);
  while tt>0 do
  begin
    dec(tt);
    readln(a,b,c);
    a0:=1; b0:=2; c0:=3;
    t:=0;
    for i:=1 to a do
      for j:=1 to b do
        for k:=1 to c do
        begin
          read(x);
          if x=1 then
          begin
            inc(t);
            d[t,1]:=i;
            d[t,2]:=j;
            d[t,3]:=k;
          end;
        end;
    if (b<=a) and (b<=c) then
    begin
      swap(a0,b0);
      swap(a,b);
    end
    else if (c<=a) and (c<=b) then
    begin
      swap(a0,c0);
      swap(a,c);
    end;
    if b>c then
    begin
      swap(b0,c0);
      swap(b,c);
    end;
    fillchar(can,sizeof(can),false);
    for i:=1 to t do
      can[d[i,a0]]:=true;
    ans:=0;
    for i:=1 to a do
      if can[i] then inc(ans);
    fillchar(f,sizeof(f),false);
    work(1,0);
    writeln(ans);
  end;
end.