bzoj3774

这算是最小割中比较难的吧

看到选取显然最小割

看到上下左右四个点我感觉肯定和染色相关

注意每个点的收益获得条件是[或]，因此我们考虑拆点i', i，分别表示通过四周控制和控制本身的代价

连边s-->i 流量为选择该点的代价； i-->i' 流量为该点的收益； i'到上下左右的j，流量为正无穷，表示另一个条件

这样，要获得收益便一定要割断一边，就满足了或的性质

注意，另一种颜色的连边与这种颜色相反，由于染色可以得到二分图

所以另一种颜色的连边反过来建即可

const inf=1000000007;
      dx:array[1..4] of longint=(0,0,-1,1);
      dy:array[1..4] of longint=(1,-1,0,0);
 
type node=record
       po,next,flow:longint;
     end;
 
var e:array[0..2000010] of node;
    numh,h,cur,p,pre,d:array[0..5010] of longint;
    a:array[0..51,0..51] of longint;
    ans,i,j,x,y,len,t,n,m,k:longint;
 
function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;
 
procedure add(x,y,f:longint);
  begin
    inc(len);
    e[len].po:=y;
    e[len].flow:=f;
    e[len].next:=p[x];
    p[x]:=len;
  end;
 
procedure build(x,y,f:longint);
  begin
    add(x,y,f);
    add(y,x,0);
  end;
 
function sap:longint;
  var i,j,u,neck,tmp,q:longint;
  begin
    for i:=0 to t do
      cur[i]:=p[i];
    sap:=0;
    u:=0;
    neck:=inf;
    numh[0]:=t+1;
    while h[0]<t+1 do
    begin
      i:=cur[u];
      d[u]:=neck;
      while i<>-1 do
      begin
        j:=e[i].po;
        if (e[i].flow>0) and (h[u]=h[j]+1) then
        begin
          neck:=min(neck,e[i].flow);
          pre[j]:=u;
          cur[u]:=i;
          u:=j;
          if u=t then
          begin
            sap:=sap+neck;
            while u<>0 do
            begin
              u:=pre[u];
              j:=cur[u];
              dec(e[j].flow,neck);
              inc(e[j xor 1].flow,neck);
            end;
            neck:=inf;
          end;
          break;
        end;
        i:=e[i].next;
      end;
      if i=-1 then
      begin
        dec(numh[h[u]]);
        if numh[h[u]]=0 then exit;
        tmp:=t;
        q:=-1;
        i:=p[u];
        while i<>-1 do
        begin
          j:=e[i].po;
          if e[i].flow>0 then
            if h[j]<tmp then
            begin
              tmp:=h[j];
              q:=i;
            end;
          i:=e[i].next;
        end;
        cur[u]:=q;
        h[u]:=tmp+1;
        inc(numh[h[u]]);
        if u<>0 then
        begin
          u:=pre[u];
          neck:=d[u];
        end;
      end;
    end;
  end;
 
begin
  len:=-1;
  fillchar(p,sizeof(p),255);
  readln(n,m);
  t:=2*n*m+1;
  for i:=1 to n do
    for j:=1 to m do
    begin
      read(x);
      inc(k); a[i,j]:=k;
      if (i+j) mod 2=1 then build(0,a[i,j],x)
      else build(a[i,j],t,x);
    end;
 
  for i:=1 to n do
    for j:=1 to m do
    begin
      read(x);
      ans:=ans+x;
      if (i+j) mod 2=1 then build(a[i,j],a[i,j]+n*m,x)
      else build(a[i,j]+n*m,a[i,j],x);
    end;
 
  for i:=1 to n do
    for j:=1 to m do
    begin
      if (i+j) mod 2=1 then
      begin
        for k:=1 to 4 do
        begin
          x:=i+dx[k];
          y:=j+dy[k];
          if (x<=0) or (x>n) or (y<=0) or (y>m) then continue;
          build(a[i,j]+n*m,a[x,y],inf);
        end;
      end
      else begin
        for k:=1 to 4 do
        begin
          x:=i+dx[k];
          y:=j+dy[k];
          if (x<=0) or (x>n) or (y<=0) or (y>m) then continue;
          build(a[x,y],a[i,j]+n*m,inf);
        end;
      end;
    end;
 
  writeln(ans-sap);
end.