bzoj3796

好像已经很久没有做后缀数组的题目，导致这种题一开始没想出来
看到公共子串肯定想到后缀数组吧，但我都忘了最长公共子串怎么求了
重要的性质：最长公共子串=max(h[i]）名次相邻的两个后缀要分别属于s1,s2串 具体怎么证很简单
这道题多了一个条件，就是公用子串不能包含某个串——很明显想到KMP
我们可以预处理与s3匹配的起始位置，然后处理每个点右边最近的起始位置
然后在穷举h[i]的时候判断一下即可

var h,f,x,y,sum,sa,rank:array[0..120000] of longint;
    v:array[0..120000] of boolean;
    j,t,st,en,ans,i,p,l,n,m:longint;
    s,ss:ansistring;
    fl:boolean;

function max(a,b:longint):longint;
  begin
    if a>b then exit(a) else exit(b);
  end;

procedure suffix;
  var i,p,j,m:longint;
  begin
    m:=150;
    for i:=1 to n do
    begin
      y[i]:=ord(s[i]);
      inc(sum[y[i]]);
    end;
    for i:=1 to m do
      inc(sum[i],sum[i-1]);
    for i:=n downto 1 do
    begin
      sa[sum[y[i]]]:=i;
      dec(sum[y[i]]);
    end;
    p:=1;
    rank[sa[1]]:=1;
    for i:=2 to n do
    begin
      if y[sa[i]]<>y[sa[i-1]] then inc(p);
      rank[sa[i]]:=p;
    end;
    m:=p;
    j:=1;
    while m<n do
    begin
      y:=rank;
      fillchar(sum,sizeof(sum),0);
      p:=0;
      for i:=n-j+1 to n do
      begin
        inc(p);
        x[p]:=i;
      end;
      for i:=1 to n do
        if sa[i]>j then
        begin
          inc(p);
          x[p]:=sa[i]-j;
        end;
      for i:=1 to n do
      begin
        rank[i]:=y[x[i]];
        inc(sum[rank[i]]);
      end;
      for i:=1 to m do
        inc(sum[i],sum[i-1]);
      for i:=n downto 1 do
      begin
        sa[sum[rank[i]]]:=x[i];
        dec(sum[rank[i]]);
      end;
      p:=1;
      rank[sa[1]]:=1;
      for i:=2 to n do
      begin
        if (y[sa[i]]<>y[sa[i-1]]) or (y[sa[i-1]+j]<>y[sa[i]+j]) then inc(p);
        rank[sa[i]]:=p;
      end;
      m:=p;
      j:=j shl 1;
    end;
    p:=0;
    h[1]:=0;
    for i:=1 to n do
    begin
      if rank[i]=1 then continue;
      j:=sa[rank[i]-1];
      while s[i+p]=s[j+p] do inc(p);
      h[rank[i]]:=p;
      if p>0 then dec(p);
    end;
  end;

begin
  readln(s);
  readln(ss);
  p:=length(s)+1;
  s:=s+chr(1)+ss+chr(2);
  n:=length(s);

  readln(ss);
  l:=length(ss);
  ss:=ss+' ';
  for i:=2 to l do
  begin
    j:=f[i-1];
    while (j>0) and (ss[j+1]<>ss[i]) do j:=f[j];
    if ss[j+1]=ss[i] then f[i]:=j+1 else f[i]:=0;
  end;

  j:=0;
  for i:=1 to p-1 do
  begin
    while (j>0) and (ss[j+1]<>s[i]) do j:=f[j];
    if ss[j+1]=s[i] then
    begin
      inc(j);
      if j=l then v[i-l+1]:=true;
    end
    else j:=0;
  end;

  t:=100000007;
  for i:=p-1 downto 1 do
  begin
    if v[i] then t:=i;
    f[i]:=t;  //右边最近的匹配起始节点
  end;
  suffix;
  ans:=0;
  for i:=2 to n do
  begin
    fl:=false;
    if (sa[i]<p) and (sa[i-1]>p) and (sa[i-1]<n) then
    begin
      st:=sa[i];
      en:=f[st];
      fl:=true;
    end;
    if (sa[i]>p) and (sa[i]<n) and (sa[i-1]<p) then
    begin
      st:=sa[i-1];
      en:=f[st];
      fl:=true;
    end;
    if fl then
    begin
      if h[i]>=en-st+l then  //判断是否包含了匹配串
        ans:=max(ans,en-st+l-1)
      else ans:=max(ans,h[i]);
    end;
  end;
  writeln(ans);
end.