【BZOJ2693】jzptab（莫比乌斯反演）

题意：

T <= 10000

N, M<=10000000

思路：同BZOJ2154

From http://www.cnblogs.com/ST-Saint/p/4617247.html

对于一个素数p，它的新 h 值显然是 p - p^2 的

如果 p 是多个素数的一次项的积

显然 h 是积性的 h( p ) = h( p1 ) * h( p2 ) * h( p3 )……

如果 p 的唯一分解可以写成一部分素数乘积 i 与 另一部分在前一部分中出现过的素数的乘积 j，也就是存在质因子的指数大于1，它新增的每一个因子的 μ 值都是0，没有意义，只有统计时D变成了原来的 j 倍

所以 此时 h( p ) = h( i ) * j

const mo=100000009;
      max=10000000;
var flag,prime:array[0..max]of longint;
    sum,f:array[0..max]of int64;
    cas,v,n,m,i,j,t:longint;

function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;

function clac(x,y:int64):int64;
begin
 x:=x*(x+1) div 2 mod mo;
 y:=y*(y+1) div 2 mod mo;
 exit(x*y mod mo);
end;

function query(n,m:longint):int64;
var i,x,y,pos,t:longint;
begin
 i:=1; query:=0;
 if n>m then begin t:=n; n:=m; m:=t; end;
 while i<=n do
 begin
  x:=n div i; y:=m div i;
  pos:=min(n div x,m div y);
  query:=query+clac(x,y)*(sum[pos]-sum[i-1]) mod mo;
  query:=(query mod mo+mo) mod mo;
  i:=pos+1;
 end;
end;

begin
 assign(input,'bzoj2693.in'); reset(input);
 assign(output,'bzoj2693.out'); rewrite(output);
 f[1]:=1;
 for i:=2 to max do
 begin
  if flag[i]=0 then
  begin
   inc(m); prime[m]:=i;
   f[i]:=(i-int64(i)*i) mod mo;
  end;
  j:=1;
  while (j<=m)and(prime[j]*i<=max) do
  begin
   t:=prime[j]*i; flag[t]:=1;
   if i mod prime[j]=0 then
   begin
    f[t]:=prime[j]*f[i] mod mo;
    break;
   end;
   f[t]:=f[prime[j]]*f[i] mod mo;
   inc(j);
  end;
 end;
 for i:=1 to max do sum[i]:=(sum[i-1]+f[i]) mod mo;
 read(cas);
 for v:=1 to cas do
 begin
  read(n,m);
  writeln(query(n,m));
 end;
 close(input);
 close(output);
end.