bzoj2337

这句话感觉都能成定理了：
xor问题逐位考虑……
这道题就是这样，然后和bzoj3143和相似
但这道题多了自环，于是我们设f[i]表示当前位由i走到n的后为1的数学期望
显然f[n]=0，可得f[i]=sigma((1/d[i])*f[j])（如果边权这位为0）+sigma（(1/d[i])*(1-f[j]))（边权这位为1）
然后高斯消元即可

type node=record
       po,len,next:longint;
     end;

var w:array[0..20010] of node;
    b,d,p:array[0..110] of longint;
    a:array[0..110,0..110] of extended;
    n,m,x,y,z,len,t,i,j,k:longint;
    c,ans:extended;

function max(a,b:longint):longint;
  begin
    if a>b then exit(a) else exit(b);
  end;

procedure swap(var a,b:extended);
  var c:extended;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

procedure add(x,y,z:longint);
  begin
    inc(len);
    w[len].po:=y;
    w[len].len:=z;
    w[len].next:=p[x];
    p[x]:=len;
  end;

procedure work;
  var i,j,k,p:longint;
  begin
    for i:=1 to n-2 do
    begin
      p:=i;
      for k:=i+1 to n-1 do
        if abs(a[k,i])>abs(a[p,i]) then p:=k;
      if p<>i then
      begin
        for j:=i to n+1 do
          swap(a[p,j],a[i,j]);
      end;
      for k:=i+1 to n-1 do
        if abs(a[k,i])>0 then
        begin
          for j:=n+1 downto i do
            a[k,j]:=a[k,j]-a[i,j]*a[k,i]/a[i,i];
        end;
    end;
    a[n,n+1]:=0;
    for i:=n-1 downto 1 do
    begin
      for j:=i+1 to n-1 do
        a[i,n+1]:=a[i,n+1]-a[j,n+1]*a[i,j];
      a[i,n+1]:=a[i,n+1]/a[i,i];
    end;
  end;

begin
  readln(n,m);
  for i:=1 to m do
  begin
    readln(x,y,z);
    if z<>0 then t:=max(t,trunc(ln(z)/ln(2)));
    inc(d[x]);
    inc(d[y]);
    if x=y then dec(d[x])
    else add(y,x,z);
    add(x,y,z);
  end;
  for i:=0 to t do
  begin
    fillchar(a,sizeof(a),0);
    for j:=1 to n do
      a[j,j]:=1;
    for k:=1 to n do
    begin
      j:=p[k];
      while j<>0 do
      begin
        y:=w[j].po;
        if w[j].len and (1 shl i)=0 then a[k,y]:=a[k,y]-1/d[k]
        else begin
          a[k,y]:=a[k,y]+1/d[k];
          a[k,n+1]:=a[k,n+1]+1/d[k];
        end;
        j:=w[j].next;
      end;
    end;
    work;
    ans:=ans+1 shl i*a[1,n+1];
  end;
  writeln(ans:0:3);
end.