bzoj3790

观察发现，这道题目其实就相当于一个最小区间覆盖问题
这里的区间是指以每个点为中心的最长回文串
很久没写manacher，有点感动
不得不说manacher是一个非常好的算法

var s:array[0..100010] of char;
    c,l,r,f,p:array[0..100010] of longint;
    i,j,t,n,m,ans,k,right:longint;
    ch:char;

procedure swap(var a,b:longint);
  var c:longint;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

function lowbit(x:longint):longint;
  begin
    exit(x and (-x));
  end;

procedure sort(ll,rr: longint);
  var i,j,x,y: longint;
  begin
    i:=ll;
    j:=rr;
    x:=r[(ll+rr) shr 1];
    y:=l[(ll+rr) shr 1];
    repeat
      while (r[i]<x) or (r[i]=x) and (l[i]<y) do inc(i);
      while (x<r[j]) or (r[j]=x) and (y<l[j]) do dec(j);
      if not(i>j) then
      begin
        swap(r[i],r[j]);
        swap(l[i],l[j]);
        inc(i);
        j:=j-1;
      end;
    until i>j;
    if ll<j then sort(ll,j);
    if i<rr then sort(i,rr);
  end;

function ask(x:longint):longint;
  begin
    if x=0 then exit(0);
    ask:=n+1;
    while x<=n do  //因为求的是后缀最小值，事实上只要将查询和修改的范围换一下即可
    begin
      ask:=min(ask,c[x]);
      x:=x+lowbit(x);
    end;
  end;

procedure add(i:longint);
  var x:longint;
  begin
    x:=r[i];
    while x>0 do
    begin
      c[x]:=min(c[x],f[i]);
      x:=x-lowbit(x);
    end;
  end;

begin
  while true do
  begin
    read(ch);
    if not((ch>='a') and (ch<='z')) then break;
    s[0]:='$';
    s[1]:='#';
    m:=1;
    n:=0;
    while (ch>='a') and (ch<='z') do
    begin
      inc(n);
      inc(m);
      s[m]:=ch;
      inc(m);
      s[m]:='#'; //将回文串的奇偶转化为一种情况
      read(ch);
    end;
    s[m+1]:=' ';
    readln;
    k:=0;
    right:=0;
    t:=0;
    fillchar(p,sizeof(p),0);
    for i:=1 to m do
    begin
      if right>i then   //manacher的核心
        p[i]:=min(p[2*k-i],right-i)
      else p[i]:=1;
      while s[i+p[i]]=s[i-p[i]] do inc(p[i]);
      if p[i]+i>right then
      begin
        right:=p[i]+i;
        k:=i;
      end;
      if (s[i]='#') and (p[i]=1) then continue
      else begin
        inc(t);
        l[t]:=(i-p[i]+2) div 2;
        r[t]:=(i+p[i]-2) div 2;
      end;
    end;
    sort(1,t);  //解决区间覆盖问题，右端点排序
    ans:=n;
    for i:=1 to n do
      c[i]:=n+1;
    for i:=1 to t do
    begin
      f[i]:=ask(l[i]-1)+1; //以前这个问题我都是用单调队列的，这里写了树状数组，更简明
      if r[i]=n then ans:=min(ans,f[i]);
      add(i);
    end;
    writeln(ans-1);
  end;
end.