【BZOJ4583】购物（组合计数）

题意：商店出售3种颜色的球，分别为红、绿、蓝。

城市里有n个商店，第i个商店在第First_i天开始营业，连续营业Red_i+Green_i+Blue_i天，每个商店每天只能出售一种颜色的球。

每天最多有两个商店同时营业。如果同一天内有两个商店同时营业，那么这两个商店必须出售相同颜色的球。

求不同的出售方案数（对1,000,000,007取模）。两种方案不同，当且仅当某一天某一个商店出售的球的颜色不同。

1≤n≤50

1≤First_i≤500

0≤Red_i, Green_i, Blue_i≤100

0<Red_i + Green_i + Blue_i

First_i + Red_i + Green_i + Blue_i - 1≤500

保证每天最多有两个商店同时营业。

 

思路：WYZ作业 烦的一比 还是膜了本人的code才做出的

贴一下他的题解

我们很容易想到一个7维DP，dp[时间][店A剩余红球][店A剩余绿球][店A剩余蓝球][店B剩余红球][店B剩余绿球][店B剩余蓝球]

然后，首先我们发现，每个时刻一个店的剩余球总数是确定的，于是就可以把其中一个球的状态去掉，于是就变成5维了。

接着，我们尝试不记录其中一个店。

我们发现，如果某一段区间两个店同时开门，那么这段时间内卖掉的球一定是那个较早关门剩余的所有球。（因为较早关门的那个店一定要卖光，然后另一个店就必须跟着卖）

然后这段时间里的方案数，直接可以用组合数算出来。

于是我们就可以直接跳过有2个店开门的时间。

于是我们的DP状态就变成3维的了，空间&&时间都是500*100*100的。

O(1)转移xjb搞一搞就行了

const mo=1000000007;
var st,r,g,b:array[0..500]of longint;
    dp,f:array[0..500,0..500]of int64;
    c:array[0..500,-1..500]of int64;
    now,sum,i,j,k,n,t:longint;

procedure swap(var x,y:longint);
var t:longint;
begin
 t:=x; x:=y; y:=t;
end;

procedure qsort(l2,r2:longint);
var i,j,mid:longint;
begin
 i:=l2; j:=r2; mid:=st[(l2+r2)>>1];
 repeat
  while mid>st[i] do inc(i);
  while mid<st[j] do dec(j);
  if i<=j then
  begin
   swap(st[i],st[j]);
   swap(r[i],r[j]);
   swap(g[i],g[j]);
   swap(b[i],b[j]);
   inc(i); dec(j);
  end;
 until i>j;
 if l2<j then qsort(l2,j);
 if i<r2 then qsort(i,r2);
end;

function clac(x,y,z:longint):int64;
begin
 clac:=c[x+y+z,x]*c[y+z,y] mod mo;
end;

function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;

procedure solve(step:longint);
var i,j,k:longint;
begin
 if step=0 then exit;
 if sum=0 then
 begin
  now:=now+step;
  exit;
 end;
 fillchar(f,sizeof(f),0);
 for i:=0 to 100 do
  for j:=0 to 100 do
  begin
   k:=sum-i-j;
   if (k<0)or(k>100) then continue;
   if i>0 then f[i-1,j]:=(f[i-1,j]+dp[i,j]) mod mo;
   if j>0 then f[i,j-1]:=(f[i,j-1]+dp[i,j]) mod mo;
   if k>0 then f[i,j]:=(f[i,j]+dp[i,j]) mod mo;
  end;
 for i:=0 to 100 do
  for j:=0 to 100 do dp[i,j]:=f[i,j];
 inc(now); dec(sum);
 solve(step-1);
end;

begin
 assign(input,'bzoj4583.in'); reset(input);
 assign(output,'bzoj4583.out'); rewrite(output);
 readln(n);
 for i:=1 to n do read(st[i]);
 for i:=1 to n do read(r[i]);
 for i:=1 to n do read(g[i]);
 for i:=1 to n do read(b[i]);
 c[0,0]:=1;
 for i:=1 to 500 do
  for j:=0 to i do c[i,j]:=(c[i-1,j-1]+c[i-1,j]) mod mo;
 qsort(1,n); dp[0,0]:=1;
 for t:=1 to n do
 begin
  solve(st[t]-now);
  fillchar(f,sizeof(f),0);
  if sum<=r[t]+g[t]+b[t] then
  begin
   for i:=0 to r[t] do
    for j:=0 to g[t] do
    begin
     k:=sum-i-j;
     if (k<0)or(k>b[t]) then continue;
     f[r[t]-i,g[t]-j]:=(f[r[t]-i,g[t]-j]+dp[i,j]*clac(i,j,k)) mod mo;
    end;
  end
   else
   begin
    for i:=r[t] to 100 do
     for j:=g[t] to 100 do
     begin
      k:=sum-i-j;
      if (k<b[t])or(k>100) then continue;
      f[i-r[t],j-g[t]]:=(f[i-r[t],j-g[t]]+dp[i,j]*clac(r[t],g[t],b[t])) mod mo;
     end;
   end;
  for i:=0 to 100 do
   for j:=0 to 100 do dp[i,j]:=f[i,j];
  now:=now+min(sum,r[t]+g[t]+b[t]);
  sum:=abs(r[t]+g[t]+b[t]-sum);
 end;
 solve(500);
 writeln(dp[0,0]);
 close(input);
 close(output);
end.