bzoj4516: [Sdoi2016]生成魔咒

4516: [Sdoi2016]生成魔咒

Time Limit: 10 Sec  Memory Limit: 128 MB
Submit: 710  Solved: 393
[Submit][Status][Discuss]

Description

魔咒串由许多魔咒字符组成，魔咒字符可以用数字表示。例如可以将魔咒字符 1、2 拼凑起来形成一个魔咒串 [1,2]。

一个魔咒串 S 的非空字串被称为魔咒串 S 的生成魔咒。

例如 S=[1,2,1] 时，它的生成魔咒有 [1]、[2]、[1,2]、[2,1]、[1,2,1] 五种。S=[1,1,1] 时，它的生成魔咒有 [1]、

[1,1]、[1,1,1] 三种。最初 S 为空串。共进行 n 次操作，每次操作是在 S 的结尾加入一个魔咒字符。每次操作后都

需要求出，当前的魔咒串 S 共有多少种生成魔咒。

 

Input

 

第一行一个整数 n。

第二行 n 个数，第 i 个数表示第 i 次操作加入的魔咒字符。

1≤n≤100000。,用来表示魔咒字符的数字 x 满足 1≤x≤10^9

Output

输出 n 行，每行一个数。第 i 行的数表示第 i 次操作后 S 的生成魔咒数量

 

Sample Input

7
1 2 3 3 3 1 2

Sample Output

1
3
6
9
12
17
22

 

题解

这题就是求有多少个不同子串……不过首先我不会SAM，其次pascal没有set

于是我就用后缀数组+fhqtreap强行写了一发……首先把串反过来跑后缀数组求出h数组，之后每次插入一个字符就是相当于多了一个新后缀，查一下这个后缀在当前已加入的后缀里rank的前驱后继，然后求一下最长公共前缀，后缀长度减去最长公共前缀就是加入一个字符所增加的子串个数

1A赞啊>_<

program j01;
const maxn=100086;
type xx=record w,id:longint; end;
var op:array[0..maxn]of xx;
    sa,tsa,rank,trank,sum,s,mn,h:array[0..maxn]of longint;
    st:array[0..20,0..maxn]of longint;
    len,tot,i,l,r,root,k1,k2:longint;
    t:array[0..maxn]of record f,w,l,r:longint; end;
    ans:array[0..maxn]of int64;
    now,tmp:int64;

procedure swap(var a,b:longint);
var c:longint;
begin
  c:=a;a:=b;b:=c;
end;

function max(a,b:longint):longint;
begin
  if a>b then exit(a) else exit(b);
end;

function min(a,b:longint):longint;
begin
  if a<b then exit(a) else exit(b);
end;

procedure qsort(l,r:longint);
var i,j,x:longint;y:xx;
begin
  i:=l;j:=r;x:=op[(i+j)div 2].w;
  repeat
    while op[i].w<x do inc(i);
    while x<op[j].w do dec(j);
    if i<=j then
    begin
      y:=op[i];op[i]:=op[j];op[j]:=y;
      inc(i);dec(j);
    end;
  until i>j;
  if i<r then qsort(i,r);
  if l<j then qsort(l,j);
end;

procedure disc;
var i:longint;
begin
  qsort(1,len);
  tot:=1;s[op[1].id]:=1;
  for i:=2 to len do
  begin
    if(op[i].w<>op[i-1].w)then inc(tot);
    s[op[i].id]:=tot
  end;
end;

