bzoj1558

好题，初看以为只要差分然后维护相同的段数目
但是请注意下面的情况
2 3 5 8 9
 1 2 3 4 这显然答案是3而不是4
因此我们还要再维护ld，rd表示左右单独的段长度
和s表示不包括左右单独的段，中间部分最少划分成几个等差数列
具体维护见程序，比较复杂，但其实不难
这题还有一个坑爹的地方，我一开始忘开int64本地测数据竟然全能过
但是交上去就WA……感人肺腑

type node=record
       l,r:int64;
       ld,rd,s:longint;
     end;

var tree:array[0..100010*4] of node;
    lazy:array[0..100010*4] of int64;
    a:array[0..100010] of longint;
    n,m,i,x0,y0,x,y,p,q:longint;
    z:int64;
    ans:node;
    ch:char;

procedure update(var a:node;x,y:node);
  begin
    a.l:=x.l;
    a.r:=y.r;
    a.ld:=x.ld;
    if x.s=0 then  //x.s=0说明左部分全是单独的（没有连续出现2个及以上的）
    begin
      if x.r<>y.l then inc(a.ld,y.ld)
      else dec(a.ld);
    end;
    a.rd:=y.rd;
    if y.s=0 then
    begin
      if x.r<>y.l then inc(a.rd,x.rd)
      else dec(a.rd);
    end;
    a.s:=x.s+y.s;
    if x.s=0 then   //以下请自行理解
    begin
      if x.r=y.l then
      begin
        if y.s=0 then inc(a.s)
        else if (y.ld>0) then inc(a.s,(y.ld-1) shr 1+1);
      end;
    end
    else if x.rd>0 then
    begin
      if x.r=y.l then
      begin
        inc(a.s,(x.rd-1) shr 1);
        if y.s=0 then inc(a.s)
        else if (y.ld>0) then inc(a.s,(y.ld-1) shr 1+1);
      end
      else if y.s>0 then
        inc(a.s,(x.rd+y.ld) shr 1);
    end
    else begin
      if x.r=y.l then
      begin
        if (y.s>0) and (y.ld>0) then inc(a.s,(y.ld-1) shr 1);
        if (y.s>0) and (y.ld=0) then dec(a.s);
      end
      else if (y.s>0) and (y.ld>0) then inc(a.s,y.ld shr 1);
    end;
  end;

procedure push(i:longint);
  begin
    inc(lazy[i*2],lazy[i]);
    inc(tree[i*2].l,lazy[i]);
    inc(tree[i*2].r,lazy[i]);
    inc(lazy[i*2+1],lazy[i]);
    inc(tree[i*2+1].l,lazy[i]);
    inc(tree[i*2+1].r,lazy[i]);
    lazy[i]:=0;
  end;

procedure build(i,l,r:longint);
  var m:longint;
  begin
    if l=r then
    begin
      tree[i].l:=a[l+1]-a[l];
      tree[i].r:=a[l+1]-a[l];
      tree[i].ld:=1;
      tree[i].rd:=1;
    end
    else begin
      m:=(l+r) shr 1;
      build(i*2,l,m);
      build(i*2+1,m+1,r);
      update(tree[i],tree[i*2],tree[i*2+1]);
    end;
  end;

procedure add(i,l,r:longint);
  var m:longint;
  begin
    if (x<=l) and (y>=r) then
    begin
      inc(tree[i].l,z);
      inc(tree[i].r,z);
      lazy[i]:=lazy[i]+z;
    end
    else begin
      if lazy[i]<>0 then push(i);
      m:=(l+r) shr 1;
      if x<=m then add(i*2,l,m);
      if y>m then add(i*2+1,m+1,r);
      update(tree[i],tree[i*2],tree[i*2+1]);
    end;
  end;

function ask(i,l,r:longint):node;
  var s,s1,s2:node;
      m:longint;
  begin
    if (x<=l) and (y>=r) then exit(tree[i])
    else begin
      m:=(l+r) shr 1;
      if lazy[i]<>0 then push(i);
      if y<=m then exit(ask(i*2,l,m));
      if x>m then exit(ask(i*2+1,m+1,r));
      s1:=ask(i*2,l,m);
      s2:=ask(i*2+1,m+1,r);
      update(s,s1,s2);
      exit(s);
    end;
  end;

begin
  readln(n);
  for i:=1 to n do
    readln(a[i]);
  dec(n);
  build(1,1,n);
  readln(m);
  for i:=1 to m do
  begin
    read(ch);
    if ch='A' then
    begin
      readln(x0,y0,p,q);
      if x0>1 then //修改要分三种情况
      begin
        x:=x0-1; y:=x0-1; z:=p;  
        add(1,1,n);
      end;
      if y0<=n then
      begin
        x:=y0; y:=y0; z:=-int64(p)-int64(y0-x0)*int64(q);
        add(1,1,n);
      end;
      if x0<y0 then
      begin
        x:=x0; y:=y0-1; z:=q;
        add(1,1,n);
      end;
    end
    else begin
      readln(x,y);
      if y=x then writeln(1)
      else begin
        dec(y);
        ans:=ask(1,1,n);
        if ans.s=0 then writeln((y-x+3) shr 1) //全是单独的可以直接算出来
        else writeln(ans.s+(ans.ld+1) shr 1+(ans.rd+1) shr 1);
      end;
    end;
  end;
end.