bzoj3572: [Hnoi2014]世界树

3572: [Hnoi2014]世界树

Time Limit: 20 Sec  Memory Limit: 512 MB
Submit: 1325  Solved: 732
[Submit][Status][Discuss]

Description

世界树是一棵无比巨大的树，它伸出的枝干构成了整个世界。在这里，生存着各种各样的种族和生灵，他们共同信奉着绝对公正公平的女神艾莉森，在他们的信条里，公平是使世界树能够生生不息、持续运转的根本基石。
世界树的形态可以用一个数学模型来描述：世界树中有n个种族，种族的编号分别从1到n，分别生活在编号为1到n的聚居地上，种族的编号与其聚居地的编号相同。有的聚居地之间有双向的道路相连，道路的长度为1。保证连接的方式会形成一棵树结构，即所有的聚居地之间可以互相到达，并且不会出现环。定义两个聚居地之间的距离为连接他们的道路的长度；例如，若聚居地a和b之间有道路，b和c之间有道路，因为每条道路长度为1而且又不可能出现环，所卧a与c之间的距离为2。
出于对公平的考虑，第i年，世界树的国王需要授权m[i]个种族的聚居地为临时议事处。对于某个种族x（x为种族的编号），如果距离该种族最近的临时议事处为y（y为议事处所在聚居地的编号），则种族x将接受y议事处的管辖（如果有多个临时议事处到该聚居地的距离一样，则y为其中编号最小的临时议事处）。
现在国王想知道，在q年的时间里，每一年完成授权后，当年每个临时议事处将会管理多少个种族（议事处所在的聚居地也将接受该议事处管理）。 现在这个任务交给了以智慧著称的灵长类的你：程序猿。请帮国王完成这个任务吧。

Input

第一行为一个正整数n，表示世界树中种族的个数。
接下来n-l行，每行两个正整数x，y，表示x聚居地与y聚居地之间有一条长度为1的双
向道路。接下来一行为一个正整数q，表示国王询问的年数。
接下来q块，每块两行：
第i块的第一行为1个正整数m[i]，表示第i年授权的临时议事处的个数。
第i块的第二行为m[i]个正整数h[l]、h[2]、…、h[m[i]]，表示被授权为临时议事处的聚居地编号（保证互不相同）。

Output

输出包含q行，第i行为m[i]个整数，该行的第j(j=1，2…，，m[i])个数表示第i年被授权的聚居地h[j]的临时议事处管理的种族个数。

Sample Input

10
2 1
3 2
4 3
5 4
6 1
7 3
8 3
9 4
10 1
5
2
6 1
5
2 7 3 6 9
1
8
4
8 7 10 3
5
2 9 3 5 8

Sample Output

1 9
3 1 4 1 1
10
1 1 3 5
4 1 3 1 1

HINT

 

N<=300000, q<=300000,m[1]+m[2]+…+m[q]<=300000

 

题解

建立虚树，因为虚树上的点并不都是给出的点，所以要从下向上再从上向下扫两遍，求出数组bel，即距离虚树上每个点最近的给出的点。然后对于每一条虚边上的点，控制它的一定是两端点的bel，二分（其实是在倍增出的祖先数组中跳）出分界点，然后算一下。具体细节看代码吧，感觉还是又不少要注意的地方

//因为扫的顺序搞错了吃了好几发WA

program j01;
const maxn=300086;
var f:array[0..maxn,0..20]of longint;
    fa,dfn,h,head,bin,id,ans,dep:array[0..maxn]of longint;
    q,next:array[0..2*maxn]of longint;
    st,cnt,bel,rem,size,tmp,del:array[0..maxn]of longint;
    vis:array[0..maxn]of boolean;
    n,m,u,v,i,tt,time:longint;

procedure add(u,v:longint);
begin
  inc(tt);q[tt]:=v;next[tt]:=head[u];head[u]:=tt;
end;

procedure swap(var a,b:longint);
var c:longint;
begin
  c:=a;a:=b;b:=c;
end;

procedure dfs(i:longint);
var j:longint;
begin
  for j:=1 to bin[dep[i]] do
    f[i,j]:=f[f[i,j-1],j-1];
  size[i]:=1;inc(time);dfn[i]:=time;
  j:=head[i];
  while j>0 do
  begin
    if q[j]<>f[i,0] then
    begin
      dep[q[j]]:=dep[i]+1;
      f[q[j],0]:=i;
      dfs(q[j]);
      inc(size[i],size[q[j]]);
    end;
    j:=next[j];
  end;
end;

function cmp(a,b:longint):boolean;
begin
  exit(dfn[a]<dfn[b]);
end;

procedure sort(l,r:longint);
var i,j,x:longint;
begin
  i:=l;j:=r;x:=h[(i+j)div 2];
  repeat
    while cmp(h[i],x) do inc(i);
    while cmp(x,h[j]) do dec(j);
    if i<=j then
    begin
      swap(h[i],h[j]);swap(id[i],id[j]);
      inc(i);dec(j);
    end;
  until i>j;
  if i<r then sort(i,r);
  if l<j then sort(l,j);
end;

