bzoj1570

购买的机票限制和数据范围很容易想到是网络流
不难想到每个城市按时刻拆点，这也是一个经典模型
由于时间不会太大，我们穷举时间，不断在残留网络上建图，跑最大流
直至总流量为k即可

const inf=100000007;
type node=record
       po,next,flow:longint;
     end;

var e:array[0..1000100] of node;
    a,b,c,p,numh,h,d,cur,pre:array[0..6010] of longint;
    s,max,t,ans,i,n,m,k,len:longint;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

procedure add(x,y,f:longint);
  begin
    inc(len);
    e[len].po:=y;
    e[len].flow:=f;
    e[len].next:=p[x];
    p[x]:=len;
  end;

procedure build(x,y,f:longint);
  begin
    add(x,y,f);
    add(y,x,0);
  end;

function sap:longint;
  var u,i,j,tmp,neck,q:longint;
  begin
    sap:=0;
    u:=0;
    fillchar(numh,sizeof(numh),0);
    fillchar(h,sizeof(h),0);
    for i:=0 to max do
      cur[i]:=p[i];
    cur[t]:=p[t];
    numh[0]:=max+2;
    neck:=inf;
    while h[0]<max+2 do
    begin
      d[u]:=neck;
      i:=cur[u];
      while i<>-1 do
      begin
        j:=e[i].po;
        if (e[i].flow>0) and (h[u]=h[j]+1) then
        begin
          neck:=min(neck,e[i].flow);
          pre[j]:=u;
          cur[u]:=i;
          u:=j;
          if u=t then
          begin
            sap:=sap+neck;
            while u<>0 do
            begin
              u:=pre[u];
              j:=cur[u];
              dec(e[j].flow,neck);
              inc(e[j xor 1].flow,neck);
            end;
            neck:=inf;
          end;
          break;
        end;
        i:=e[i].next;
      end;
      if i=-1 then
      begin
        dec(numh[h[u]]);
        if numh[h[u]]=0 then break;
        q:=-1;
        tmp:=max+1;
        i:=p[u];
        while i<>-1 do
        begin
          j:=e[i].po;
          if (e[i].flow>0) then
            if h[j]<tmp then
            begin
              tmp:=h[j];
              q:=i;
            end;
          i:=e[i].next;
        end;
        h[u]:=tmp+1;
        cur[u]:=q;
        inc(numh[h[u]]);
        if u<>0 then
        begin
          u:=pre[u];
          neck:=d[u];
        end;
      end;
    end;
  end;

begin
  len:=-1;
  fillchar(p,sizeof(p),255);
  readln(n,m,k);
  build(0,1,k);
  for i:=1 to m do
    readln(a[i],b[i],c[i]);
  t:=6010;
  ans:=0;
  repeat
    for i:=1 to m do
      build(ans*n+a[i],(ans+1)*n+b[i],c[i]);
    for i:=1 to n do
      build(ans*n+i,(ans+1)*n+i,inf);
    build((ans+1)*n+n,t,inf);
    max:=(ans+1)*n+n;
    inc(ans);
    s:=s+sap;
  until s=k;
  writeln(ans);
end.