bzoj2790

观察这道题，d(a,b) 就是先变成最大公约数然后再变成b

设g[x]表示x的质因数数目，不难得到d(a,b)=g[a/gcd(a,b)]+g[b/gcd(a,b)]

因为g[xy]=g[x]+g[y] 所以d(a,b)=g[a/gcd(a,b)]+g[b/gcd(a,b)]=g[a]+g[b]-2*g[gcd(a,b)]

g[]很明显可以用线性筛搞出来，下面考虑如何解决询问

我们发现从穷举是序列中哪个数来考虑，是无法优化的

考虑穷举约数（穷举约数是根号的复杂度，这是一个非常经典的转化）

设f[x]表示在序列中是x倍数的元素g[]最小且编号尽量小的

因为对于每个i，j不等于i，所以我们还要维护一个次优值

这一步我们可以O(n√a)的复杂度

然后我们对于每个元素，我们只要穷举约数，在这个约数是最大公约数的情况下的最优值即可

有人说，如果记录的f[x]的元素和当前询问元素的最大公约数是x的倍数而不是x怎么办

丝毫不影响，因为d(a,b)=g[a]+g[b]-2*g[gcd(a,b)]，g[ax]>=g[x] a是正整数

如果这个更新了，那到后面那个最大公约数时肯定会被再更新

const inf=1000000007;
var f,w:array[0..1000010,1..2] of longint;
    p,a,g:array[0..1000010] of longint;
    k,mx,i,t,n,j,ans:longint;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

function cmp(a1,b1,a2,b2:longint):boolean;
  begin
    if a1=a2 then exit(b1<b2);
    exit(a1<a2);
  end;

procedure work(x,i:longint);
  begin
    if cmp(g[a[i]],i,f[x,0],w[x,0]) then
    begin
      f[x,1]:=f[x,0];
      w[x,1]:=w[x,0];
      f[x,0]:=g[a[i]];
      w[x,0]:=i;
    end
    else if cmp(g[a[i]],i,f[x,1],w[x,1]) then
    begin
      f[x,1]:=g[a[i]];
      w[x,1]:=i;
    end;
  end;

procedure get(x,i:longint);
  begin
    if w[x,0]=i then
    begin
      if w[x,1]=0 then exit;
      if cmp(f[x,1]-2*g[x],w[x,1],ans,k) then
      begin
        ans:=f[x,1]-2*g[x];
        k:=w[x,1];
      end;
    end
    else if cmp(f[x,0]-2*g[x],w[x,0],ans,k) then
    begin
      ans:=f[x,0]-2*g[x];
      k:=w[x,0];
    end;
  end;

begin
  readln(n);
  for i:=1 to n do
  begin
    read(a[i]);
    if mx<a[i] then mx:=a[i];
  end;
  g[1]:=0;
  for i:=2 to mx do
  begin
    if g[i]=0 then
    begin
      g[i]:=1;
      inc(t);
      p[t]:=i;
    end;
    for j:=1 to t do
    begin
      if i*p[j]>mx then break;
      g[i*p[j]]:=g[i]+1;
      if i mod p[j]=0 then break;
    end;
  end;
  for i:=1 to mx do
  begin
    f[i,0]:=inf;
    f[i,1]:=inf;
  end;
  for i:=1 to n do
    for j:=1 to trunc(sqrt(a[i])) do
      if a[i] mod j=0 then
      begin
        work(j,i);
        if j*j<>a[i] then work(a[i] div j,i);
      end;

  for i:=1 to n do
  begin
    ans:=inf;
    k:=0;
    for j:=1 to trunc(sqrt(a[i])) do
      if a[i] mod j=0 then
      begin
        get(j,i);
        if j*j<>a[i] then get(a[i] div j,i);
      end;
    writeln(k);
  end;
end.