【BZOJ3932】任务查询系统（主席树）

题意：若干有优先级的任务会持续一段时间，给出所有任务，询问每个时刻前k小优先级任务的优先级总和，询问强制在线。

对于100%的数据，1≤m,n,Si,Ei,Ci≤100000，0≤Ai,Bi≤100000，1≤Pi≤10000000，Xi为1到n的一个排列

思路：不用离散化，主席树继承并保存每个时刻的个数和与权值和，对于任务差分后插入，询问时二分即可

注意个数不够时特判一波（我是这么干的） 

询问中l=r时小心处理

var t:array[0..8100000,0..1]of longint;
    sum1:array[0..8100000]of longint;
    sum2:array[0..8100000]of int64;
    a,b,c:array[1..210000]of longint;
    root:array[0..210000]of longint;
    m1,n1,i,j,cnt,k,n,st,ed,x,y,z,a1,b1,c1:longint;
    ans:int64;

procedure swap(var x,y:longint);
var t:longint;
begin
 t:=x; x:=y; y:=t;
end;

function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;

function max(x,y:longint):longint;
begin
 if x>y then exit(x);
 exit(y);
end;

procedure qsort(l,r:longint);
var i,j,mid:longint;
begin
 i:=l; j:=r; mid:=a[(l+r)>>1];
 repeat
  while mid>a[i] do inc(i);
  while mid<a[j] do dec(j);
  if i<=j then
  begin
   swap(a[i],a[j]); swap(b[i],b[j]); swap(c[i],c[j]);
   inc(i); dec(j);
  end;
 until i>j;
 if l<j then qsort(l,j);
 if i<r then qsort(i,r);
end;

procedure update(l,r,x,v:longint;var p:longint);
var mid:longint;
    tmp:int64;
begin
 inc(cnt); t[cnt]:=t[p]; sum1[cnt]:=sum1[p]; sum2[cnt]:=sum2[p];
 p:=cnt;
 sum1[p]:=sum1[p]+v;
 tmp:=x; tmp:=tmp*v;
 sum2[p]:=sum2[p]+tmp;
 if l=r then exit;
 mid:=(l+r)>>1;
 if x<=mid then update(l,mid,x,v,t[p,0])
  else update(mid+1,r,x,v,t[p,1]);
end;


function query(l,r,x,p:longint):int64;
var mid,tmp:longint;
begin
 if x=0 then exit(0);
 if l=r then
 begin
  query:=l; query:=query*x;
  exit;
 end;
 if sum1[p]<=x then exit(sum2[p]);
 tmp:=sum1[t[p,0]];
 mid:=(l+r)>>1;
 if tmp>=x then exit(query(l,mid,x,t[p,0]))
  else exit(sum2[t[p,0]]+query(mid+1,r,x-tmp,t[p,1]));
end;

begin
 assign(input,'bzoj3932.in'); reset(input);
 assign(output,'bzoj3932.out'); rewrite(output);
 readln(m1,n1);
 st:=maxlongint; ed:=-maxlongint;
 for i:=1 to m1 do
 begin
  readln(x,y,z);
  ed:=max(ed,z);
  inc(n); a[n]:=x; b[n]:=z; c[n]:=1;
  if y+1<=n1 then
  begin
   inc(n); a[n]:=y+1; b[n]:=z; c[n]:=-1;
  end;
 // st:=min(st,x); ed:=max(ed,y);
 end;
 qsort(1,n); j:=1;
 for i:=1 to n1 do
 begin
  root[i]:=root[i-1];
  while (j<=n)and(a[j]=i) do
  begin
   update(1,ed,b[j],c[j],root[i]);
   inc(j);
  end;
 end;
 ans:=1;
 for i:=1 to n1 do
 begin
  readln(x,a1,b1,c1);
  k:=1+(ans*a1+b1) mod c1;
  ans:=query(1,ed,k,root[x]);
  writeln(ans);
 end;
 close(input);
 close(output);
end.