Neo4J之Cypher 第三章
Cypher是一种声明式图形查询语言，可用于表达性和高效的图形查询和更新。它旨在同时适合开发人员和运营专业人员。Cypher的设计既简单又强大。可以轻松表达高度复杂的数据库查询，使您可以专注于自己的域，而不会迷失在数据库访问中。
Cypher的结构基于英文散文和简洁的图像，使查询既易于编写，也易于阅读。
子句链接在一起，并且它们相互之间提供中间结果集。例如，来自一个MATCH子句的匹配变量将是存在下一个子句的上下文。查询语言由几个不同的子句组成。
MATCH：要匹配的图形模式。这是从图形中获取数据的最常用方法。WHERE：在自己的权利不是一个条款，但相当一部分MATCH，OPTIONAL MATCH和WITH。向模式添加约束，或过滤通过的中间结果WITH。RETURN：返回什么。
制造数据
CREATE (john:Person {name: 'John'})
CREATE (joe:Person {name: 'Joe'})
CREATE (steve:Person {name: 'Steve'})
CREATE (sara:Person {name: 'Sara'})
CREATE (maria:Person {name: 'Maria'})
CREATE (john)-[:FRIEND]->(joe)-[:FRIEND]->(steve)
例如，这是一个查询，该查询在返回“约翰”和找到的任何朋友之前，先找到一个名为“约翰”和“约翰的”朋友（虽然不是他的直接朋友）的用户。
MATCH (john {name: 'John'})-[:FRIEND]->()-[:FRIEND]->(fof)
RETURN john.name, fof.name
示例二:添加过滤条件的查询
找到所有关注过朋友的用户,并返回他们关注的朋友中以S开头的人的名字
MATCH (user)-[:FRIEND]->(follwer)
WHERE user.name IN ['Joe', 'John', 'Sara'] AND
follwer.name =~ 'S.*'
RETURN user.name, follwer.name
3.1.1模式Patterns
Neo4j图由节点和关系构成。节点可能还有标签和属性，关系可能还有类型和属性。节点表达实体，关系连接一对节点。节点可以看做关系型数据库中的表，但有一些不一样。节点的标签可以理解为不同的表名，属性类似数据库中的列，一个节点的数据类型类似关系数据库中的一行数据，拥有相同标签的节点通常具有类似的属性，但不必完全一样，这点和关系数据库中一张表中的行数据拥有相同列的是不一样的。
节点和模式都是低层次的构建块，单个节点或关系都只能表示很少的信息，但是模型可以将很多节点和关系编码为任意复杂的想法
3.1.2.1节点语法
() 匿名节点 可以匹配所有节点，如果想在其余地方引用这个节点，可以添加一个变量，如(matrix)
-- :表示无方向关系
-->:有方向关系
-[rale]->:给关系赋予一个变量,方便对其操作
-[rale:friend]->:匹配关系类型为friend类型的关系,并赋予rale变量接收
-[rale:friend {long_time:2}]->:给关系加条件,匹配friend类型的关系且属性long_time为2
3.1.2.3 模式语法
将节点和关系的语法组合在一起可以表达模式
(keanu:Person:Actor {name: "Keanu Reeves"})-[role:ACTED_IN {roles: ["Neo"]}]->
(matrix:Movie {title: "The Matrix"})
3.1.2.4模式变量:
同时如果想要关系语法不想重复写,想要多个语句写的时候减少重复写,可以将关系语法赋予一个变量
acted_in = (people:Person)-[:acted_in]->(movie:Movie)
这样acted_in 就可以写到多个查询语句中,减少重复编写
3.1.3.1更新语句
一个Cypher查询部分不能同时匹配和更新图数据,每个部分要么读取和匹配图,要么更新它,如果需要读取并且更新图
它需要两部分:读取和更新.
对于读取,Cypher采用惰性加载,直到需要返回结果的时候才实际的去匹配数据.
with用来连接这两部分
使用with语句进行聚合过滤查询,示例:
MATCH (n {name:"John"})-[:friend]-(friend)
WITH n, count(friend) as friendsCount
WHERE friendsCount>3
RETURN n, friendsCount
使用with语句进行聚合更新,示例:
MATCH (n {name:'John'})-[:friend]-(friend)
WITH n,count(friend) as friendsCount
SET n.friendsCount = friendsCount
RETURN n.friendsCount
3.1.3.2返回数据
任何查询都可以返回数据.RETURN语句有三个子句,分别为SKIP,LIMIT和ORDER BY
3.1.4事务
任何更新图的查询都运行在一个事务中,一个更新查询要么全部成功,要么全部失败
Cypher要么新创建一个事务,要么运行在一个已有的事务中:
如果上下文中没有事务,Cypher将会创建一个,一旦查询完成就提交该事务
如果运行上下文中已有事务,查询就会运行在该事务之中.直到事务成功提交之后,数据才会被存储
可以将多个查询作为单个事务去运行,保证数据正常
注意:事务中的查询结果是放在内存中的,一个事务如果查询量巨大会造成内存的大量使用
3.1.5唯一性
进行模式匹配时,默认不会多次匹配同一个图关系.比如匹配John朋友的朋友,不会将John自己也返回给John
示例:
1.先准备数据
在模式匹配时，neo4j确保不会在单个模式中多次找到相同图形关系的匹配。举例，在寻找朋友的朋友时，不会返回所述用户自身。
CREATE (adam:User { name: 'Adam' }),(pernilla:User { name: 'Pernilla' }),(david:User { name: 'David'}),(adam)-[:FRIEND]->(pernilla),(pernilla)-[:FRIEND]->(david)
寻找Adam朋友的朋友
MATCH (user:User { name: 'Adam' })-[r1:FRIEND]-()-[r2:FRIEND]-(friend_of_a_friend)
RETURN friend_of_a_friend.name AS fofName
因为r1和r2在同一个模式中，又是不同的变量名，所以不会返回同一条关系，即图形中的有向边。检验：在两个子句中用不同的变量名就不管用
MATCH (user:User { name: 'Adam' })-[r1:FRIEND]-(friend)
MATCH (friend)-[r2:FRIEND]-(friend_of_a_friend)
RETURN friend_of_a_friend.name AS fofName
但是只要在一个模式中，即使拆分了多个子模式也不会匹配到同一关系，如下所示。
MATCH (user:User { name: 'Adam' })-[r1:FRIEND]-(friend),(friend)-[r2:FRIEND]-(friend_of_a_friend)
RETURN friend_of_a_friend.name AS fofName
3.1.6兼容性
设置Cypher查询的版本
Neo4j数据库的Cypher也是会进行版本变化的.
可以在neo4j.conf配置中cypher.default_language_version 参数来设置Neo4j数据库使用哪个版本的Cypher语言
如果只是想在一个查询中指定版本,可以在查询语句的开头地方写上版本
比如:
Cypher 2.3
match(n) return(n)
目前的版本有3.1 3.0 2.3
