bzoj2281

有思维难度的好题
这种题我们一般可以先从部分分考虑
30%的分数k=2也就是黑白各一个
不难发现如果初始黑白棋子相邻那必然是先手必败态否则一定是先手必胜
那么30分的部分分是很容易拿到的，组合数学
如果有多个棋子，必败态又是什么呢
由于黑白棋是相间隔的，我们不妨依次编号1号白棋，1号黑棋……一直编到k/2，我们记作m
同号棋子都相邻则一定是必败态，这个很容易看出来，还有呢？
我们假设编号为i的黑白棋之间有d[i]个格子
我们知道白棋往左移是没有意义的，因为黑棋也可以按同样的方向移同样多的格子
这样同号棋子间的间隔不变，本质还是刚才的状态，同理，黑棋往右移也是没有意义的
现在也就是每人轮流可以把d个白棋（黑棋）往右（左）移若干个格子
若是最后移动成同号棋子都相邻的那个人获胜
也就是，一共有m堆石子，每个人可以从最多d堆取任意多个，最后取完的获胜！
这不就是nim取石子的扩展吗？
考虑经典的nim取石子问题，在任意一堆中取任意个
若n堆石子的异或和=0则为先手必败
n堆石子异或和=0即二进制每一位异或和为0，也就是每一位和mod 2=0
于是我们脑洞大开的猜想，如果可以在1~d堆中任意取，
那先手必败态是否是每一位和mod (d+1)=0？
怎么证？其实很简单，首先全是0必然必败不多说
由于是可以取任意多个，所以二进制位之间互不影响
如果存在某位和x是（d+1)的倍数且不为0，那么先手操作最多只能对x-(0~d)因为最多操作d堆
那么下面，我仍然可以把x还原成(d+1)的倍数
所以很明显每一位和都mod (d+1)=0是先手必败态，否则为必胜
下面就是统计，我们显然可以用补集的思想，统计先手必败的数目
显然∑d[i]也就是m堆石子总和是在[0,n-k]之间
我们设f[i,j]表示到二进制第i位石子堆和为j的方案数，然后穷举这位和是(d+1)的倍数的情况
然后组合数学搞一搞，由于组合涉及到除法取模，所以我们还要求一下乘法逆元

const mo=1000000007;
var f:array[-1..15,0..10010] of int64;
    a,b:array[0..10010] of int64;
    d,t,n,k,m,i,j,p,q:longint;
    ans:int64;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

function quick(y:int64;n:longint):int64;
  begin
    quick:=1;
    while n>0 do
    begin
      if n mod 2=1 then quick:=quick*y mod mo;
      n:=n shr 1;
      y:=y*y mod mo;
    end;
  end;

function c(n,m:longint):int64;
  begin
    exit(a[n]*b[m] mod mo*b[n-m] mod mo);
  end;

begin
  readln(n,k,d);
  m:=k div 2;
  a[0]:=1;
  for i:=1 to n do
    a[i]:=a[i-1]*int64(i) mod mo;
  b[0]:=1;
  for i:=1 to n do
    b[i]:=quick(a[i],mo-2); //a^(p-1)≡1 (mod p) 明显a的乘法逆元即a^(p-2)
  f[-1,0]:=1;
  t:=trunc(ln(n)/ln(2));
  for i:=0 to t do
    for p:=0 to min(n-k,m*(1 shl i-1)) do
      for j:=0 to min(m div (d+1),(n-k-p) div (1 shl i) div (d+1)) do
      begin
        q:=p+j*(d+1)*1 shl i;
        f[i,q]:=(f[i,q]+f[i-1,p]*c(m,j*(d+1)) mod mo) mod mo;
      end;

  for i:=0 to n-k do
    ans:=(ans+f[t,i]*c(n-i-k+m,m) mod mo) mod mo;//剩下的格子在邻号棋子之间放置
  writeln((c(n,k)-ans+mo) mod mo);
end.