bzoj1036

树链剖分的基本题
详细介绍在http://blog.sina.com.cn/s/blog_7a1746820100wp67.html
通过树链剖分我们就可以在树上做线段树操作，完成解答

const inf=2147483647;
type node=record
       po,next:longint;
     end;
     point=record
       max,sum:longint;
     end;


var tree:array[0..120010] of point;
    size,d,fa,p,b,c,top:array[0..30010] of longint;
    w:array[0..80010] of node;
    len,i,n,m,x,y,t:longint;
    ch:char;
    s:string;

function max(a,b:longint):longint;
  begin
    if a>b then exit(a) else exit(b);
  end;

procedure update(i:longint);
  begin
    tree[i].sum:=tree[i*2].sum+tree[i*2+1].sum;
    tree[i].max:=max(tree[i*2].max,tree[i*2+1].max);
  end;

procedure swap(var a,b:longint);
  var c:longint;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

procedure add(x,y:longint);
  begin
    inc(len);
    w[len].po:=y;
    w[len].next:=p[x];
    p[x]:=len;
  end;

procedure dfs1(x:longint);  //预处理
  var i,y:longint;
  begin
    i:=p[x];
    size[x]:=1;
    while i<>0 do
    begin
      y:=w[i].po;
      if fa[x]<>y then
      begin
        fa[y]:=x;
        d[y]:=d[x]+1;
        dfs1(y);
        size[x]:=size[x]+size[y];
      end;
      i:=w[i].next;
    end;
  end;

procedure dfs2(x:longint);
  var i,y,q:longint;
  begin
    i:=p[x];
    inc(t);
    c[x]:=t;
    q:=0;
    while i<>0 do
    begin
      y:=w[i].po;
      if (c[y]=0) and (size[q]<size[y]) then q:=y;
      i:=w[i].next;
    end;
    if q<>0 then
    begin
      top[q]:=top[x];  //重儿子先访问
      dfs2(q);
    end;
    i:=p[x];  //然后访问轻儿子
    while i<>0 do
    begin
      y:=w[i].po;
      if c[y]=0 then
      begin
        top[y]:=y;
        dfs2(y);
      end;
      i:=w[i].next;
    end;
  end;

procedure build(i,l,r:longint);
  var m:longint;
  begin
    if l=r then
    begin
      tree[i].sum:=b[l];
      tree[i].max:=b[l];
    end
    else begin
      m:=(l+r) shr 1;
      build(i*2,l,m);
      build(i*2+1,m+1,r);
      update(i);
    end;
  end;

procedure add(i,l,r:longint);
  var m:longint;
  begin
    if l=r then
    begin
      tree[i].sum:=y;
      tree[i].max:=y;
    end
    else begin
      m:=(l+r) shr 1;
      if x<=m then add(i*2,l,m) else add(i*2+1,m+1,r);
      update(i);
    end;
  end;

function getmax(i,l,r,x,y:longint):longint;
  var m,t:longint;
  begin
    if (x<=l) and (y>=r) then exit(tree[i].max)
    else begin
      m:=(l+r) shr 1;
      t:=-inf;
      if x<=m then t:=max(t,getmax(i*2,l,m,x,y));
      if y>m then t:=max(t,getmax(i*2+1,m+1,r,x,y));
      exit(t);
    end;
  end;

function getsum(i,l,r,x,y:longint):longint;
  var m,t:longint;
  begin
    if (x<=l) and (y>=r) then exit(tree[i].sum)
    else begin
      m:=(l+r) shr 1;
      t:=0;
      if x<=m then t:=t+getsum(i*2,l,m,x,y);
      if y>m then t:=t+getsum(i*2+1,m+1,r,x,y);
      exit(t);
    end;
  end;

function asksum(x,y:longint):longint;
  var f1,f2:longint;
  begin
    asksum:=0;
    f1:=top[x];
    f2:=top[y];
    while f1<>f2 do
    begin
      if d[f1]>=d[f2] then
      begin
        asksum:=asksum+getsum(1,1,n,c[f1],c[x]);
        x:=fa[f1];
      end
      else begin
        asksum:=asksum+getsum(1,1,n,c[f2],c[y]);
        y:=fa[f2];
      end;
      f1:=top[x];
      f2:=top[y];
    end;
    if c[x]>c[y] then swap(x,y);
    asksum:=asksum+getsum(1,1,n,c[x],c[y]);
  end;

function askmax(x,y:longint):longint;
  var f1,f2,t:longint;
  begin
    t:=-inf;
    f1:=top[x];
    f2:=top[y];
    while f1<>f2 do  //提取
    begin
      if d[f1]>=d[f2] then
      begin
        t:=max(t,getmax(1,1,n,c[f1],c[x]));
        x:=fa[f1];
      end
      else begin
        t:=max(t,getmax(1,1,n,c[f2],c[y]));
        y:=fa[f2];
      end;
      f1:=top[x];
      f2:=top[y];
    end;
    if c[x]>c[y] then swap(x,y);
    t:=max(t,getmax(1,1,n,c[x],c[y]));
    exit(t);
  end;

begin
  readln(n);
  for i:=1 to n-1 do
  begin
    readln(x,y);
    add(x,y);
    add(y,x);
  end;
  d[1]:=1;
  dfs1(1);
  t:=0;
  top[1]:=1;
  dfs2(1);
  for i:=1 to n do
    read(b[c[i]]);
  build(1,1,n);
  readln(m);
  for i:=1 to m do
  begin
    read(ch);
    s:='';
    while ch<>' ' do
    begin
      s:=s+ch;
      read(ch);
    end;
    readln(x,y);
    if s='QMAX' then
      writeln(askmax(x,y))
    else if s='QSUM' then
      writeln(asksum(x,y))
    else if s='CHANGE' then
    begin
      x:=c[x];
      b[x]:=y;
      add(1,1,n);
    end;
  end;
end.