bzoj1146: [CTSC2008]网络管理Network

1146: [CTSC2008]网络管理Network

Time Limit: 50 Sec  Memory Limit: 162 MB
Submit: 3641  Solved: 1076
[Submit][Status][Discuss]

Description

　　M公司是一个非常庞大的跨国公司，在许多国家都设有它的下属分支机构或部门。为了让分布在世界各地的N个

部门之间协同工作，公司搭建了一个连接整个公司的通信网络。该网络的结构由N个路由器和N-1条高速光缆组成。

每个部门都有一个专属的路由器，部门局域网内的所有机器都联向这个路由器，然后再通过这个通信子网与其他部

门进行通信联络。该网络结构保证网络中的任意两个路由器之间都存在一条直接或间接路径以进行通信。 高速光

缆的数据传输速度非常快，以至于利用光缆传输的延迟时间可以忽略。但是由于路由器老化，在这些路由器上进行

数据交换会带来很大的延迟。而两个路由器之间的通信延迟时间则与这两个路由器通信路径上所有路由器中最大的

交换延迟时间有关。作为M公司网络部门的一名实习员工，现在要求你编写一个简单的程序来监视公司的网络状况

。该程序能够随时更新网络状况的变化信息（路由器数据交换延迟时间的变化），并且根据询问给出两个路由器通

信路径上延迟第k大的路由器的延迟时间。【任务】 你的程序从输入文件中读入N个路由器和N-1条光缆的连接信息

，每个路由器初始的数据交换延迟时间Ti，以及Q条询问（或状态改变）的信息。并依次处理这Q条询问信息，它们

可能是： 1. 由于更新了设备，或者设备出现新的故障，使得某个路由器的数据交换延迟时间发生了变化。 2. 查

询某两个路由器a和b之间的路径上延迟第k大的路由器的延迟时间。

Input

　　第一行为两个整数N和Q，分别表示路由器总数和询问的总数。第二行有N个整数，第i个数表示编号为i的路由

器初始的数据延迟时间Ti。紧接着N-1行，每行包含两个整数x和y。表示有一条光缆连接路由器x和路由器y。紧接

着是Q行，每行三个整数k、a、b。如果k=0，则表示路由器a的状态发生了变化，它的数据交换延迟时间由Ta变为b

。如果k>0，则表示询问a到b的路径上所经过的所有路由器（包括a和b）中延迟第k大的路由器的延迟时间。注意N

,Q<=80000,任意一个路由器在任何时刻都满足延迟时间小于10^8。对于所有询问满足0<=K<=N

Output

　　对于每一个第二种询问（k>0），输出一行。包含一个整数为相应的延迟时间。如果路径上的路由器不足k个，

则输出信息“invalid request!”（全部小写不包含引号，两个单词之间有一个空格）。

Sample Input

5 5
5 1 2 3 4
3 1
2 1
4 3
5 3
2 4 5
0 1 2
2 2 3
2 1 4
3 3 5

Sample Output

3
2
2
invalid request!

 

题解

非常裸的整体二分……只有我这种sb才有可能写WA……当然套个数据结构写也没什么问题……

【无论是整体二分还是数据结构】上树的时候可以树剖，但是如果用dfs序会降个log，也要好写很多。

我WA是因为把第k大看成第k小了【捂脸】太丢人了……

{$S-}{$R-}{$I-}{$V-}
program j01;
const maxn=80086;
type xx=record x,y,lc,id,tp,k:longint; end;
var a:array[0..maxn]of longint;
    op,tmp1,tmp2:array[0..10*maxn]of xx;
    c:array[0..2*maxn]of longint;
    fir,ed,dep:array[0..maxn]of longint;
    fa:array[0..maxn,0..20]of longint;
    q,next:array[0..2*maxn]of longint;
    head:array[0..maxn]of longint;
    bin:array[0..maxn]of longint;
    ans:array[0..maxn]of longint;
    n,m,tt,tot,k,u,v,i,cnt,mn,mx,tmp:longint;
 
function min(a,b:longint):longint;
begin
  if a<b then exit(a) else exit(b);
end;
 
function max(a,b:longint):longint;
begin
  if a>b then exit(a) else exit(b);
end;
 
procedure swap(var a,b:longint);inline;
var c:longint;
begin
  c:=a;a:=b;b:=c;
end;
 
procedure add(u,v:longint);inline;
begin
  inc(tt);q[tt]:=v;next[tt]:=head[u];head[u]:=tt;
end;
 
