【BZOJ4199&UOJ131】品酒大会（后缀数组，并查集）

题意：

 

两杯“r相似” （r>1）的酒同时也是“1 相似”、“2 相似”、……、“(r−1) 相似”的。

n<=300000 abs(a[i])<=10^9

思路：对于i,j两个后缀，它们的贡献只与它们的lcp有关

而lcp又是它们之间height的最小值

所以可以把height从大到小排序

然后用并查集合并最值，方案数之类的

每次合并的都是排名相邻的一对后缀，相当于一段不相交的线段

每个集合中的lcp即为height的最小值

将r相似的加到r-1相似中

被UOJ的extra卡了一发，原来是0相似的初始最大值忘记初始化了

const oo=1<<62;
var sum,f:array[0..310000]of int64;
    sa,rank,height,id,mx,mn,size,a,fa,x,y,wc,wd,b:array[0..310000]of longint;
    n,m,i,p,q,t:longint;
    ch:ansistring;
procedure swap(var x,y:longint);
var t:longint;
begin
 t:=x; x:=y; y:=t;
end;

function max(x,y:int64):int64;
begin
 if x>y then exit(x);
 exit(y);
end;

function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;

procedure qsort(l,r:longint);
var i,j,mid:longint;
begin
 i:=l; j:=r; mid:=height[id[(l+r)>>1]];
 repeat
  while mid<height[id[i]] do inc(i);
  while mid>height[id[j]] do dec(j);
  if i<=j then
  begin
   swap(id[i],id[j]);
   inc(i); dec(j);
  end;
 until i>j;
 if l<j then qsort(l,j);
 if i<r then qsort(i,r);
end;

function find(k:longint):longint;
begin
 if fa[k]<>k then fa[k]:=find(fa[k]);
 find:=fa[k];
end;

procedure merge(x,y:longint);
begin
 size[y]:=size[y]+size[x];
 mx[y]:=max(mx[x],mx[y]);
 mn[y]:=min(mn[x],mn[y]);
 fa[x]:=y;
end;

function cmp(a,b,l:longint):boolean;
begin
 exit((y[a]=y[b])and(y[a+l]=y[b+l]));
end;

procedure getsa(n:longint);
var i,j,p:longint;
begin
 for i:=0 to n-1 do
 begin
  x[i]:=a[i];
  inc(wc[a[i]]);
 end;
 for i:=1 to m-1 do wc[i]:=wc[i-1]+wc[i];
 for i:=n-1 downto 0 do
 begin
  dec(wc[x[i]]);
  sa[wc[x[i]]]:=i;
 end;
 j:=1; p:=1;
 while p<n do
 begin
  p:=0;
  for i:=n-j to n-1 do
  begin
   y[p]:=i; inc(p);
  end;
  for i:=0 to n-1 do
   if sa[i]>=j then begin y[p]:=sa[i]-j; inc(p); end;
  for i:=0 to n-1 do wd[i]:=x[y[i]];
  for i:=0 to m-1 do wc[i]:=0;
  for i:=0 to n-1 do inc(wc[wd[i]]);
  for i:=1 to m-1 do wc[i]:=wc[i-1]+wc[i];
  for i:=n-1 downto 0 do
  begin
   dec(wc[wd[i]]);
   sa[wc[wd[i]]]:=y[i];
  end;
  for i:=0 to n do swap(x[i],y[i]);
  p:=1; x[sa[0]]:=0;
  for i:=1 to n-1 do
   if cmp(sa[i-1],sa[i],j) then x[sa[i]]:=p-1
    else
    begin
     x[sa[i]]:=p; inc(p);
    end;
  j:=j*2;
  m:=p;
 end;
end;

procedure getheight(n:longint);
var i,j,k:longint;
begin
 for i:=1 to n do rank[sa[i]]:=i;
 k:=0;
 for i:=0 to n-1 do
 begin
  if k>0 then dec(k);
  j:=sa[rank[i]-1];
  while a[i+k]=a[j+k] do inc(k);
  height[rank[i]]:=k;
 end;
end;

begin
 assign(input,'bzoj4199.in'); reset(input);
 assign(output,'bzoj4199.out'); rewrite(output);
 readln(n);
 readln(ch);
 for i:=0 to n-1 do a[i]:=ord(ch[i+1])-ord('a')+1;
 a[n]:=0; m:=300;
 getsa(n+1);
 getheight(n);
 for i:=0 to n-1 do read(b[i]);
 for i:=1 to n do
 begin
  fa[i]:=i;
  size[i]:=1; mx[i]:=b[sa[i]]; mn[i]:=mx[i];
  f[i]:=-oo;
 end;
 f[0]:=-oo;
 for i:=1 to n-1 do id[i]:=i+1;
 qsort(1,n-1);
 for i:=1 to n-1 do
 begin
  p:=find(id[i]-1); q:=find(id[i]);
  t:=height[id[i]];
  sum[t]:=sum[t]+int64(size[p])*size[q];
  f[t]:=max(f[t],int64(mx[p])*mx[q]);
  f[t]:=max(f[t],int64(mx[p])*mn[q]);
  f[t]:=max(f[t],int64(mn[p])*mx[q]);
  f[t]:=max(f[t],int64(mn[p])*mn[q]);
  merge(p,q);
 end;
 for i:=n-2 downto 0 do
 begin
  sum[i]:=sum[i]+sum[i+1];
  f[i]:=max(f[i],f[i+1]);
 end;
 for i:=0 to n-1 do
  if f[i]>-oo then writeln(sum[i],' ',f[i])
   else writeln(0,' ',0);

 close(input);
 close(output);
end.