NOI2010 海拔

又是一道平面图的题，有向边的处理要注意一下，向右的向上连，向下的向右连，向左的向下连，向上的向左连，然后转化即可，对于向上，左的，边界处的边没有必要连，最后还得用dijkstra，反正我的spfa超时2个点，不知道它牛怎么过的，只好打堆了...

program noi2010(input,output);
type
   node    = ^link;
   link    = record
         goal,w : longint;
         next   : node;
      end;
var
   l           : array[0..251000] of node;
   d           : array[0..251000] of int64;
   v           : array[0..251000] of boolean;
   heap,pos    : array[0..251000] of longint;
   number      : array[0..501,0..501] of longint;
   final,start : longint;
   n,tot       : longint;
procedure add(xx,yy,ww: longint );
var
   tt : node;
begin
   new(tt);
   tt^.goal:=yy;
   tt^.w:=ww;
   tt^.next:=l[xx];
   l[xx]:=tt;
end; { add }
procedure init;
var
   i,j : longint;
   sum : longint;
begin
   readln(n);
   start:=0;
   final:=n*n+1;
   sum:=0;
   for i:=0 to n*n+1 do
      l[i]:=nil;
   for i:=1 to n do
      for j:=1 to n do
      begin
     inc(sum);
     number[i,j]:=sum;
      end;
end; { init }
procedure make_graph();
var
   i,j,ww : longint;
begin
   for i:=1 to n+1 do
      for j:=1 to n do
      begin
     readln(ww);
     if i=1 then
        add(number[i,j],final,ww)
     else
        if i=n+1 then
           add(start,number[i-1,j],ww)
        else
           add(number[i,j],number[i-1,j],ww);
      end;
   for i:=1 to n do
      for j:=1 to n+1 do
      begin
     readln(ww);
     if j=1 then
        add(start,number[i,j],ww)
     else
        if j=n+1 then
           add(number[i,j-1],final,ww)
        else
           add(number[i,j-1],number[i,j],ww);
      end;
   for i:=1 to n+1 do
      for j:=1 to n do
      begin
     readln(ww);
     if (i<>1)and(i<>n+1) then
        add(number[i-1,j],number[i,j],ww);
      end;
   for i:=1 to n do
      for j:=1 to n+1 do
      begin
     readln(ww);
     if (j<>1)and(j<>n+1) then
        add(number[i,j],number[i,j-1],ww);
      end;
end; { make_graph }
procedure swap(var aa,bb :longint );
var
   tt : longint;
begin
   tt:=aa;
   aa:=bb;
   bb:=tt;
end; { swap }
procedure up(now: longint );
begin
   while (d[heap[now]]<d[heap[now>>1]]) do
   begin
      swap(heap[now],heap[now>>1]);
      pos[heap[now]]:=now;
      pos[heap[now>>1]]:=now>>1;
      now:=now>>1;
   end;
end; { up }
procedure down(now :longint );
var
   tmp : longint;
begin
   while now<=(tot>>1) do
   begin
      tmp:=now*2;
      if (tmp+1<=tot)and(d[heap[tmp+1]]<d[heap[tmp]]) then
     inc(tmp);
      if d[heap[tmp]]<d[heap[now]] then
      begin
     swap(heap[tmp],heap[now]);
     pos[heap[tmp]]:=tmp;
     pos[heap[now]]:=now;
     now:=tmp;
      end
      else
     break;
   end;
end; { down }
procedure insect(x :longint );
begin
   inc(tot);
   heap[tot]:=x;
   pos[x]:=tot;
   up(tot);
end; { insect }
procedure change(x : longint;ww:int64 );
begin
   d[x]:=ww;
   up(pos[x]);
end; { change }
function delete():longint;
begin
   delete:=heap[1];
   swap(heap[1],heap[tot]);
   dec(tot);
   pos[heap[1]]:=1;
   down(1);
end; { delete }
procedure dijkstra;
var
   i,tmp : longint;
   t     : node;
begin
   fillchar(d,sizeof(d),63);
   fillchar(v,sizeof(v),false);
   d[0]:=0;
   for i:=start to final do
      insect(i);
   for i:=start to final do
   begin
      tmp:=delete();
      v[tmp]:=true;
      t:=l[tmp];
      while t<>nil do
      begin
     if (not v[t^.goal])and(d[tmp]+t^.w<d[t^.goal]) then
        change(t^.goal,d[tmp]+t^.w);
     t:=t^.next;
      end;
   end;
end; { dijkstra }
procedure print;
begin
   writeln(d[final]);
end; { print }
begin
   assign(input,'altitude.in');reset(input);
   assign(output,'altitude.out');rewrite(output);
   init;
   make_graph;
   dijkstra;
   print;
   close(input);
   close(output);
end.