bzoj1109

我们设f[i]为保留第i个木块最多的符合未知数

显然f[i]=max(f[j])+1 满足i>j a[i]>a[j] i-j>=a[i]-a[j]

我们把最后一个式子变成a[i]-i<=a[j]-j

三元关系很不好弄对吧,但仔细观察可知，由最后两个式子一定可以推出i>j

那不就水了，排序树状数组即可

var f,a,b:array[0..100010] of longint;
    c:array[0..1000010] of longint;
    i,n,ans:longint;

function max(a,b:longint):longint;
  begin
    if a>b then exit(a) else exit(b);
  end;

function lowbit(x:longint):longint;
  begin
    exit(x and (-x));
  end;

procedure swap(var a,b:longint);
  var c:longint;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

procedure add(x,w:longint);
  begin
    while x<=n do
    begin
      c[x]:=max(c[x],w);
      x:=x+lowbit(x);
    end;
  end;

function ask(x:longint):longint;
  begin
    ask:=0;
    while x>0 do
    begin
      ask:=max(ask,c[x]);
      x:=x-lowbit(x);
    end;
  end;

procedure sort(l,r:longint);
  var y,i,j,x:longint;
  begin
    i:=l;
    j:=r;
    x:=a[(l+r) shr 1];
    y:=b[(l+r) shr 1];
    repeat
      while (b[i]>y) or (b[i]=y) and (a[i]<x) do inc(i);
      while (y>b[j]) or (b[j]=y) and (x<a[j]) do dec(j);
      if not(i>j) then
      begin
        swap(a[i],a[j]);
        swap(b[i],b[j]);
        inc(i);
        dec(j);
      end;
    until i>j;
    if l<j then sort(l,j);
    if i<r then sort(i,r);
  end;

begin
  readln(n);
  for i:=1 to n do
  begin
    read(a[i]);
    b[i]:=a[i]-i;
  end;
  sort(1,n);
  for i:=1 to n do
  begin
    if b[i]>0 then continue;
    f[i]:=ask(a[i]-1)+1;
    ans:=max(f[i],ans);
    add(a[i],f[i]);
  end;
  writeln(ans);
end.