function lca(u,v:longint):longint;
var d,i:longint;
begin
  if u=v then exit(u);
  if dep[u]<dep[v] then swap(u,v);
  d:=dep[u]-dep[v];
  for i:=bin[d] downto 0 do
    if d and(1 shl i)>0 then u:=f[u,i];
  for i:=bin[dep[u]] downto 0 do
    if f[u,i]<>f[v,i] then
    begin
      u:=f[u,i];v:=f[v,i];
    end;
  if u=v then exit(u) else exit(f[u,0]);
end;

procedure ins(u,v:longint);
begin
  fa[v]:=u;
end;

procedure qsort(l,r:longint);
var i,j,x:longint;
begin
  i:=l;j:=r;x:=tmp[(i+j)div 2];
  repeat
    while cmp(tmp[i],x) do inc(i);
    while cmp(x,tmp[j]) do dec(j);
    if i<=j then
    begin
      swap(tmp[i],tmp[j]);
      inc(i);dec(j);
    end;
  until i>j;
  if i<r then qsort(i,r);
  if l<j then qsort(l,j);
end;

function dis(u,v:longint):longint;
begin
  exit(dep[u]+dep[v]-2*dep[lca(u,v)]);
end;


procedure sol(u,v:longint);
var i,t1,t2,x,mid,nxt:longint;
begin
  x:=v;
  for i:=bin[dep[v]] downto 0 do
    if dep[f[x,i]]>dep[u] then x:=f[x,i];
  dec(rem[u],size[x]);
  if bel[u]=bel[v] then
  begin
    inc(cnt[bel[u]],size[x]-size[v]);
    exit;
  end;
  mid:=v;
  for i:=bin[dep[v]] downto 0 do
  begin
    nxt:=f[mid,i];
    if dep[nxt]<=dep[u] then continue;
    t1:=dis(bel[u],nxt);t2:=dis(bel[v],nxt);
    if(t1>t2)or((t1=t2)and(bel[u]>bel[v])) then mid:=nxt;
  end;
  inc(cnt[bel[u]],size[x]-size[mid]);
  inc(cnt[bel[v]],size[mid]-size[v]);
end;

procedure solve;
var i,j,ff,top,x,k,tot,t1,t2:longint;
begin
  readln(k);
  for i:=1 to k do
  begin
    read(h[i]);vis[h[i]]:=true;cnt[h[i]]:=0;id[i]:=i;
  end;
  sort(1,k);
  st[1]:=1;top:=1;tmp[1]:=1;tot:=1;
  if vis[1] then bel[1]:=1 else bel[1]:=0;
  for i:=1 to k do
  begin
    if h[i]=st[top] then continue;
    x:=h[i];ff:=lca(x,st[top]);
    while(top>1)and(dep[ff]<dep[st[top-1]]) do
    begin
      ins(st[top-1],st[top]);dec(top);
    end;
    if st[top]<>ff then ins(ff,st[top]);
    if st[top-1]<>ff then
    begin
      if tmp[tot]<>ff then
      begin
        inc(tot);tmp[tot]:=ff;
      end;
      st[top]:=ff;
      if vis[ff] then bel[ff]:=ff else bel[ff]:=0;
    end else dec(top);
    inc(top);st[top]:=x;inc(tot);tmp[tot]:=x;
    if vis[x] then bel[x]:=x else bel[x]:=0;
  end;
  while top>1 do
  begin
    ins(st[top-1],st[top]);dec(top);
  end;
  qsort(1,tot);
  for j:=tot downto 2 do
  begin
    i:=tmp[j];
    t1:=dis(fa[i],bel[i]);t2:=dis(fa[i],bel[fa[i]]);
    if(t1<t2)or((t1=t2)and(bel[i]<bel[fa[i]]))or(bel[fa[i]]=0) then
      bel[fa[i]]:=bel[i];
  end;
  for j:=1 to tot do
  begin
    i:=tmp[j];
    rem[i]:=size[i];if i=1 then continue;
    t1:=dis(i,bel[i]);t2:=dis(i,bel[fa[i]]);
    if(t1>t2)or((t1=t2)and(bel[fa[i]]<bel[i]))or(bel[i]=0) then
      bel[i]:=bel[fa[i]];
  end;
  for i:=2 to tot do
    sol(fa[tmp[i]],tmp[i]);
  for i:=1 to tot do inc(cnt[bel[tmp[i]]],rem[tmp[i]]);
  for i:=1 to k do ans[id[i]]:=cnt[h[i]];
  for i:=1 to k do vis[h[i]]:=false;
  for i:=1 to k do write(ans[i],' ');writeln;
end;

begin
  //assign(input,'1.in');reset(input);
  readln(n);
  fillchar(head,sizeof(head),0);
  for i:=1 to n-1 do
  begin
    readln(u,v);add(u,v);add(v,u);
  end;
  bin[1]:=0;
  for i:=2 to n do
    if i and(i-1)=0 then bin[i]:=bin[i-1]+1 else bin[i]:=bin[i-1];
  dep[1]:=0;time:=0;
  dfs(1);
  readln(m);
  for i:=1 to m do
  begin
    solve;
  end;
end.