bzoj2595

一开始看是插头dp，后来发现还有一个叫斯坦纳树的东西

什么叫斯坦纳树，就是使给定点连通开销和最小的树（可以包含多余的点）

到这张平面图上，我们不难想到用dp来解决，设f[x,y,S]表示连通集合为S，树根为点(x,y)的最小开销

不难得到两个方程式

f[x,y,S]=min(f[x,y,s']+f[x,y,S-s']-a[x,y]) S'是S的一个子集，相当于合并两个数

f[x,y,S]=min(f[x',y',S]+a[x,y]) (x',y')与(x,y)相邻

由于景点很少，我们显然可以用状压dp，初始f[景点坐标，景点状态]=0

第一个方程转移大家都会，第二个方程转移是没有明确转移顺序，只要转移起点，因此我们用spfa转移

所以总的处理转移，我们穷举连通状况，然后先用第一个方程转移，然后再用第二个方程转移

const dx:array[1..4] of longint=(0,0,1,-1);
      dy:array[1..4] of longint=(1,-1,0,0);
      inf=1000000007;
type node=record
       x,y,k:longint;
     end;

var q:array[0..1000010] of node;
    pre:array[0..11,0..11,0..1025] of node;
    f:array[0..11,0..11,0..1025] of longint;
    v:array[0..11,0..11] of boolean;
    a:array[0..11,0..11] of longint;
    t,h,r,k,i,j,s,n,m,x,y:longint;

function make(i,j,k:longint):node;
  begin
    make.x:=i;
    make.y:=j;
    make.k:=k;
  end;

procedure spfa(k:longint);
  var i,x,y,x0,y0:longint;
  begin
    while h<=r do
    begin
      x0:=q[h].x; y0:=q[h].y;
      v[x0,y0]:=false;
      for i:=1 to 4 do
      begin
        x:=x0+dx[i];
        y:=y0+dy[i];
         if (x<0) or (x>n) or (y<0) or (y>m) then continue;
        if f[x,y,k]>f[x0,y0,k]+a[x,y] then
        begin
          f[x,y,k]:=f[x0,y0,k]+a[x,y];
          pre[x,y,k]:=make(x0,y0,k);
          if not v[x,y] then
          begin
            v[x,y]:=true;
            inc(r);
            q[r].x:=x; q[r].y:=y;
          end;
        end;
      end;
      inc(h);
    end;
  end;

procedure dfs(x,y,k:longint);
  var m:node;
  begin
    v[x,y]:=true;
    m:=pre[x,y,k];
    if m.x=0 then exit;
    dfs(m.x,m.y,m.k);
    if (m.x=x) and (m.y=y) then dfs(m.x,m.y,k-m.k);
  end;

begin
  readln(n,m);
  for i:=1 to n do
    for j:=1 to m do
      for k:=0 to 1024 do
        f[i,j,k]:=inf;
  for i:=1 to n do
    for j:=1 to m do
    begin
      read(a[i,j]);
      if a[i,j]=0 then
      begin
        f[i,j,1 shl t]:=0;
        inc(t);
      end;
    end;
  h:=1;
  r:=0;
  for k:=1 to 1 shl t-1 do
  begin
    for i:=1 to n do
      for j:=1 to m do
      begin
        s:=k and (k-1);
        while s<>0 do  //穷举子集
        begin
          if f[i,j,k]>f[i,j,s]+f[i,j,k-s]-a[i,j] then
          begin
            f[i,j,k]:=f[i,j,s]+f[i,j,k-s]-a[i,j];
            pre[i,j,k]:=make(i,j,s); //记录从哪转移来的
          end;
          s:=k and (s-1);
        end;
        if f[i,j,k]<inf then
        begin
          v[i,j]:=true;
          inc(r);
          q[r].x:=i; q[r].y:=j;
        end;
      end;
    spfa(k);
    h:=1;
    r:=0;
  end;
  for i:=1 to n do
    for j:=1 to m do
      if a[i,j]=0 then
      begin
        x:=i;
        y:=j;
        break;
      end;

  writeln(f[x,y,1 shl t-1]);
  dfs(x,y,1 shl t-1);
  for i:=1 to n do
  begin
    for j:=1 to m do
      if a[i,j]=0 then write('x')
      else if v[i,j] then write('o')
      else write('_');
    writeln;
  end;
end.