求原图和补图的三元环个数

2.1 题目描述
给定一个无自环重边的无向图，求这个图的三元环¹
的个数以及补图²的三元环个数。
2.2 输入格式
第一行 2 个数n,m ，分别表示图的点数、边数。
接下来 m行，每行两个数 u, v ，表示一条连接u, v 的无向边。
2.3 输出格式
一行两个数，依次表示原图的三元环个数以及补图的三元环的个数。
2.4 样例输入
5 5
1 2
1 3
2 3
2 4
3 4

2.5 样例输出
2 1
2.6 数据范围
对于 30%的数据：n ≤ 100
对于 60%的数据：m ≤ 500
对于 100%的数据：n ≤ 105
,m ≤ 105
2.7 评分方式
如果你两个数均输出正确，得 10分。
否则如果两个数中任意一个正确或者两个数的和正确，得 6 分。
否则不得分。

1大小为 3的环。即一个无序三元组 (x, y, z) 使得任意两点之间都有边

2一条连接(u, v)(u = v) 的边，如果在原图中出现了，那么在补图中不会出现，否则一定会在补图中出现。

 

直接求两个图的三元环个数并不好求，那么如果我们知道了原图和补图三元环个数的和，则只要求其中一种就行了。

但是直接求和也不好求，这时我们可以求那些既不存在于原图也不存在于补图的三元环个数。

可知这些三元环一定是至少有一条边在原图，至少有一条边在补图的，于是它们在两图中都是残缺的。

那么我们记录一下每个点在原图中的度d[i]，d[i]*(n-1-d[i])就是经过i点的不在原图也不在补图的三元环个数。（一条边在原图一条边不在，n-1-d[i]为i在补图中的度）

由于我们对每个点都进行了计算，所以算出来的值是两倍的，需要除以2。

全图中三元环个数为，用它减去我们算出来的值就得出了原图和补图三元环个数之和。

现在我们开始统计原图中三元环个数。直接暴力枚举有共点的两条边，然后查找另外两个点有木有边。

我是用的小PO的先把边按照双关键字排序然后二分查找的方法。由于记的是单向边所以不用除以2

 

program Neayo;
const
        inf='triangle.in';
        ouf='triangle.out';
var
        i,j,k,m,n,e:longint;
        sum,ans:int64;
        d,s,t,l,r:array[0..100001]of longint;

function c(x:int64):int64;
begin
        c:=(x*(x-1)*int64(x-2)) div 6;
end;
procedure qsort(l,r:longint);
var x,x1,x2,i,j:longint;
begin
     i:=l;j:=r;
     x1:=s[(l+r)shr 1];
     x2:=t[(l+r)shr 1];
     repeat
           while (s[i]<x1)or((s[i]=x1)and(t[i]<x2))do inc(i);
           while (s[j]>x1)or((s[j]=x1)and(t[j]>x2))do dec(j);
           if i<=j then
           begin
                x:=s[i];s[i]:=s[j];s[j]:=x;
                x:=t[i];t[i]:=t[j];t[j]:=x;
                inc(i);
                dec(j);
           end;
     until(i>j);
     if i<r then qsort(i,r);
     if j>l then qsort(l,j);
end;
procedure init;
var x,y,tmp:int64;
begin
     assign(input,inf);assign(output,ouf);
     reset(input);rewrite(output);
     readln(n,m);
     for i:=1 to m do
     begin
          readln(x,y);
          if x>y then begin tmp:=x;x:=y;y:=tmp;end;
          s[i]:=x;t[i]:=y;
          inc(d[x]);
          inc(d[y]);
     end;
     sum:=0;
     for i:=1 to n do
      sum:=sum+d[i]*(n-1-d[i]);
     sum:=sum div 2;
     sum:=c(n)-sum;
     close(input);
end;
//=================
function find(x,l,r:longint):boolean;
var mid:longint;
begin

     while l<=r do
     begin
          mid:=(l+r)shr 1;
          if (t[mid]>x)then r:=mid-1
          else if (t[mid]=x) then exit(true)
          else l:=mid+1;
     end;
     exit(false);
end;
procedure go;
var
    t1,t2:int64;
    have:boolean;
begin
     qsort(1,m);
     for i:=1 to m+1 do
     if s[i]<>s[i-1]then
     begin
          r[s[i-1]]:=i-1;
          l[s[i]]:=i;
          r[s[i]]:=i;
     end;
     for k:=1 to n do
     begin
          for i:=l[k] to r[k]-1 do
          begin
               t1:=t[i];
               for j:=i+1 to r[k] do
               begin
                    t2:=t[j];
                    if find(t2,l[t1],r[t1]) then inc(ans);
               end;
          end;
     end;
     writeln(ans,' ',sum-ans);
end;
begin
     init;
     go;
     close(output);
end.