procedure dfs(i:longint);
var j:longint;
begin
  for j:=1 to bin[dep[i]] do
    fa[i,j]:=fa[fa[i,j-1],j-1];
  inc(tot);fir[i]:=tot;
  j:=head[i];
  while j>0 do
  begin
    if q[j]<>fa[i,0] then
    begin
      fa[q[j],0]:=i;dep[q[j]]:=dep[i]+1;
      dfs(q[j]);
    end;
    j:=next[j];
  end;
  inc(tot);ed[i]:=tot;
end;
 
function lca(u,v:longint):longint;
var d,i:longint;
begin
  if u=v then exit(u);
  if dep[u]<dep[v] then swap(u,v);
  d:=dep[u]-dep[v];
  for i:=0 to bin[d] do
    if d and(1 shl i)>0 then u:=fa[u,i];
  for i:=bin[dep[v]] downto 0 do
    if fa[u,i]<>fa[v,i] then
    begin
      u:=fa[u,i];v:=fa[v,i];
    end;
  if u=v then exit(u) else exit(fa[u,i]);
end;
 
procedure push(a,b,c:longint);
begin
  inc(cnt);
  with op[cnt] do
  begin
    x:=a;y:=c;id:=b;tp:=0;
  end;
  mx:=max(mx,a);mn:=min(mn,a);
end;
 
procedure addd(i,dd:longint);inline;
begin
  while i<=tot do
  begin
    inc(c[i],dd);inc(i,i and(-i));
  end;
end;
 
function sum(i:longint):longint;inline;
begin
  sum:=0;if i=0 then exit(0);
  while i>0 do
  begin
    sum:=sum+c[i];dec(i,i and(-i));
  end;
end;
 
function ask(a:xx):longint;inline;
begin
  exit(sum(a.x)+sum(a.y)-sum(fir[a.lc])-sum(fir[fa[a.lc,0]]));
end;
 
procedure solve(ql,qr,l,r:longint);
var i,j,tmp,lt,rt,mid:longint;
begin
  if ql>qr then exit;
  if l=r then
  begin
    for i:=ql to qr do
      if op[i].tp=1 then ans[op[i].id]:=l;
    exit;
  end;
  mid:=(l+r)div 2;lt:=0;rt:=0;
  for i:=ql to qr do
    if op[i].tp=0 then
    begin
      if op[i].x<=mid then
      begin
        addd(op[i].id,op[i].y);inc(lt);tmp1[lt]:=op[i];
      end else
      begin
        inc(rt);tmp2[rt]:=op[i];
      end;
    end else
    begin
      tmp:=ask(op[i]);
      if op[i].k<=tmp then
      begin
        inc(lt);tmp1[lt]:=op[i];
      end else
      begin
        dec(op[i].k,tmp);inc(rt);tmp2[rt]:=op[i];
      end;
    end;
  for i:=1 to lt do
    if tmp1[i].tp=0 then addd(tmp1[i].id,-tmp1[i].y);
  for i:=1 to lt do op[i+ql-1]:=tmp1[i];
  for i:=1 to rt do op[ql+lt+i-1]:=tmp2[i];
  solve(ql,ql+lt-1,l,mid);
  solve(ql+lt,qr,mid+1,r);
end;
 
begin
  readln(n,m);
  mn:=maxlongint;mx:=0;
  for i:=1 to n do read(a[i]);
  fillchar(head,sizeof(head),0);tt:=0;
  bin[1]:=0;
  for i:=2 to n do
    if i and(i-1)=0 then bin[i]:=bin[i-1]+1 else bin[i]:=bin[i-1];
  for i:=1 to n-1 do
  begin
    readln(u,v);add(u,v);add(v,u);
  end;
  tot:=0;fa[1,0]:=0;dep[1]:=0;
  dfs(1);
  cnt:=0;
  for i:=1 to n do
  begin
    push(a[i],fir[i],1);push(a[i],ed[i],-1);
  end;
  for i:=1 to m do
  begin
    readln(k,u,v);
    if k=0 then
    begin
      push(a[u],fir[u],-1);push(a[u],ed[u],1);
      a[u]:=v;
      push(a[u],fir[u],1);push(a[u],ed[u],-1);
      ans[i]:=-2;
    end else
    begin
      inc(cnt);
      op[cnt].k:=k;op[cnt].x:=fir[u];op[cnt].y:=fir[v];
      op[cnt].lc:=lca(u,v);op[cnt].tp:=1;op[cnt].id:=i;
      tmp:=dep[u]+dep[v]-2*dep[op[cnt].lc]+1;
      if tmp<k then
      begin
        ans[i]:=-1;dec(cnt);
      end else op[cnt].k:=tmp-op[cnt].k+1;
    end;
  end;
  solve(1,cnt,mn,mx);
  for i:=1 to m do
    if ans[i]>-2 then
    begin
      if ans[i]=-1 then writeln('invalid request!') else writeln(ans[i]);
    end;
end.