CEOI2004 锯木厂选址

编号山脚的树是1

w[i] 表示从1号到i号节点的树的总质量。

d[i] 表示第i棵树距离山脚的锯木厂的距离。

g[i] 表示从i到n棵树都运到i地的锯木厂所用的费用。

h[i] 表示从1到i棵树都运到山底锯木厂所用的费用。

f[i] 表示中间的锯木厂建设在i处所用过的最小费用。

很容易写出朴素方程  f[i] = h[i-1] + g[j] +　h[j-1] - h[i] - (w[j-1] - w[i])*d[i]

进行一下化简变换。

令t[i]=g[x]+h[x-1]

得到(t[x]-t[y])/(w[x-1]-w[y-1])>d[i]

注意当前你的i是倒着循环的，所以凸包要反着画，斜率之间的关系也因此而发生改变。

 

program wood(input,output);
var
    h     :array[0..25000] of int64;
    f,g   :array[0..25000] of int64;
    w     :array[0..25000] of int64;
    d     :array[0..25000] of int64;
    q      :array[0..25000] of longint;
    n        :longint;
    answer:int64;
procedure init;
var
    i:longint;
begin
    readln(n);
    for i:=n downto 1 do
        readln(w[i],d[i]);
end;{ init }
procedure change();
var
    i:longint;
begin
    for i:=1 to n do
    begin
        w[i]:=w[i-1]+w[i];
        d[i]:=d[i-1]+d[i];
        h[i]:=h[i-1]+(w[i]-w[i-1])*d[i];
    end;
    for i:=n downto 1 do
        g[i]:=g[i+1]+(w[n]-w[i])*(d[i+1]-d[i]);
end;{ change }
function K(x,y:longint):double;
begin
    exit((g[x]+h[x-1]-g[y]-h[y-1])/(w[x-1]-w[y-1]));
end;{ K }
procedure main;
var
    i         :longint;
    head,tail:longint;
    bestK     :double;
begin
    head:=1;
    tail:=1;
    q[1]:=n;
    f[n]:=0;
    answer:=maxlongint;
    for i:=n-1 downto 1 do
    begin
        bestK:=d[i];
        while (tail-head+1>=2)and(k(q[head+1],q[head])>=bestk) do
            inc(head);
        f[i]:=h[i-1]+g[q[head]]+h[q[head]-1]-h[i]-d[i]*(w[q[head]-1]-w[i]);
        while (tail-head+1>=2)and(k(q[tail],q[tail-1])<k(i,q[tail])) do
            dec(tail);
        inc(tail);
        q[tail]:=i;
        if f[i]<answer then
            answer:=f[i];
    end;
end;{ main }
procedure print;
begin
    writeln(answer);
end;{ print }
begin
    assign(input,'wood.in');reset(input);
    assign(output,'wood.out');rewrite(output);
    init;
    change;
    main;
    print;
    close(input);
    close(output);
end.