bzoj3196

平衡树系列终于完结，撒花

裸的树套树，扔代码跑

const mo=20306789;
var w,b,s,key,fa:array[0..4000010] of longint;
    son:array[0..4000010,1..2] of longint;
    a,root:array[0..60010*4] of longint;
    i,n,m,x,y,k,ch,ans,t:longint;

function max(a,b:longint):longint;
  begin
    if a>b then exit(a) else exit(b);
  end;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

procedure open(x:longint);
  begin
    inc(t);
    b[t]:=x;
    w[t]:=1;  s[t]:=1;
    key[t]:=trunc(random*mo)+1;
  end;

procedure update(x:longint);
  begin
    s[x]:=s[son[x,1]]+s[son[x,2]]+w[x];
  end;

procedure rotate(i,x,w:longint);
  var y:longint;
  begin
    y:=fa[x];
    if fa[y]<>0 then
    begin
      if son[fa[y],1]=y then son[fa[y],1]:=x
      else son[fa[y],2]:=x;
    end
    else root[i]:=x;
    fa[x]:=fa[y];
    son[y,3-w]:=son[x,w];
    if son[x,w]<>0 then fa[son[x,w]]:=y;
    son[x,w]:=y;
    fa[y]:=x;
    update(y);
    update(x);
  end;

procedure up(i,x:longint);
  var y:longint;
  begin
    y:=fa[x];
    while (y<>0) and (key[y]>key[x]) do
    begin
      if son[y,1]=x then rotate(i,x,2)
      else rotate(i,x,1);
      y:=fa[x];
    end;
  end;

procedure add(i,x:longint);
  var p:longint;
  begin
    if root[i]=0 then
    begin
      open(x);
      root[i]:=t;
    end
    else begin
      p:=root[i];
      repeat
        inc(s[p]);
        if b[p]=x then
        begin
          inc(w[p]);
          exit;
        end
        else if b[p]>x then
        begin
          if son[p,1]=0 then break;
          p:=son[p,1];
        end
        else begin
          if son[p,2]=0 then break;
          p:=son[p,2];
        end;
      until false;
      open(x);
      fa[t]:=p;
      if b[p]>x then son[p,1]:=t else son[p,2]:=t;
      up(i,t);
    end;
  end;

procedure sift(i,x:longint);
  var j1,j2:longint;
  begin
    repeat
      j1:=son[x,1]; j2:=son[x,2];
      if j1+j2=0 then break;
      if (j2<>0) and ((key[j1]>key[j2]) or (j1=0)) then
      begin
        rotate(i,j2,1);
        dec(s[j2]);
      end
      else begin
        rotate(i,j1,2);
        dec(s[j1]);
      end;
    until false;
    if son[fa[x],1]=x then son[fa[x],1]:=0 else son[fa[x],2]:=0;
    fa[x]:=0; w[x]:=0; s[x]:=0;
  end;

procedure del(i,x:longint);
  var p:longint;
  begin
    p:=root[i];
    repeat
      dec(s[p]);
      if b[p]=x then
      begin
        if w[p]=1 then sift(i,p)
        else dec(w[p]);
        break;
      end
      else if b[p]>x then p:=son[p,1]
      else p:=son[p,2];
    until false;
  end;

procedure build(i,l,r,x:longint);
  var m:longint;
  begin
    add(i,a[x]);
    if l<>r then
    begin
      m:=(l+r) shr 1;
      if x<=m then build(i*2,l,m,x)
      else build(i*2+1,m+1,r,x);
    end;
  end;

procedure change(i,l,r,x,y:longint);
  var m:longint;
  begin
    add(i,y);
    del(i,a[x]);
    if l<>r then
    begin
      m:=(l+r) shr 1;
      if x<=m then change(i*2,l,m,x,y)
      else change(i*2+1,m+1,r,x,y);
    end;
  end;

function rank(i,x:longint):longint;
  var p:longint;
  begin
    p:=root[i];
    rank:=0;
    while p<>0 do
    begin
      if b[p]=x then
      begin
        rank:=rank+s[son[p,1]];
        break;
      end
      else if b[p]>x then p:=son[p,1]
      else begin
        rank:=rank+s[son[p,1]]+w[p];
        p:=son[p,2];
      end;
    end;
  end;

procedure getrank(i,l,r,k:longint);
  var m:longint;
  begin
    if (x<=l) and (y>=r) then ans:=ans+rank(i,k)
    else begin
      m:=(l+r) shr 1;
      if x<=m then getrank(i*2,l,m,k);
      if y>m then getrank(i*2+1,m+1,r,k);
    end;
  end;

function what(k:longint):longint;
  var l,r,m:longint;
  begin
    l:=0;
    r:=100000000;
    what:=0;
    while l<=r do
    begin
      m:=(l+r) shr 1;
      ans:=0; getrank(1,1,n,m);
      if ans<=k then
      begin
        what:=m;
        l:=m+1;
      end
      else r:=m-1;
    end;
  end;

procedure pre(i,x:longint);
  var p:longint;
  begin
    p:=root[i];
    while p<>0 do
    begin
      if b[p]>=x then p:=son[p,1]
      else begin
        ans:=max(ans,b[p]);
        p:=son[p,2];
      end;
    end;
  end;

procedure suffix(i,x:longint);
  var p:longint;
  begin
    p:=root[i];
    while p<>0 do
    begin
      if b[p]<=x then p:=son[p,2]
      else begin
        ans:=min(ans,b[p]);
        p:=son[p,1];
      end;
    end;
  end;

procedure askpre(i,l,r:longint);
  var m:longint;
  begin
    if (x<=l) and (y>=r) then pre(i,k)
    else begin
      m:=(l+r) shr 1;
      if x<=m then askpre(i*2,l,m);
      if y>m then askpre(i*2+1,m+1,r);
    end;
  end;

procedure asksuf(i,l,r:longint);
  var m:longint;
  begin
    if (x<=l) and (y>=r) then suffix(i,k)
    else begin
      m:=(l+r) shr 1;
      if x<=m then asksuf(i*2,l,m);
      if y>m then asksuf(i*2+1,m+1,r);
    end;
  end;

begin
  randomize;
  readln(n,m);
  for i:=1 to n do
    read(a[i]);
  for i:=1 to n do
    build(1,1,n,i);
  for i:=1 to m do
  begin
    read(ch);
    if ch=1 then
    begin
      readln(x,y,k);
      ans:=0; getrank(1,1,n,k);
      writeln(ans+1);
    end
    else if ch=2 then
    begin
      readln(x,y,k);
      writeln(what(k-1));
    end
    else if ch=3 then
    begin
      readln(x,k);
      change(1,1,n,x,k);
      a[x]:=k;
    end
    else if ch=4 then
    begin
      readln(x,y,k);
      ans:=0; askpre(1,1,n);
      writeln(ans);
    end
    else if ch=5 then
    begin
      readln(x,y,k);
      ans:=100000000; asksuf(1,1,n);
      writeln(ans);
    end;
  end;
end.