【POJ1743】Musical Theme（后缀数组，二分）

题意：求一个字符串的不重叠最长相同变化的子串

n<=20000

思路：这是一道论文题

我们将原串两两之间作差，可以发现所求的相同变化的子串作出的差相同

问题就转化成了不重叠的最长重复子串

显然答案有二分性，二分答案，将问题转化为是否存在长度为k的相同子串

将后缀分成连续的若干组，每组相邻的height都不小于k

有希望满足条件的两个后缀一定在同一组

只要判断某组中的sa最大与最小值之差是否不小于k即可

有一组满足则k满足

var a,b,wc,wd,x,y,height,sa,rank:array[0..100000]of longint;
    n,i,l,r,mid,last,m:longint;

function cmp(a,b,l:longint):boolean;
begin
 exit((y[a]=y[b])and(y[a+l]=y[b+l]));
end;

procedure swap(var x,y:longint);
var t:longint;
begin
 t:=x; x:=y; y:=t;
end;

procedure getsa(n:longint);
var i,j,p:longint;
begin
 for i:=0 to n-1 do
 begin
  x[i]:=a[i];
  inc(wc[a[i]]);
 end;
 for i:=1 to m do wc[i]:=wc[i-1]+wc[i];
 for i:=n-1 downto 0 do
 begin
  dec(wc[x[i]]);
  sa[wc[x[i]]]:=i;
 end;
 j:=1; p:=1;
 while p<n do
 begin
  p:=0;
  for i:=n-j to n-1 do
  begin
   y[p]:=i; inc(p);
  end;
  for i:=0 to n-1 do
   if sa[i]>=j then begin y[p]:=sa[i]-j; inc(p); end;
  for i:=0 to n-1 do wd[i]:=x[y[i]];
  for i:=0 to m do wc[i]:=0;
  for i:=0 to n-1 do inc(wc[wd[i]]);
  for i:=1 to m do wc[i]:=wc[i-1]+wc[i];
  for i:=n-1 downto 0 do
  begin
   dec(wc[wd[i]]);
   sa[wc[wd[i]]]:=y[i];
  end;
  for i:=0 to n do swap(x[i],y[i]);
  p:=1; x[sa[0]]:=0;
  for i:=1 to n-1 do
  begin
   if cmp(sa[i-1],sa[i],j) then x[sa[i]]:=p-1
    else begin x[sa[i]]:=p; inc(p); end;
  end;
  j:=j*2;
  m:=p;
 end;
end;

procedure getheight(n:longint);
var i,j,k:longint;
begin
 k:=0;
 for i:=1 to n do rank[sa[i]]:=i;
 for i:=0 to n-1 do
 begin
  if k>0 then dec(k);
  j:=sa[rank[i]-1];
  while a[i+k]=a[j+k] do inc(k);
  height[rank[i]]:=k;
 end;
end;

function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;

function max(x,y:longint):longint;
begin
 if x>y then exit(x);
 exit(y);
end;

function isok(x:longint):boolean;
var l,r,i:longint;
begin
 l:=sa[0]; r:=sa[0];
 for i:=1 to n-1 do
  if height[i]<x then
  begin
   l:=sa[i]; r:=sa[i];
  end
   else
   begin
    l:=min(l,sa[i]);
    r:=max(r,sa[i]);
    if r-l>=x then exit(true);
   end;
 exit(false);
end;

begin
 assign(input,'poj1743.in'); reset(input);
 assign(output,'poj1743.out'); rewrite(output);
 while not eof do
 begin
  fillchar(a,sizeof(a),0);
  fillchar(b,sizeof(b),0);
  fillchar(sa,sizeof(sa),0);
  fillchar(rank,sizeof(rank),0);
  fillchar(x,sizeof(x),0);
  fillchar(y,sizeof(y),0);
  fillchar(height,sizeof(height),0);
  fillchar(wc,sizeof(wc),0);
  fillchar(wd,sizeof(wd),0);
  readln(n);
  if n=0 then break;
  for i:=0 to n-1 do read(b[i]);
  dec(n);
  for i:=0 to n-1 do a[i]:=b[i+1]-b[i]+100;
  a[n]:=0; m:=300;
  getsa(n+1);
  getheight(n);
  l:=4; r:=(n-1) div 2; last:=0;
  while l<=r do
  begin
   mid:=(l+r)>>1;
   if isok(mid) then begin last:=mid; l:=mid+1; end
    else r:=mid-1;
  end;
  if last<4 then writeln(0)
   else writeln(last+1);
 // for i:=1 to n do write(sa[i]+1,' ');
 // writeln;
 // for i:=0 to n do writeln(height[i]);

 end;

 close(input);
 close(output);
end.