【BZOJ2038】小Z的袜子（莫队）

题意：

给定n个数a1, a2…… an与m个询问(L,R)。对于每个询问，从aL, aL+1…… aR这R-L+1个数中随机取出两个数，求这两个数相同的概率。

数据范围：1<=n,m,ai<=50000

思路：

以下是原话：

平方运算的存在是线段树无法打破的坚冰！

只有询问，没有修改！ 可以任意的顺序求解询问！

 考虑两个位置关系任意的区间[L1,R1]与[L2,R2]

已有前者的信息，要得到后者的信息只需插入或删除L1与L2间的数和R1与R2间的数

若L1<L2则删除[L1,L2-1]内的数， 否则插入[L2,L1-1]内的数；

若R1<R2则插入[R1+1,R2]内的数， 否则删除[R2+1,R1]内的数；

无论何种情况，所需操作数均为 |L1 - L2| + |R1 - R2|

将m个区间重新排列，最小化：

 

定义(L0,R0) = (1,0)

分块，将询问以左端点所在块的编号为第一关键字，右端点大小为第二关键字排序，依次计算保证

时间复杂度O(N^1.5)

复杂度分析是这样的：
1、i与i+1在同一块内，r单调递增，所以r是O(n)的。由于有n^0.5块,所以这一部分时间复杂度是n^1.5。
2、i与i+1跨越一块，r最多变化n，由于有n^0.5块，所以这一部分时间复杂度是n^1.5
3、i与i+1在同一块内时l变化不超过n^0.5，跨越一块也不会超过n^0.5，忽略*2。由于有m次询问（和n同级），所以时间复杂度是n^1.5
于是就是O(n^1.5)了

type arr=record
          l,r,c,t:longint;
         end;
var s:array[0..50000]of int64;
    ans:array[1..50000,1..2]of int64;
    q:array[1..50000]of arr;
    c,a:array[1..50000]of longint;
    n,m,i,kuai:longint;
    tmp:int64;

procedure swap(var x,y:arr);
var t:arr;
begin
 t:=x; x:=y; y:=t;
end;

procedure qsort(l,r:longint);
var i,j,mid1,mid2:longint;
begin
 i:=l; j:=r; mid1:=q[(l+r)>>1].c; mid2:=q[(l+r)>>1].r;
 repeat
  while (mid1>q[i].c)or((mid1=q[i].c)and(mid2>q[i].r)) do inc(i);
  while (mid1<q[j].c)or((mid1=q[j].c)and(mid2<q[j].r)) do dec(j);
  if i<=j then
  begin
   swap(q[i],q[j]);
   inc(i); dec(j);
  end;
 until i>j;
 if l<j then qsort(l,j);
 if i<r then qsort(i,r);
end;

function gcd(x,y:int64):int64;
var r,t:int64;
begin
 if x<y then
 begin
  t:=x; x:=y; y:=t;
 end;
 repeat
  r:=x mod y;
  x:=y;
  y:=r;
 until r=0;
 exit(x);
end;

procedure add(x,y:longint);
begin
 tmp:=tmp-s[a[x]]*s[a[x]];
 s[a[x]]:=s[a[x]]+y;
 tmp:=tmp+s[a[x]]*s[a[x]];
end;

procedure modui;
var a,b,c,d,k1,k2,k:int64;
    i,j:longint;
begin
 a:=1; b:=0; tmp:=0;
 for i:=1 to m do
 begin
  c:=q[i].l; d:=q[i].r;
  for j:=b+1 to d do add(j,1);
  for j:=c to a-1 do add(j,1);
  for j:=a to c-1 do add(j,-1);
  for j:=d+1 to b do add(j,-1);
  a:=c; b:=d;
  if c=d then
  begin
   ans[i,1]:=0; ans[i,2]:=1;
   continue;
  end;
  k1:=tmp-(d-c+1);
  if k1=0 then
  begin
   ans[i,1]:=0; ans[i,2]:=1;
   continue;
  end;
  k2:=(d-c+1)*(d-c);
  k:=gcd(k1,k2);
  ans[i,1]:=k1 div k;
  ans[i,2]:=k2 div k;
 end;

end;

procedure qsort1(l,r:longint);
var i,j,mid:longint;
    t:int64;
begin
 i:=l; j:=r; mid:=q[(l+r)>>1].t;
 repeat
  while mid>q[i].t do inc(i);
  while mid<q[j].t do dec(j);
  if i<=j then
  begin
   swap(q[i],q[j]);
   t:=ans[i,1]; ans[i,1]:=ans[j,1]; ans[j,1]:=t;
   t:=ans[i,2]; ans[i,2]:=ans[j,2]; ans[j,2]:=t;
   inc(i); dec(j);
  end;
 until i>j;
 if l<j then qsort1(l,j);
 if i<r then qsort1(i,r);
end;

begin
 assign(input,'bzoj2038.in'); reset(input);
 assign(output,'bzoj2038.out'); rewrite(output);
 readln(n,m);
 for i:=1 to n do read(a[i]);
 kuai:=trunc(sqrt(n));
 for i:=1 to n do c[i]:=(i-1) div kuai+1;
 for i:=1 to m do
 begin
  readln(q[i].l,q[i].r);
  q[i].c:=c[q[i].l];
  q[i].t:=i;
 end;
 qsort(1,m);
 modui;
 qsort1(1,m);
 for i:=1 to m do writeln(ans[i,1],'/',ans[i,2]);
 close(input);
 close(output);
end.