51nod1962区间计数

　　考虑每个值作为最大值的区间实际上可以用单调栈求出来，即找到左边第一个比它大的数l[i],右边第一个比它大的r[i]，那就是左端点在[l[i],i]右端点在[i,r[i]]的区间是以第i个数作为最大值。

　　这样的话可以看成二维平面上一个矩形区域,每个矩形区域有着一样的最大值，如果我们把最大值相同的矩形放在一起考虑，问题就变成了：最大值相同的a产生的矩形和b产生的矩形交的面积之和。

　　用一个扫描线去做，维护当前线上矩形交的长度now。具体是这样的：开2n个线段树，对于每一种最大值开线段树，分别用roota[i]和rootb[i]维护a和b的最大值为i的矩形在当前扫描线上覆盖情况。每次一个值为w的a产生的左上角[x1,y1],右下角[x2,y2]的矩形在x1处加入，now+=rootb[w]在[y1,y2]覆盖了多少，再在roota[w]的线段树修改。删除把+改成-就行了。这样最后ans+=now。

　　写着非常简单。

program j01;
const maxn=350086;
var a,b:array[0..maxn]of longint;
    roota,rootb:array[0..maxn]of longint;
    la,lb:array[0..maxn]of longint;
    sta,stb:array[0..maxn]of longint;
    f:array[0..40*maxn]of record l,r,tag,w:longint; end;
    topa,topb,cnt,n,i:longint;
    ll,rr,dd:longint;
    sum,now:int64;
    
function min(a,b:longint):longint;inline;begin if a<b then exit(a) else exit(b); end;
function max(a,b:longint):longint;inline;begin if a>b then exit(a) else exit(b); end;
    
function ask(i,l,r:longint):longint;
var mid,res:longint;
begin
    if i=0 then exit(0);
    if(ll<=l)and(r<=rr)then exit(f[i].w);
    mid:=(l+r)div 2;res:=f[i].tag*(min(rr,r)-max(ll,l)+1);
    if ll<=mid then res:=res+ask(f[i].l,l,mid);
    if mid+1<=rr then res:=res+ask(f[i].r,mid+1,r);
    exit(res);
end;

procedure change(var i:longint;l,r:longint);
var mid:longint;
begin
    if i=0 then
    begin
        inc(cnt);i:=cnt;
    end;
    if(ll<=l)and(r<=rr)then
    begin
        inc(f[i].tag,dd);inc(f[i].w,dd*(r-l+1));exit;
    end;
    mid:=(l+r)div 2;
    if ll<=mid then change(f[i].l,l,mid);
    if mid+1<=rr then change(f[i].r,mid+1,r);
    f[i].w:=f[i].tag*(r-l+1)+f[f[i].l].w+f[f[i].r].w;
end;
    
begin
    readln(n);
    for i:=1 to n do read(a[i]);
    for i:=1 to n do read(b[i]);
    fillchar(la,sizeof(la),0);fillchar(lb,sizeof(lb),0);
    fillchar(roota,sizeof(roota),0);fillchar(rootb,sizeof(rootb),0);
    a[0]:=maxlongint;b[0]:=maxlongint;topa:=0;topb:=0;sta[0]:=0;stb[0]:=0;
    sum:=0;now:=0;
    for i:=1 to n do
    begin
        while a[sta[topa]]<=a[i] do
        begin
            ll:=la[sta[topa]];rr:=sta[topa];dd:=-1;
            now:=now-ask(rootb[a[sta[topa]]],1,n);
            change(roota[a[sta[topa]]],1,n);
            dec(topa);
        end;
        while b[stb[topb]]<=b[i] do
        begin
            ll:=lb[stb[topb]];rr:=stb[topb];dd:=-1;
            now:=now-ask(roota[b[stb[topb]]],1,n);
            change(rootb[b[stb[topb]]],1,n);
            dec(topb);
        end;
        la[i]:=sta[topa]+1;ll:=la[i];rr:=i;dd:=1;
        now:=now+ask(rootb[a[i]],1,n);change(roota[a[i]],1,n);
        inc(topa);sta[topa]:=i;
        lb[i]:=stb[topb]+1;ll:=lb[i];rr:=i;dd:=1;
        now:=now+ask(roota[b[i]],1,n);change(rootb[b[i]],1,n);
        inc(topb);stb[topb]:=i;
        sum:=sum+now;//writeln(now,' ',sum);
    end;
    writeln(sum);
end.