bzoj1799

这是一道比较难的数位dp

因为逐位统计好像无法处理数位和整除原数的

但是有了刚才的bzoj1072的经验，我们能做的是逐位处理被一个数d整除的方案

不难想到先穷举数位和now，now最大也就162，可以承受

然后在统计数位和为now且能整除原数的方案

我们用f[less,i,j,k]表示第i位是否必须小于n的第i位，还有i位没处理，当前数位和为j，处理过的数位mod now余数为k的方案

然后记忆化搜索就可以了（转移见程序）

var f:array[0..1,0..20,0..170,0..170] of int64;
    a:array[0..20] of longint;
    len,t,now,i:longint;
    l,r,ans:int64;

function max(a,b:longint):longint;
  begin
    if a>b then exit(a) else exit(b);
  end;

function calc(p,i,j,k:longint):int64;
  var w,ch,s,t:longint;
      sum:int64;
  begin
    sum:=0;
    if i=0 then
      if (j=0) and (k=0) then exit(1)
      else exit(0);
    if f[p,i,j,k]<>-1 then exit(f[p,i,j,k]); //记忆化
    s:=max(0,j-9*(i-1));
    if p=0 then t:=a[i] else t:=9;
    for w:=s to t do //穷举这位的数
    begin
      if (p=0) and (w=a[i]) then ch:=0
      else ch:=1;
      sum:=sum+calc(ch,i-1,j-w,((k*10 mod now)+w) mod now); 转移
    end;
    f[p,i,j,k]:=sum;
    exit(sum);
  end;

procedure work(x:int64);
  begin
    t:=0;
    while x<>0 do
    begin
      inc(t);
      a[t]:=x mod 10;
      x:=x div 10;
    end;
  end;

function count(p:int64):int64;
  begin
    work(p);
    fillchar(f,sizeof(f),255);
    exit(calc(0,t,now,0));
  end;

begin
  readln(l,r);
  len:=trunc(ln(r)/ln(10))+1;
  for now:=1 to 162 do
  begin
    if now>len*9 then break;  //小优化
    ans:=ans+count(r)-count(l-1);
  end;
  writeln(ans);
end.