【BZOJ3939】Cow Hopscotch（动态开点线段树）

题意：

就像人类喜欢跳格子游戏一样，FJ的奶牛们发明了一种新的跳格子游戏。虽然这种接近一吨的笨拙的动物玩跳格子游戏几乎总是不愉快地结束，但是这并没有阻止奶牛们在每天下午参加跳格子游戏 

游戏在一个R*C的网格上进行，每个格子有一个取值在1-k之间的整数标号，奶牛开始在左上角的格子，目的是通过若干次跳跃后到达右下角的格子，当且仅当格子A和格子B满足如下条件时能从格子A跳到格子B： 

1.B格子在A格子的严格右方(B的列号严格大于A的列号) 

2.B格子在A格子的严格下方(B的行号严格大于A的行号) 

3.B格子的标号和A格子的标号不同 

请你帮助奶牛计算出从左上角的格子到右下角的格子一共有多少种不同的方案

n,m<=750,k<=n*m

 

思路：这题是金组的数据范围

在铜组因为数据小 裸的dp可做 金组需要优化

 \[ dp[i,j]= \sum_{x=1}^{i-1}  \sum_{y=1}^{j-1}  dp[x,y]         (a[i,j]<>a[x,y]) \] 

转化为左上角的所有方案-该颜色的所有方案

因为只要求保存一个版本

可以用一棵动态开点的线段树解决

修改时使用类似于主席树的方法

const mo=1000000007;
var t:array[0..7000000]of record
                           l,r,s:longint;
                          end;

    sum,a,dp:array[0..800,0..800]of longint;
    root:array[0..1000000]of longint;
    f:array[0..800]of longint;
    n,m,i,j,s1,s2,cnt,k:longint;

procedure pushup(x:longint);
var l,r:longint;
begin
 l:=t[x].l; r:=t[x].r;
 t[x].s:=(t[l].s+t[r].s) mod mo;
end;

procedure update(var p:longint;l,r,x,v:longint);
var mid:longint;
begin
 if p=0 then
 begin
  inc(cnt); p:=cnt;
 end;
 if l=r then
 begin
  t[p].s:=(t[p].s+v) mod mo; exit;
 end;
 mid:=(l+r)>>1;
 if x<=mid then update(t[p].l,l,mid,x,v)
  else update(t[p].r,mid+1,r,x,v);
 pushup(p);
end;

function query(p,l,r,x,y:longint):longint;
var mid:longint;
begin

 if (p=0)or(x>y) then exit(0);
 if (x<=l)and(y>=r) then exit(t[p].s);
 mid:=(l+r)>>1;
 query:=0;
 if x<=mid then query:=(query+query(t[p].l,l,mid,x,y)) mod mo;
 if y>mid then query:=(query+query(t[p].r,mid+1,r,x,y)) mod mo;
end;


begin
// assign(input,'bzoj3939.in'); reset(input);
// assign(output,'bzoj3939.out'); rewrite(output);
 readln(n,m,k);
 for i:=1 to n do
  for j:=1 to m do read(a[i,j]);

 dp[1,1]:=1;
 for i:=1 to m do sum[1,i]:=1;
 update(root[a[1,1]],1,m,1,1);

 for i:=2 to n do
 begin
  for j:=m downto 1 do
  begin
   s1:=sum[i-1,j-1];
   s2:=query(root[a[i,j]],1,m,1,j-1);
   dp[i,j]:=((s1-s2) mod mo+mo) mod mo;
   update(root[a[i,j]],1,m,j,dp[i,j]);
  end;
  for j:=1 to m do
  begin
   f[j]:=(f[j-1]+dp[i,j]) mod mo;
   sum[i,j]:=(sum[i-1,j]+f[j]) mod mo;
  end;
 end;
  writeln(dp[n,m]);
 {for i:=1 to n do
 begin
  for j:=1 to m do write(dp[i,j],' ');
  writeln;
 end; }


 close(input);
 close(output);
end.