bzoj3261

xor有一个很重要的性质就是A xor B xor B=A
所以这道题求[l,r]中p,使a[p] xor a[p+1] xor ... xor a[N] xor x 最大
就是=最大化a[1] xor ……a[n] xor x xor a[1] xor a[2] xor ……a[p-1]
令b[i]=a[1] xor a[2] xor ……a[i]
则最大化b[p] xor b[n] xor X p∈[l-1,r-1] 
抛开区间，求b[p] xor Y的最大值我们需要用到trie树
由于是区间修改，所以要求我们对trie进行可持久化
类比主席树，我们对每个i都建立一棵trie树，不同的节点增开空间
在区间询问的时候，如果两棵树指向同一个节点，说明这一位上的值是不能取的，否则就按trie的贪心做
感觉可持久化就是对历史信息尽可能的保留，对新的值新开空间

var son:array[-1..30000010,0..1] of longint;
    i,t,x,l,r,n,m:longint;
    b,root:array[-1..610000] of longint;
    ch:char;

procedure add(j,x:longint);
  var i,a,b,y:longint;
  begin
    a:=root[j-1];
    b:=root[j];
    for i:=23 downto 0 do
    begin
      y:=x and (1 shl i);
      if y>0 then y:=1;
      inc(t);
      son[b,y]:=t;  //类比主席树
      son[b,1-y]:=son[a,1-y];
      a:=son[a,y];
      b:=son[b,y];
    end;
  end;

function ask(l,r,x:longint):longint;
  var y,i,a,b:longint;
  begin
    a:=root[l];
    b:=root[r];
    ask:=0;
    for i:=23 downto 0 do
    begin
      y:=x and (1 shl i);
      if y>0 then y:=1;
      if (son[b,1-y]=0) or (son[b,1-y]=son[a,1-y]) then  //判断这位在区间内是否存在
      begin
        a:=son[a,y];
        b:=son[b,y];
      end
      else begin
        ask:=ask+1 shl i;
        a:=son[a,1-y];
        b:=son[b,1-y];
      end;
    end;
  end;

begin
  readln(n,m);
  b[0]:=0;
  t:=1;
  root[0]:=1;
  x:=1;
  for i:=23 downto 0 do
  begin
    inc(t);
    son[x,0]:=t;
    x:=t;
  end;
  for i:=1 to n do
  begin
    read(x);
    b[i]:=b[i-1] xor x;
    inc(t);
    root[i]:=t;
    add(i,b[i]);
  end;
  readln;
  for i:=1 to m do
  begin
    read(ch);
    if ch='A' then
    begin
      readln(x);
      inc(n);
      b[n]:=b[n-1] xor x;
      inc(t);
      root[n]:=t;
      add(n,b[n]);
    end
    else begin
      readln(l,r,x);
      x:=x xor b[n];
      writeln(ask(l-2,r-1,x));
    end;
  end;
end.