【BZOJ3238】差异（后缀数组，单调栈）

题意：

思路：显然len(t[i])+len(t[j])这部分的和是一定的

那么问题就在于如何快速求出两两之间lcp之和

考虑将它们排名后用SA可以很方便的求出lcp，且对答案没有影响，因为形式都是数对

所以用SA求出height

每个位置的height作为lcp的区间为扩展到最左最右，直到height[x]<height[i]，height[y]<height[i]

这样合法的左区间为[x+1,i]，右区间为[i,y-1]

考虑如何维护一个支持寻找最靠近当前位置的比当前位置上的数小的位置

这个可以用两次单调栈维护

但还要考虑到重复计算的情况，比如有多个最小值覆盖了全部区域

我们可以在比较时其中一次取等号，一次不取

var x,y,sa,rank,height,wc,wd,a:array[0..600000]of longint;
    l,r:array[1..600000]of int64;
    stk:array[1..600000]of longint;
    n,i,m,top:longint;
    ans,j:int64;
    ch:ansistring;

function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;

function cmp(a,b,l:longint):boolean;
begin
 exit((y[a]=y[b])and(y[a+l]=y[b+l]));
end;

procedure swap(var x,y:longint);
var t:longint;
begin
 t:=x; x:=y; y:=t;
end;

procedure getsa(n:longint);
var i,j,p:longint;
begin
 for i:=0 to n-1 do
 begin
  x[i]:=a[i];
  inc(wc[x[i]]);
 end;
 for i:=1 to m-1 do wc[i]:=wc[i-1]+wc[i];
 for i:=n-1 downto 0 do
 begin
  dec(wc[x[i]]);
  sa[wc[x[i]]]:=i;
 end;
 j:=1; p:=1;
 while p<n do
 begin
  p:=0;
  for i:=n-j to n-1 do
  begin
   y[p]:=i; inc(p);
  end;
  for i:=0 to n-1 do
   if sa[i]>=j then begin y[p]:=sa[i]-j; inc(p); end;
  for i:=0 to n-1 do wd[i]:=x[y[i]];
  for i:=0 to m-1 do wc[i]:=0;
  for i:=0 to n-1 do inc(wc[wd[i]]);
  for i:=1 to m-1 do wc[i]:=wc[i-1]+wc[i];
  for i:=n-1 downto 0 do
  begin
   dec(wc[wd[i]]);
   sa[wc[wd[i]]]:=y[i];
  end;
  for i:=0 to n do swap(x[i],y[i]);
  p:=1; x[sa[0]]:=0;
  for i:=1 to n-1 do
   if cmp(sa[i-1],sa[i],j) then x[sa[i]]:=p-1
    else begin x[sa[i]]:=p; inc(p); end;
  j:=j<<1;
  m:=p;
 end;
end;

procedure getheight(n:longint);
var i,j,k:longint;
begin
 k:=0;
 for i:=1 to n do rank[sa[i]]:=i;
 for i:=0 to n-1 do
 begin
  if k>0 then dec(k);
  j:=sa[rank[i]-1];
  while a[i+k]=a[j+k] do inc(k);
  height[rank[i]]:=k;
 end;
end;

begin
 assign(input,'bzoj3238.in'); reset(input);
 assign(output,'bzoj3238.out'); rewrite(output);
 readln(ch);
 n:=length(ch);
 for i:=0 to n-1 do a[i]:=ord(ch[i+1])-ord('a')+1;
 a[n]:=0; m:=300;
 getsa(n+1);
 getheight(n);
 stk[1]:=1; height[1]:=-maxlongint; top:=1;
 for i:=2 to n do
 begin
  while (top>0)and(height[i]<height[stk[top]]) do dec(top);
  if stk[top]=1 then l[i]:=2
   else l[i]:=stk[top]+1;
  inc(top); stk[top]:=i;
 end;

 stk[1]:=n+1; height[n+1]:=-maxlongint; top:=1;
 for i:=n downto 2 do
 begin
  while (top>0)and(height[i]<=height[stk[top]]) do dec(top);
  if stk[top]=n+1 then r[i]:=n
   else r[i]:=stk[top]-1;
  inc(top); stk[top]:=i;
 end;


 ans:=int64(n-1)*int64(n)*(n+1) div 2;
 for i:=2 to n do ans:=ans-2*(-l[i]+i+1)*(r[i]-i+1)*height[i];
 //for i:=2 to n+1 do writeln(l[i],' ',r[i]);
 writeln(ans);
 close(input);
 close(output);
end.