bzoj4025: 二分图

4025: 二分图

Time Limit: 20 Sec  Memory Limit: 512 MB
Submit: 1127  Solved: 420
[Submit][Status][Discuss]

Description

神犇有一个n个节点的图。因为神犇是神犇，所以在T时间内一些边会出现后消失。神犇要求出每一时间段内这个图是否是二分图。这么简单的问题神犇当然会做了，于是他想考考你。

 

Input

输入数据的第一行是三个整数n,m,T。

第2行到第m+1行，每行4个整数u,v,start,end。第i+1行的四个整数表示第i条边连接u,v两个点，这条边在start时刻出现，在第end时刻消失。

 

Output

输出包含T行。在第i行中，如果第i时间段内这个图是二分图，那么输出“Yes”，否则输出“No”，不含引号。

 

Sample Input

3 3 3
1 2 0 2
2 3 0 3
1 3 1 2

Sample Output

Yes
No
Yes

HINT

 

样例说明：

0时刻，出现两条边1-2和2-3。

第1时间段内，这个图是二分图，输出Yes。

1时刻，出现一条边1-3。

第2时间段内，这个图不是二分图，输出No。

2时刻，1-2和1-3两条边消失。

第3时间段内，只有一条边2-3，这个图是二分图，输出Yes。

 

数据范围：

n<=100000，m<=200000，T<=100000，1<=u,v<=n，0<=start<=end<=T。

 

题解

  我们想象对时间轴建一颗线段树，然后对于每一条边有个存在区间，想象线段树区间覆盖。我们从顶走到底的一个点的话，把所有覆盖路径上节点的边都拿出来处理，这样就得到了这个时间点的状态。我们用这样的思想对时间轴进行分治，对于当前处理的某个时间段，首先把完全覆盖这个时间段[l,r]的边给处理一下，然后把开始时间<=mid的找出来递归处理[l,mid]，再把结束时间>=mid+1的拿出来递归处理[mid+1,r]

  具体实现的方法是可撤销带权并查集，权是到根的路径长度的奇偶，每次处理完一个区间，就把这个区间所有的合并操作全部撤销……这个好像挺简单的网上应该都有……有点像是ahoi2013的某道题。

program j01;
const maxn=100086;
type edge=record u,v,st,ed:longint; end;
var e:array[0..2*maxn]of edge;
    st:array[0..2*maxn]of longint;
    fa,d:array[0..maxn]of longint;
    a:array[0..maxn]of boolean;
    n,m,t,i,top:longint;
 
procedure swap(var a,b:edge);
var c:edge;
begin
  c:=a;a:=b;b:=c;
end;
 
procedure swap(var a,b:longint);
var c:longint;
begin
  c:=a;a:=b;b:=c;
end;
 
function ic(var a:longint):longint;
begin
  inc(a);exit(a);
end;
 
function de(var a:longint):longint;
begin
  de:=a;dec(a);
end;
 
function find(i:longint):longint;
begin
  while fa[i]<>i do i:=fa[i];exit(i);
end;
 
function dep(i:longint):boolean;
begin
  dep:=false;
  while fa[i]<>i do
  begin
    dep:=dep xor a[i];i:=fa[i];
  end;
end;
 
procedure union(u,v:longint;dd:boolean);
begin
  if d[u]>d[v] then swap(u,v);
  if d[u]=d[v] then
  begin
    st[ic(top)]:=-v;inc(d[v]);
  end;
  st[ic(top)]:=u;fa[u]:=v;
  a[u]:=dd;
end;
 
procedure resume(now:longint);
begin
  while top>now do
  begin
    if st[top]<0 then dec(d[-st[top]]) else
    begin
      fa[st[top]]:=st[top];a[st[top]]:=false;
    end;
    dec(top);
  end;
end;
 
procedure solve(l,r,m:longint);
var mid,i,j,now,fx,fy:longint;dd:boolean;
begin
  now:=top;mid:=(l+r)div 2;
  i:=1;
  while i<=m do
  begin
    if(e[i].st<=l)and(r<=e[i].ed)then
    begin
      fx:=find(e[i].u);fy:=find(e[i].v);
      dd:=not(dep(e[i].u) xor dep(e[i].v));
      if fx<>fy then union(fx,fy,dd) else
      begin
        if dd then
        begin
          for j:=l to r do writeln('No');
          resume(now);
          exit;
        end;
      end;
      swap(e[de(i)],e[de(m)]);
    end;
    inc(i);
  end;
  if l=r then
  begin
    writeln('Yes');resume(now);exit;
  end;
  i:=1;j:=m;
  while i<=j do
  begin
    if e[i].st>mid then swap(e[de(i)],e[de(j)]);
    inc(i);
  end;
  solve(l,mid,j);
  i:=1;j:=m;
  while i<=j do
  begin
    if e[i].ed<=mid then swap(e[de(i)],e[de(j)]);
    inc(i);
  end;
  solve(mid+1,r,j);
  resume(now);
end;
 
begin
  readln(n,m,t);
  for i:=1 to n do
  begin
    fa[i]:=i;a[i]:=false;d[i]:=1;
  end;
  i:=1;
  while i<=m do
  begin
    readln(e[i].u,e[i].v,e[i].st,e[i].ed);
    inc(e[i].st);
    if e[i].st>e[i].ed then
    begin
      dec(i);dec(m);
    end;
    inc(i);
  end;
  top:=0;
  solve(1,t,m);
end.