procedure getsa;
var i,j,m,p:longint;
begin
  fillchar(sum,sizeof(sum),0);m:=tot;
  for i:=1 to len do rank[i]:=s[i];
  for i:=1 to len do inc(sum[rank[i]]);
  for i:=1 to m do inc(sum[i],sum[i-1]);
  for i:=len downto 1 do
  begin
    sa[sum[rank[i]]]:=i;dec(sum[rank[i]]);
  end;
  m:=1;trank[sa[1]]:=1;
  for i:=2 to len do
  begin
    if(rank[sa[i]]<>rank[sa[i-1]])then inc(m);
    trank[sa[i]]:=m;
  end;
  j:=1;rank:=trank;
  while m<len do
  begin
    fillchar(sum,sizeof(sum),0);p:=0;
    for i:=len-j+1 to len do
    begin
      inc(p);tsa[p]:=i;
    end;
    for i:=1 to len do
      if sa[i]>j then
      begin
        inc(p);tsa[p]:=sa[i]-j;
      end;
    for i:=1 to len do inc(sum[rank[i]]);
    for i:=1 to m do inc(sum[i],sum[i-1]);
    for i:=len downto 1 do
    begin
      sa[sum[rank[tsa[i]]]]:=tsa[i];dec(sum[rank[tsa[i]]]);
    end;
    m:=1;trank[sa[1]]:=1;
    for i:=2 to len do
    begin
      if(rank[sa[i]]<>rank[sa[i-1]])or(rank[sa[i]+j]<>rank[sa[i-1]+j])then
        inc(m);
      trank[sa[i]]:=m;
    end;
    j:=j*2;rank:=trank;
  end;
end;

procedure geth;
var i,j,k:longint;
begin
  k:=0;
  for i:=1 to len do
  begin
    if rank[i]=1 then
    begin
      h[rank[i]]:=0;continue;
    end;
    j:=sa[rank[i]-1];
    while(s[i+k]=s[j+k])do inc(k);
    h[rank[i]]:=k;
    if k>0 then dec(k);
  end;
end;

procedure getst;
var i,j,a,b:longint;
begin
  mn[0]:=-1;
  for i:=1 to len do
    if i and(i-1)=0 then mn[i]:=mn[i-1]+1 else mn[i]:=mn[i-1];
  for i:=1 to len do st[0,i]:=h[i];
  for i:=1 to mn[len] do
    for j:=1 to len+1-(1 shl i) do
      st[i,j]:=min(st[i-1,j],st[i-1,j+(1 shl(i-1))]);
end;

function ask(a,b:longint):longint;
var d:longint;
begin
  if a>b then swap(a,b);
  d:=mn[b-a+1];
  exit(min(st[d,a],st[d,b-(1 shl d)+1]));
end;

procedure split(i,x:longint;var k1,k2:longint);
begin
  if i=0 then
  begin
    k1:=0;k2:=0;exit;
  end;
  if t[i].w<x then
  begin
    k1:=i;split(t[i].r,x,t[i].r,k2);
  end else
  begin
    k2:=i;split(t[i].l,x,k1,t[i].l);
  end;
end;

function merge(x,y:longint):longint;
begin
  if(x=0)and(y=0) then exit(x+y);
  if t[x].f>t[y].f then
  begin
    t[x].r:=merge(t[x].r,y);exit(x);
  end else
  begin
    t[y].l:=merge(x,t[y].l);exit(y);
  end;
end;

begin
  randomize;
  readln(len);
  for i:=1 to len do
  begin
    read(s[i]);op[i].id:=i;op[i].w:=s[i];
  end;
  disc;for i:=1 to len div 2 do swap(s[i],s[len-i+1]);
  getsa;geth;
  getst;
  root:=0;
  for i:=len downto 1 do
  begin
    split(root,rank[i],k1,k2);
    l:=k1;while t[l].r>0 do l:=t[l].r;
    r:=k2;while t[r].l>0 do r:=t[r].l;
    t[i].f:=random(maxlongint);t[i].w:=rank[i];
    root:=merge(merge(k1,i),k2);
    tmp:=0;
    if l>0 then tmp:=max(tmp,ask(rank[l]+1,rank[i]));
    if r>0 then tmp:=max(tmp,ask(rank[i]+1,rank[r]));
    now:=now+len-i+1-tmp;
    writeln(now);
  end;
end.