bzoj2125 3047

仙人掌上的最短路，这里有详细的题解
http://pan.baidu.com/s/1wzCpC
我觉得讲的很清楚，不懂的见代码注释吧

type node=record
       po,next,num:longint;
     end;

var e,w:array[0..200010] of node;
    dfn,low,p,q,mark,s,d,dis,dep,fa:array[0..10010] of longint;
    anc:array[0..10010,0..20] of longint;
    v:array[0..10010] of boolean;
    st:array[0..1000010] of longint;
    t,h,i,len,x,y,z,n,m,tot,qq:longint;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

procedure add(x,y,z:longint);
  begin
    inc(len);
    e[len].po:=y;
    e[len].next:=p[x];
    e[len].num:=z;
    p[x]:=len;
  end;

procedure fadd(x,y:longint);
  begin
    inc(len);
    w[len].po:=y;
    w[len].next:=q[x];
    q[x]:=len;
  end;

procedure spfa;
  var f,r,i,x,y:longint;
  begin
    f:=1;
    r:=1;
    st[1]:=1;
    for i:=2 to n do  //d[]表示根节点到其他节点的最短路
      d[i]:=2000000007;
    while f<=r do
    begin
      x:=st[f];
      i:=p[x];
      v[x]:=false;
      while i<>0 do
      begin
        y:=e[i].po;
        if d[y]>d[x]+e[i].num then
        begin
          d[y]:=d[x]+e[i].num;
          if not v[y] then
          begin
            inc(r);
            st[r]:=y;
            v[y]:=true;
          end;
        end;
        i:=e[i].next;
      end;
      inc(f);
    end;
  end;

procedure get(x,y:longint);
  begin
    inc(tot);
    while y<>x do
    begin
      mark[y]:=tot;  //环上节点（除最高点）标为同一颜色
      fadd(x,y);    //建“杨天”树
      y:=fa[y];
    end;
  end;

procedure dfs1(x:longint);
  var i,y:longint;
  begin
    inc(h);
    dfn[x]:=h;
    low[x]:=h;
    i:=p[x];
    while i<>0 do
    begin
      y:=e[i].po;
      if fa[x]<>y then
      begin
        if dfn[y]=0 then
        begin
          fa[y]:=x;
          dis[y]:=dis[x]+e[i].num;  //dis[]表示得到的dfs树上根节点到节点的距离
          dfs1(y);
        end;
        low[x]:=min(low[x],low[y]);
        if low[y]>dfn[x] then
          fadd(x,y);   //dfs树的树边
      end;
      i:=e[i].next;
    end;
    i:=p[x];
    while i<>0 do
    begin
      y:=e[i].po;
      if (dfn[y]>dfn[x]) and (fa[y]<>x) then
      begin
        get(x,y);  //处理环
        s[tot]:=dis[y]-dis[x]+e[i].num;  //求这个环的长度
      end;
      i:=e[i].next;
    end;
  end;

procedure dfs2(x:longint);
  var i,y:longint;
  begin
    for i:=1 to t do
    begin
      y:=anc[x,i-1];
      if y<>0 then anc[x,i]:=anc[y,i-1] else break;
    end;
    i:=q[x];
    while i<>0 do
    begin
      y:=w[i].po;
      fa[y]:=x;
      anc[y,0]:=x;
      dep[y]:=dep[x]+1;  //在杨天树上的深度
      dfs2(y);
      i:=w[i].next;
    end;
  end;

function lca(x,y:longint):longint;
  var i,p,a,b,z:longint;
  begin
    if x=y then exit(0);  //注意
    if dep[x]<dep[y] then
    begin
      p:=x; x:=y; y:=p;
    end;
    a:=x;
    b:=y;
    p:=trunc(ln(dep[x])/ln(2));
    if dep[a]>dep[b] then
    begin
      for i:=p downto 0 do
        if dep[a]-1 shl i>=dep[b] then a:=anc[a,i];
    end;
    if a=b then exit(d[x]-d[a]);  //如果点a是点x的祖先那么a,x之间最短距离为d[x]-d[a]
    for i:=p downto 0 do
      if (anc[a,i]<>anc[b,i]) then
      begin
        a:=anc[a,i];
        b:=anc[b,i];
      end;
    z:=fa[a];
    if (mark[a]<>0) and (mark[a]=mark[b]) then  //最后提到环上两点要讨论
    begin
      p:=abs(dis[a]-dis[b]);
      exit(d[x]-d[a]+d[y]-d[b]+min(p,s[mark[a]]-p));
    end
    else exit(d[x]+d[y]-2*d[z]);  //否则直接当树做
  end;

begin
  readln(n,m,qq);
  for i:=1 to m do
  begin
    readln(x,y,z);
    add(x,y,z);
    add(y,x,z);
  end;
  t:=trunc(ln(n)/ln(2));
  spfa;
  len:=0;
  dfs1(1);
  dfs2(1);
  for i:=1 to qq do
  begin
    readln(x,y);
    writeln(lca(x,y));
  end;
end.