【ZJOI2017 Round2练习&BZOJ4826】D1T2 sf（主席树，单调栈）

题意：

思路：From http://blog.csdn.net/neither_nor/article/details/70211150

对每个点i，单调栈求出左边和右边第一个大于i的位置，记为l[i]和r[i]

那么(l[i],r[i])会产生p1的贡献

左端点为l[i]，右端点在[i+1,r-1]的点对都会产生p1的贡献

右端点为r[i]，左端点在[l+1,i-1]的点对都会产生p2的贡献

将点对看成平面上的点，横坐标左端点纵坐标右端点，上述贡献分别对应单点加和线段加

查询就是矩形求和

From MG：

考虑修改均为如(x,y1..y2)与(x1..x2,y)形式

因为询问均为矩形，则修改(y1..y2,x)与(x,y1..y2)等价

若统一转化为(x,y1..y2)形式，可用主席树维护

若统一转化为(y1..y2,x)形式，可用树状数组套主席树维护

注意点对(i,i)都有p1的贡献

var t:array[0..10000000]of record
                           a,s:int64;
                           l,r:longint;
                          end;
    d:array[1..1000000,1..4]of longint;
    l,r:array[1..300000]of longint;
    root,stk,a:array[0..300000]of longint;
    n,m,i,cnt,j,top,que,x,y,p1,p2:longint;
    ans:int64;

procedure update(l,r,x,y,v:longint;var p:longint);
var mid:longint;
begin
 if (l>x)or(x>y) then exit;
 inc(cnt); t[cnt]:=t[p]; p:=cnt;
 t[p].s:=t[p].s+int64(v)*(y-x+1);
 if (l=x)and(r=y) then
 begin
  t[p].a:=t[p].a+v;
  exit;
 end;
 mid:=(l+r)>>1;
 if y<=mid then update(l,mid,x,y,v,t[p].l)
  else if x>mid then update(mid+1,r,x,y,v,t[p].r)
  else
  begin
   update(l,mid,x,mid,v,t[p].l);
   update(mid+1,r,mid+1,y,v,t[p].r);
  end;
end;

procedure query(l,r,x,y,p1,p2:longint);
var mid:longint;
begin
 if (l=x)and(r=y) then
 begin
  ans:=ans+t[p1].s-t[p2].s;
  exit;
 end;
 ans:=ans+(t[p1].a-t[p2].a)*(y-x+1);
 mid:=(l+r)>>1;
 if y<=mid then query(l,mid,x,y,t[p1].l,t[p2].l)
  else if x>mid then query(mid+1,r,x,y,t[p1].r,t[p2].r)
  else
  begin
   query(l,mid,x,mid,t[p1].l,t[p2].l);
   query(mid+1,r,mid+1,y,t[p1].r,t[p2].r);
  end;
end;

procedure swap(var x,y:longint);
var t:longint;
begin
 t:=x; x:=y; y:=t;
end;

procedure qsort(l,r:longint);
var i,j,mid:longint;
begin
 i:=l; j:=r; mid:=d[(l+r)>>1,1];
 repeat
  while mid>d[i,1] do inc(i);
  while mid<d[j,1] do dec(j);
  if i<=j then
  begin
   swap(d[i,1],d[j,1]);
   swap(d[i,2],d[j,2]);
   swap(d[i,3],d[j,3]);
   swap(d[i,4],d[j,4]);
   inc(i); dec(j);
  end;
 until i>j;
 if l<j then qsort(l,j);
 if i<r then qsort(i,r);
end;

begin
 assign(input,'bzoj4826.in'); reset(input);
 assign(output,'bzoj4826.out'); rewrite(output);
 readln(n,que,p1,p2);
 for i:=1 to n do read(a[i]);
 top:=1; stk[top]:=0; a[0]:=maxlongint;
 for i:=1 to n do
 begin
  while (top>0)and(a[i]>a[stk[top]]) do dec(top);
  if top=1 then l[i]:=0
   else l[i]:=stk[top];
  inc(top); stk[top]:=i;
 end;
 top:=1; stk[top]:=n+1; a[n+1]:=maxlongint;
 for i:=n downto 1 do
 begin
  while (top>0)and(a[i]>a[stk[top]]) do dec(top);
  if top=1 then r[i]:=n+1
   else r[i]:=stk[top];
  inc(top); stk[top]:=i;
 end;
 for i:=1 to n do
 begin
  if (l[i]>0)and(r[i]<=n) then
  begin
   inc(m); d[m,1]:=l[i]; d[m,2]:=r[i]; d[m,3]:=r[i]; d[m,4]:=p1;
  end;
  if l[i]>0 then
  begin
   inc(m); d[m,1]:=l[i]; d[m,2]:=i+1; d[m,3]:=r[i]-1; d[m,4]:=p2;
  end;
  if r[i]<=n then
  begin
   inc(m); d[m,1]:=r[i]; d[m,2]:=l[i]+1; d[m,3]:=i-1; d[m,4]:=p2;
  end;
 end;
 qsort(1,m);
 j:=1;
 for i:=1 to n do
 begin
  root[i]:=root[i-1];
  while (j<=m)and(d[j,1]=i) do
  begin
   update(1,n,d[j,2],d[j,3],d[j,4],root[i]);
   inc(j);
  end;
 end;
 for i:=1 to que do
 begin
  readln(x,y);
  ans:=(y-x)*p1;
  query(1,n,x,y,root[y],root[x-1]);
  writeln(ans);
 end;
 close(input);
 close(output);
end.