【BZOJ1014】火星人prefix（splay，Hash）

题意：

、

思路：

 

const mo=9000011;
var t:array[0..200000,0..1]of longint;
    sum,size,fa,a,b,id,mi:array[0..200000]of longint;
    n,m,i,x,y,s,k,j,cnt,root:longint;
    ch:ansistring;
 
procedure swap(var x,y:longint);
var t:longint;
begin
 t:=x; x:=y; y:=t;
end;
 
procedure pushup(x:longint);
var l,r:longint;
begin
 l:=t[x,0]; r:=t[x,1];
 size[x]:=size[l]+size[r]+1;
 sum[x]:=(sum[l]+int64(mi[size[l]])*b[x]+int64(mi[size[l]+1])*sum[r]) mod mo;
 // sum[x]:=(sum[r]+int64(mi[size[r]])*b[x]+int64(mi[size[r]+1])*sum[l]) mod mo; 也可以
end;
 
function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;
 
procedure rotate(x:longint;var k:longint);
var y,z,l,r:longint;
begin
 y:=fa[x]; z:=fa[y];
 if t[y,0]=x then l:=0
  else l:=1;
 r:=l xor 1;
 if y<>k then
 begin
  if t[z,0]=y then t[z,0]:=x
   else t[z,1]:=x;
 end
  else k:=x;
 fa[x]:=z; fa[y]:=x; fa[t[x,r]]:=y;
 t[y,l]:=t[x,r]; t[x,r]:=y;
 pushup(y);
 pushup(x);
end;
 
procedure splay(x:longint;var k:longint);
var y,z:longint;
begin
 while x<>k do
 begin
  y:=fa[x]; z:=fa[y];
  if y<>k then
  begin
   if (t[y,0]=x)xor(t[z,0]=y) then rotate(x,k)
    else rotate(y,k);
  end
   else k:=x;
  rotate(x,k);
 end;
end;
 
procedure build(l,r,x:longint);
var mid,now,last:longint;
begin
 if l>r then exit;
 now:=id[l]; last:=id[x];
 if l=r then
 begin
  sum[now]:=a[now]; b[now]:=a[now];
  fa[now]:=last; size[now]:=1;
  if l<x then t[last,0]:=now
   else t[last,1]:=now;
  exit;
 end;
 mid:=(l+r)>>1; now:=id[mid];
 build(l,mid-1,mid);
 build(mid+1,r,mid);
 b[now]:=a[mid]; fa[now]:=last;
 pushup(now);
 if mid<x then t[last,0]:=now
  else t[last,1]:=now;
end;
 
function kth(x:longint):longint;
var k,tmp:longint;
begin
 k:=root;
 while k<>0 do
 begin
  tmp:=size[t[k,0]]+1;
  if tmp=x then exit(k);
  if tmp>x then k:=t[k,0]
   else
   begin
    x:=x-tmp;
    k:=t[k,1];
   end;
 end;
end;
 
function query(k,tot:longint):longint;
var x,y:longint;
begin
 x:=kth(k); y:=kth(k+tot+1);
 splay(x,root);
 splay(y,t[x,1]);
 exit(sum[t[y,0]]);
end;
 
function ask(x,y:longint):longint;
var l,r,mid,last:longint;
begin
 l:=1; r:=min(cnt-x,cnt-y)-1; last:=0;
 while l<=r do
 begin
  mid:=(l+r)>>1;
  if query(x,mid)=query(y,mid) then begin last:=mid; l:=mid+1; end
   else r:=mid-1;
 end;
 exit(last);
end;
 
procedure ins(x,y:longint);
var p,q,z:longint;
begin
 p:=kth(x+1);
 q:=kth(x+2);
 splay(p,root);
 splay(q,t[p,1]);
 inc(cnt); z:=cnt; t[q,0]:=z;
 fa[z]:=q; b[z]:=y;
 pushup(z);
 pushup(q);
 pushup(p);
end;
 
begin
 
 readln(ch);
 n:=length(ch);
 for i:=2 to n+1 do a[i]:=ord(ch[i-1])-ord('a')+1;
 mi[0]:=1;
 for i:=1 to 150000 do mi[i]:=mi[i-1]*27 mod mo;
 for i:=1 to n+2 do id[i]:=i;
 build(1,n+2,0); root:=(n+3)>>1; cnt:=n+2;
 readln(m);
 for i:=1 to m do
 begin
  readln(ch); k:=length(ch); s:=0; x:=0; y:=0;
  for j:=3 to k do
  begin
   if ch[j]=' ' then begin inc(s); continue; end;
   if s=0 then x:=x*10+ord(ch[j])-ord('0');
   if s=1 then y:=y*10+ord(ch[j])-ord('0');
  end;
  if ch[1]='Q' then writeln(ask(x,y));
  if ch[1]='R' then
  begin
   y:=y+ord('0')-ord('a')+1;
   k:=kth(x+1); splay(k,root);
   b[k]:=y; pushup(root);
  end;
  if ch[1]='I' then
  begin
   y:=y+ord('0')-ord('a')+1;
   ins(x,y);
  end;
 end;
 
end.