bzoj3878

当初只会暴力，现在差不多觉得水了
显然离线处理，对输入的数排序然后会发现不管怎么修改都是结果总是单调不降的
对于每次处理，我们只要找到那段越界的即可
显然上线段树，话说jsoi这么喜欢线段树？
下面在bzoj上过不去，因为pascal编译器处理比较严格，可能某处爆了int64，我也懒得查了，本地是能过的

type node=record
       mi,mx,att,mul,an:int64;
     end;

var tree:array[0..100100*4] of node;
    ans,b,c:array[0..100100] of longint;
    a:array[0..100100] of int64;
    ch:array[0..100100] of char;
    m,f,t,i,n:longint;

procedure swap(var a,b:longint);
  var c:longint;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

procedure sort(l,r:longint);
  var i,j:longint;
      x,y:int64;

  begin
    i:=l;
    j:=r;
    x:=a[(l+r) shr 1];
    repeat
      while a[i]<x do inc(i);
      while x<a[j] do dec(j);
      if not(i>j) then
      begin
        y:=a[i]; a[i]:=a[j]; a[j]:=y;
        swap(c[i],c[j]);
        inc(i);
        dec(j);
      end;
    until i>j;
    if l<j then sort(l,j);
    if i<r then sort(i,r);
  end;

procedure cal(i,x,y:longint;x1,x2,x3:int64);
  begin
    with tree[i] do
    begin
      mi:=mi*x1+x2*a[x]+x3;
      mx:=mx*x1+x2*a[y]+x3;
      mul:=mul*x1;
      att:=att*x1;
      an:=an*x1;
      att:=att+x2;
      an:=an+x3;
    end;
  end;

procedure build(i,l,r:longint);
  var m:longint;
  begin
    tree[i].mi:=a[l];
    tree[i].mx:=a[r];
    tree[i].mul:=1;
    if l<>r then
    begin
      m:=(l+r) shr 1;
      build(i*2,l,m);
      build(i*2+1,m+1,r);
    end;
  end;

procedure push(i,l,r:longint);
  var m:longint;
  begin
    m:=(l+r) shr 1;
    with tree[i] do
    begin
      cal(i*2,l,m,mul,att,an);
      cal(i*2+1,m+1,r,mul,att,an);
      mul:=1;
      att:=0;
      an:=0;
    end;
  end;

procedure max(i,l,r:longint);
  var m:longint;
  begin
    if l=r then cal(i,l,l,0,0,t)
    else begin
      m:=(l+r) shr 1;
      push(i,l,r);
      if tree[i*2].mx>t then
      begin
        cal(i*2+1,m+1,r,0,0,t);
        max(i*2,l,m);
      end
      else max(i*2+1,m+1,r);
      tree[i].mx:=tree[i*2+1].mx;
      tree[i].mi:=tree[i*2].mi;
    end;
  end;

procedure min(i,l,r:longint);
  var m:longint;
  begin
    if l=r then cal(i,l,l,0,0,f)
    else begin
      m:=(l+r) shr 1;
      push(i,l,r);
      if tree[i*2+1].mi<f then
      begin
        cal(i*2,l,m,0,0,f);
        min(i*2+1,m+1,r);
      end
      else min(i*2,l,m);
      tree[i].mx:=tree[i*2+1].mx;
      tree[i].mi:=tree[i*2].mi;
    end;
  end;

procedure ask(i,l,r:longint);
  var m:longint;
  begin
    if l=r then
      ans[c[l]]:=tree[i].mx
    else begin
      m:=(l+r) shr 1;
      push(i,l,r);
      ask(i*2,l,m);
      ask(i*2+1,m+1,r);
    end;
  end;

begin
  readln(m,f,t);
  for i:=1 to m do
    readln(ch[i],b[i]);
  readln(n);
  for i:=1 to n do
  begin
    readln(a[i]);
    if a[i]>t then a[i]:=t;
    if a[i]<f then a[i]:=f;
    c[i]:=i;
  end;
  sort(1,n);
  build(1,1,n);
  for i:=1 to m do
    if ch[i]='+' then
    begin
      cal(1,1,n,1,0,b[i]);
      if tree[1].mx>t then max(1,1,n);
    end
    else if ch[i]='-' then
    begin
      cal(1,1,n,1,0,-b[i]);
      if tree[1].mi<f then min(1,1,n);
    end
    else if ch[i]='*' then
    begin
      cal(1,1,n,b[i],0,0);
      if tree[1].mx>t then max(1,1,n);
    end
    else begin
      cal(1,1,n,1,b[i],0);
      if tree[1].mx>t then max(1,1,n);
    end;
  ask(1,1,n);
  for i:=1 to n do
    writeln(ans[i]);
end.