bzoj2259

这道题很不错，首先读入方式有一种跳跃的既视感：
读入Si之后，我们可以直接往后跳Si,可以想到最短路，设序列为a[]，我们设n+1是终点
如果i+a[i]<=n+1 那么i-->i+a[i] 权值为0 否则i-->n+1 权值为i+a[i]-n
注意这可以算是一种非常经典的区间建图的方法
下面我们解决调整某个数，我们比划一下就知道，在相邻两点连一条权值为1的无向边即可
然后我们可以跑最短路了
但是看到n<=1000000是不是感觉dij+heap有点虚？实际上对这个图我们直接宽搜就好了
为什么？仔细研究发现，大部分边权值不是1就是0，只有一些点到终点的权值是不和谐的
但这有什么关系呢？我们到快到终点的那个点直接计算比较取最优即可

const inf=1000000007;

var q,f,d:array[0..1000010] of longint;
    ans,n,i,h,r:longint;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

procedure add(x,w:longint);
  begin
    if (x<1) or (x>n+1) then exit;
    while d[x]>inf do
    begin
      d[x]:=w;
      inc(r);
      q[r]:=x;
      if f[x]>n then
      begin
        ans:=min(ans,f[x]-n-1+d[x]);
        exit;
      end;
      x:=f[x];
    end;
  end;

procedure work;
  var x:longint;
  begin
    if f[1]>n then
    begin
      ans:=f[1]-n-1;
      exit;
    end;
    h:=1;
    add(f[1],0);
    while (h<=r) and (d[n+1]>inf) do
    begin
      x:=q[h];
      add(x-1,d[x]+1);
      add(x+1,d[x]+1);
      inc(h);
    end;
  end;

begin
  readln(n);
  for i:=1 to n do
  begin
    read(f[i]);
    f[i]:=f[i]+i+1;
  end;
  ans:=inf;
  fillchar(d,sizeof(d),127);
  work;
  ans:=min(ans,d[n+1]);
  writeln(ans);
end.