bzoj2006

论将区间和转化为前缀和的重要性
这题一旦转化为前缀和就非常明了了
一段区间[l,r]的美妙程度就等于s[r]-s[l-1]
对于这种无法计算出所有方案而取前k大的题目，我们一般分类别然后利用类别内的单调性用堆维护
对于以i开头的区间，显然最美的长度在[l,r]之间的区间和
显然是max(s[i+l-1~i+r-1])，设这个最美的为k
次美的就是max(max(s[i+l-1~k-1]),max(s[k+1~i+r-1]),以此类推
不难想到用ST预处理区间前缀最大值
然后用大根堆维护开头为i,末端点位置在[p,q]上的最大值，
每次取出当前堆最大值，设在k取到最大值，就将这个区间裂位[p,k-1],[k+1,q]两个区间加入堆
一共进行k次，总的复杂度大约是O(klogn+nlogn)
讲的可能不是很清楚，具体见程序吧

type node=record
       tl,tr,st,loc:longint;
       num:int64;
     end;

var heap:array[0..1000010] of node;
    d:array[0..30] of longint;
    f:array[0..500010,0..30] of longint;
    s:array[0..500010] of longint;
    n,k,l,r,i,j,x,y,t,p:longint;
    ans:int64;

function max(a,b:longint):longint;
  begin
    if s[a]>s[b] then exit(a) else exit(b);
  end;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

function ask(x,y:longint):longint;
  var k:longint;
  begin
    k:=trunc(ln(y-x+1)/ln(2));
    exit(max(f[x,k],f[y-d[k]+1,k]));
  end;

procedure insert(i,x,y:longint);
  begin
    heap[t].tl:=x;
    heap[t].tr:=y;
    heap[t].st:=i;
    heap[t].loc:=ask(x,y);
    heap[t].num:=s[heap[t].loc]-s[i-1];
  end;

procedure swap(var a,b:node);
  var c:node;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

procedure up(i:longint);
  var j:longint;
  begin
    j:=i shr 1;
    while j>0 do
    begin
      if heap[i].num>heap[j].num then
      begin
        swap(heap[i],heap[j]);
        i:=j;
        j:=i shr 1;
      end
      else break;
    end;
  end;

procedure sift(i:longint);
  var j:longint;
  begin
    j:=i shl 1;
    while j<=t do
    begin
      if (j<t) and (heap[j].num<heap[j+1].num) then inc(j);
      if heap[i].num<heap[j].num then
      begin
        swap(heap[i],heap[j]);
        i:=j;
        j:=i shl 1;
      end
      else break;
    end;
  end;

begin
  readln(n,k,l,r);
  for i:=1 to n do
  begin
    readln(x);
    s[i]:=s[i-1]+x;
    f[i,0]:=i;
  end;
  t:=trunc(ln(n)/ln(2));
  d[0]:=1;
  for i:=1 to t do
    d[i]:=d[i-1]*2;
  for j:=1 to t do
    for i:=1 to n do
      if i+d[j]-1<=n then
        f[i,j]:=max(f[i,j-1],f[i+d[j-1],j-1])
      else break;
  t:=0;
  for i:=1 to n-l+1 do
  begin
    inc(t);
    insert(i,i+l-1,min(i+r-1,n));
    up(i);
  end;
  for i:=1 to k do
  begin
    p:=heap[1].loc;
    x:=heap[1].tl;
    y:=heap[1].tr;
    j:=heap[1].st;
    ans:=ans+int64(heap[1].num);
    swap(heap[1],heap[t]);
    dec(t);
    sift(1);
    if p>x then
    begin
      inc(t);
      insert(j,x,p-1);
      up(t);
    end;
    if p<y then
    begin
      inc(t);
      insert(j,p+1,y);
      up(t);
    end;
  end;
  writeln(ans);
end.