逆序对的相关问题：bzoj1831，bzoj2431

先从简单一点的bzoj2431入手；

n个数1~n已经限定了，所以

对于1~i-1，新加入i，最多可以增加i-1个逆序对，最少增加0个逆序对

f[i,j]表示1~i形成的序列逆序对为j的方案数

比较容易得出f[i,j]=Σf[i-1,k];

用前缀和优化即可

const mo=10000;
var f:array[0..1,0..1010] of longint;
    s:array[0..1010] of longint;
    i,j,k,n,m,p:longint;

begin
  readln(n,m);
  k:=0;
  f[0,0]:=1;
  for i:=2 to n do
  begin
    k:=1-k;
    s[0]:=f[1-k,0] mod mo;
    for j:=1 to m do
    begin
      s[j]:=(s[j-1]+f[1-k,j]) mod mo;
      f[k,j]:=0;
    end;
    for j:=0 to m do
    begin
      p:=j-i+1;
      if p<0 then p:=0;
      f[k,j]:=(s[j]-s[p]+f[1-k,p]) mod mo;
    end;
  end;
  if f[k,m]<0 then f[k,m]:=f[k,m]+mo;
  writeln(f[k,m] mod mo);
end.

然后是bzoj1831

首先我们可以先求出固定的逆序对；

然后根据贪心的思想，不难得出需要填的数是不下降的

具体证明见：http://www.cnblogs.com/htfy/archive/2012/12/11/2813497.html

令big[i,j]表示第i为数字为j时，前面有多少个比它大的

small[i,j]表示第i为数字为j时，前面有多少个比它小的

f[i,j]表示第i个-1填j最小逆序对数目

得：f[i,j]=min(f[i-1,k])+small[loc[i],j]+big[loc[i],j];

我曾经讲过对于这样的dp怎么优化，具体见程序

var c,a,b:array[0..10010] of longint;
    f,small,big:array[0..10010,0..110] of longint;
    t,n,m,i,j,ans,s:longint;

function lowbit(x:longint):longint;
  begin
    exit(x and (-x));
  end;

function ask(x:longint):longint;
  begin
    ask:=0;
    while x>0 do
    begin
      ask:=ask+c[x];
      x:=x-lowbit(x);
    end;
  end;

procedure add(x:longint);
  begin
    while x<=m do
    begin
      inc(c[x]);
      x:=x+lowbit(x);
    end;
  end;

begin
  readln(n,m);
  for i:=1 to n do
  begin
    read(a[i]);
    if a[i]=-1 then
    begin
      inc(t);
      b[t]:=i;
    end;
  end;
  for i:=n downto 1 do
  begin
    if a[i]<>-1 then
    begin
      add(a[i]);
      s:=s+ask(a[i]-1);
    end
    else begin
      for j:=1 to m do
        small[i,j]:=ask(j-1);
    end;
  end;
  fillchar(c,sizeof(c),0);
  for i:=1 to n do
  begin
    if a[i]<>-1 then add(a[i])
    else begin
      for j:=1 to m do
        big[i,j]:=ask(m)-ask(j);
    end;
  end;
  for i:=1 to t do
  begin
    f[i,1]:=f[i-1,1];
    for j:=2 to m do
      f[i,j]:=min(f[i-1,j],f[i,j-1]);   //优化
    for j:=1 to m do
      f[i,j]:=f[i,j]+big[b[i],j]+small[b[i],j];
  end;
  ans:=2147483647;
  for i:=1 to m do
    ans:=min(ans,f[t,i]);
  writeln(ans+s);
end.

总体来说，这两题不算太难，但我还是花了很多时间

1. 是做题不够认真，戒之戒之

2. 自己想出的零散的特点性质没有很好的整合，导致题目做不出来