bzoj2906

显然分块,由于颜色也有区间，我们的ans[l,r,k]表示块l和块r颜色1~k的权值和
所以我们块的大小要设为n^(2/3)，其它没什么说的，比较水

var f:array[0..41,0..41,0..20005] of int64;
    g:array[0..41,0..20005] of longint;
    s:array[0..20005] of longint;
    a,be,q:array[0..50010] of longint;
    ans,size,t,tot,i,l,r,n,m,te,x,y:longint;

procedure swap(var a,b:longint);
  var c:longint;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

procedure prework;
  var i,j,k:longint;
  begin
    for i:=1 to n do
      inc(g[be[i],a[i]]);
    for i:=2 to t do
      for j:=1 to m do
        g[i,j]:=g[i-1,j]+g[i,j];
    for i:=1 to t do
    begin
      for j:=(i-1)*size+1 to n do
      begin
        if j mod size=1 then
        begin
          for k:=1 to m do
            f[i,be[j],k]:=f[i,be[j]-1,k];
        end;
        inc(f[i,be[j],a[j]],s[a[j]]*2+1);
        inc(s[a[j]]);
      end;
      for j:=i to t do
        for k:=1 to m do
          inc(f[i,j,k],f[i,j,k-1]);
      fillchar(s,sizeof(s),0);
    end;
  end;

procedure clear;
  var i:longint;
  begin
    for i:=1 to tot do
      s[q[i]]:=0;
  end;

function ask(l,r,x,y:longint):int64;
  var i:longint;
  begin
    tot:=0;
    ask:=0;
    if be[l]=be[r] then
    begin
      for i:=l to r do
        if (a[i]>=x) and (a[i]<=y) then
        begin
          if s[a[i]]=0 then
          begin
            inc(tot);
            q[tot]:=a[i];
          end;
          ask:=ask+s[a[i]]*2+1;
          inc(s[a[i]]);
        end;
      clear;
    end
    else begin
      ask:=f[be[l]+1,be[r]-1,y]-f[be[l]+1,be[r]-1,x-1];
      for i:=l to be[l]*size do
        if (a[i]>=x) and (a[i]<=y) then
        begin
          if s[a[i]]=0 then
          begin
            inc(tot);
            q[tot]:=a[i];
            s[a[i]]:=g[be[r]-1,a[i]]-g[be[l],a[i]];
          end;
          ask:=ask+s[a[i]]*2+1;
          inc(s[a[i]]);
        end;
      for i:=(be[r]-1)*size+1 to r do
        if (a[i]>=x) and (a[i]<=y) then
        begin
          if s[a[i]]=0 then
          begin
            inc(tot);
            q[tot]:=a[i];
            s[a[i]]:=g[be[r]-1,a[i]]-g[be[l],a[i]];
          end;
          ask:=ask+s[a[i]]*2+1;
          inc(s[a[i]]);
        end;
      clear;
    end;
  end;

begin
  readln(n,m,te);
  size:=1;
  while size*size/n*size<n do inc(size);
  dec(size);
  for i:=1 to n do
  begin
    read(a[i]);
    be[i]:=(i-1) div size+1;
  end;
  t:=n div size;
  if n mod size<>0 then inc(t);
  prework;
  for i:=1 to te do
  begin
    readln(l,r,x,y);
    l:=l xor ans;
    r:=r xor ans;
    x:=x xor ans;
    y:=y xor ans;
    if l>r then swap(l,r);
    if x>y then swap(x,y);
    ans:=ask(l,r,x,y);
    writeln(ans);
  end;
end.