【ZJOI2017 Round1练习&BZOJ4773】D3T1 cycle（最小负环，倍增）

题意：给定一个带权有向图，求点数最小的负环。

2 ⩽ n ⩽ 300
0 ⩽ m ⩽ n(n - 1)
1 ⩽ ui,vi ⩽ n
abs(w[j])<= 10^4

思路：倍增思想

设d[i,j,k]为走不多于2^i次步，从j走到k的最小权值和

显然d[i]可以由d[i-1]推出

f[i,j]表示当前走若干步后从i到j的最小权值和

从大到小枚举在原来的基础上再走不多于2^i步的结果

如果有负环就不用再走2^i步，将f复原

否则将j更新为走2^i步之后的数值，继续枚举

const oo=1000000000;
var d:array[0..9,1..300,1..300]of longint;
    g,f:array[1..300,1..300]of longint;
    n,m,i,j,k,t,ans,x,y,z:longint;
    flag:boolean;

function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;

begin
 assign(input,'cycle.in'); reset(input);
 assign(output,'cycle.out'); rewrite(output);
 readln(n,m);
 for i:=1 to n do
  for j:=1 to n do
   if i<>j then d[0,i,j]:=oo;
 for i:=1 to m do
 begin
  readln(x,y,z);
  d[0,x,y]:=min(d[0,x,y],z);
 end;
 for t:=1 to 8 do
 begin
  for i:=1 to n do
   for j:=1 to n do
    if i<>j then d[t,i,j]:=oo;
  for i:=1 to n do
   for j:=1 to n do
    for k:=1 to n do d[t,i,k]:=min(d[t,i,k],d[t-1,i,j]+d[t-1,j,k]);
 end;
 for i:=1 to n do
  for j:=1 to n do
   if i<>j then f[i,j]:=oo;
 for t:=8 downto 0 do
 begin
  for i:=1 to n do
   for j:=1 to n do g[i,j]:=f[i,j];
  for i:=1 to n do
   for j:=1 to n do
    for k:=1 to n do f[i,k]:=min(f[i,k],g[i,j]+d[t,j,k]);
  flag:=false;
  for i:=1 to n do
   if f[i,i]<0 then begin flag:=true; break; end;
  if flag then
  begin
   for i:=1 to n do
    for j:=1 to n do f[i,j]:=g[i,j];
  end
   else ans:=ans+(1<<t);
 end;
 inc(ans);
 if ans>n then writeln(0)
  else writeln(ans);

 close(input);
 close(output);
end.