bzoj1914

这道题用转化补集的思想一下就很简单了
考虑不包括原点的三角形，显然对于一个点，它与原点构成的直线
在这条直线同侧的任意两点和这个点构成的三角形一定不是黄金三角形
为了避免重复我们只考虑直线上方的两点
然后我们只要按极角序扫一遍即可

type point=record
       x,y:longint;
     end;

var p:array[0..100010] of point;
    ans,s,w:int64;
    n,i,j:longint;

function cross(a,b:point):int64;
  begin
    exit(int64(a.x)*int64(b.y)-int64(b.x)*int64(a.y));
  end;

function cmp(a,b:point):boolean;  //pascal判断极角的大小，没有atan这种函数哎
  begin
    if (a.y>0) and (b.y<=0) then exit(true);
    if (b.y>0) and (a.y<=0) then exit(false);
    if cross(a,b)>0 then exit(true);
    exit(false);
  end;

procedure sort(l,r:longint);
  var i,j:longint;
      x,y:point;
  begin
    i:=l;
    j:=r;
    x:=p[(l+r) shr 1];
    while i<=j do
    begin
      while cmp(p[i],x) do inc(i);
      while cmp(x,p[j]) do dec(j);
      if i<=j then
      begin
        y:=p[i];
        p[i]:=p[j];
        p[j]:=y;
        inc(i);
        dec(j);
      end;
    end;
    if i<r then sort(i,r);
    if j>l then sort(l,j);
  end;

begin
  readln(n);
  for i:=1 to n do
    readln(p[i].x,p[i].y);
  sort(1,n);
  j:=1;
  for i:=1 to n do
  begin
    while cross(p[i],p[j mod n+1])>=0 do
    begin
      if j mod n+1=i then break;
      j:=j mod n+1;
      inc(w);
    end;
    s:=s+w*(w-1) div 2;
    dec(w);
  end;
  ans:=int64(n)*int64(n-1) div 2*int64(n-2) div 3;
  writeln(ans-s);
end.