【BZOJ3991】寻宝游戏（虚树，DFS序，splay）

题意：求在树中从任意点开始，经过若干个关键点回到原点的最小距离

要求支持在线将某个点设置（取消）为关键点，以及询问答案

n,m<=100000 len[i]<=10^9

思路：显然是一个虚树的模型，但并不需要虚树

其实就是求虚树的所有路径长度之和的2倍

思考后可以发现，必定是按DFS序从小到大走，再从最大点回到最小点总路程最短

所以只需要维护DFS序的插入，删除，前驱，后继，最大，最小，splay即可

插入点i时找到与它DFS序相邻的点x和y，对答案有dis(x,i)+dis(y,i)-dis(x,y)的贡献

最后加上首尾长度

var t:array[0..500000,0..1]of longint;
    f:array[1..110000,0..17]of longint;
    fa,rev,size:array[0..500000]of longint;
    flag,dfn,id,dep,head,vet,next,len,b:array[1..500000]of longint;
    dis,num:array[0..500000]of int64;
    n,m,i,x,y,tot,root,cnt,time,z:longint;
    ans,v,tmp,oo,l,r:int64;

procedure swap(var x,y:longint);
var t:longint;
begin
 t:=x; x:=y; y:=t;
end;

procedure pushup(x:longint);
var l,r:longint;
begin
 l:=t[x,0]; r:=t[x,1];
 size[x]:=size[l]+size[r]+1;
end;

procedure rotate(x:longint;var k:longint);
var y,z,l,r:longint;
begin
 y:=fa[x]; z:=fa[y];
 if t[y,0]=x then l:=0
  else l:=1;
 r:=l xor 1;
 if y<>k then
 begin
  if t[z,0]=y then t[z,0]:=x
   else t[z,1]:=x;
 end
  else k:=x;
 fa[x]:=z; fa[y]:=x; fa[t[x,r]]:=y;
 t[y,l]:=t[x,r]; t[x,r]:=y;
 pushup(y);
 pushup(x);
end;

procedure splay(x:longint;var k:longint);
var y,z:longint;
begin
 while x<>k do
 begin
  y:=fa[x]; z:=fa[y];
  if y<>k then
  begin
   if (t[y,0]=x)xor(t[z,0]=y) then rotate(x,k)
    else rotate(y,k);
  end
   else k:=x;
  rotate(x,k);
 end;
end;

function kth(x:longint):longint;
var k,tmp:longint;
begin
 k:=root;
 while k<>0 do
 begin
  tmp:=size[t[k,0]]+1;
  if tmp=x then exit(k)
   else if tmp>x then k:=t[k,0]
    else
    begin
     k:=t[k,1]; x:=x-tmp;
    end;
 end;
end;

function pred(x:int64):int64;
var k:longint;
    last:int64;
begin
 k:=root; last:=-oo;
 while k<>0 do
 begin
  if num[k]<x then begin last:=num[k]; k:=t[k,1]; end
   else k:=t[k,0];
 end;
 exit(last);
end;

function succ(x:int64):int64;
var k:longint;
    last:int64;
begin
 k:=root; last:=oo;
 while k<>0 do
 begin
  if num[k]>x then begin last:=num[k]; k:=t[k,0]; end
   else k:=t[k,1];
 end;
 exit(last);
end;

function rank(x:int64):longint;
var k:longint;
begin
 rank:=1; k:=root;
 while k<>0 do
 begin
  if num[k]<x then begin rank:=rank+size[t[k,0]]+1; k:=t[k,1]; end
   else k:=t[k,0];
 end;
end;

procedure ins(x:int64);
var k,k1,k2:longint;
begin
 k:=rank(x);
 k1:=kth(k-1);
 k2:=kth(k);
 splay(k1,root);
 splay(k2,t[root,1]);
 k:=t[root,1];
 inc(cnt); t[k,0]:=cnt; fa[cnt]:=k; size[cnt]:=1; num[cnt]:=x;
 inc(tot);
end;

procedure del(x:int64);
var k,k1,k2:longint;
begin
 k:=rank(x);
 k1:=kth(k-1);
 k2:=kth(k+1);
 splay(k1,root);
 splay(k2,t[root,1]);
 k1:=t[root,1]; k2:=t[k1,0];
 t[k1,0]:=0; size[k1]:=size[t[k1,1]]+1;
 fa[k2]:=0; t[k2,0]:=0; t[k2,1]:=0; size[k2]:=0; num[k2]:=0;
 dec(tot);
end;

function lca(x,y:longint):longint;
var i,d:longint;
begin
 if dep[x]<dep[y] then swap(x,y);
 d:=dep[x]-dep[y];
 for i:=0 to 17 do
  if d and (1<<i)>0 then x:=f[x,i];
 for i:=17 downto 0 do
  if f[x,i]<>f[y,i] then
  begin
   x:=f[x,i]; y:=f[y,i];
  end;
 if x=y then exit(x);
 exit(f[x,0]);
end;

function query(x,y:longint):int64;
var q:longint;
begin
 q:=lca(x,y);
 exit(dis[x]+dis[y]-2*dis[q]);
end;

procedure add(a,b,c:longint);
begin
 inc(tot);
 next[tot]:=head[a];
 vet[tot]:=b;
 len[tot]:=c;
 head[a]:=tot;
end;

procedure dfs(u:longint);
var i,e,v:longint;
begin
 flag[u]:=1;
 inc(time); dfn[u]:=time; id[time]:=u;
 for i:=1 to 17 do
 begin
  if dep[u]<1<<i then break;
  f[u,i]:=f[f[u,i-1],i-1];
 end;
 e:=head[u];
 while e<>0 do
 begin
  v:=vet[e];
  if flag[v]=0 then
  begin
   dep[v]:=dep[u]+1;
   dis[v]:=dis[u]+len[e];
   f[v,0]:=u;
   dfs(v);
  end;
  e:=next[e];
 end;
end;

begin
 assign(input,'bzoj3991.in'); reset(input);
 assign(output,'bzoj3991.out'); rewrite(output);
 readln(n,m);
 for i:=1 to n-1 do
 begin
  readln(x,y,z);
  add(x,y,z);
  add(y,x,z);
 end;
 dfs(1);
 oo:=1<<60;
 num[1]:=oo; t[1,0]:=2; size[1]:=2;
 num[2]:=-oo; fa[2]:=1; size[2]:=1;
 root:=1; cnt:=2; tot:=2;
 for i:=1 to m do
 begin
  readln(x);
  if b[x]=0 then begin v:=1; ins(dfn[x]); end
   else begin v:=-1; del(dfn[x]); end;
  b[x]:=b[x] xor 1;
  l:=pred(dfn[x]);
  r:=succ(dfn[x]);
  if l<>-oo then ans:=ans+v*query(id[l],x);
  if r<>oo then ans:=ans+v*query(id[r],x);
  if (l<>-oo)and(r<>oo) then ans:=ans-v*query(id[l],id[r]);
  tmp:=0;
  if tot>3 then
  begin
   l:=kth(2);
   r:=kth(tot-1);
   tmp:=query(id[num[l]],id[num[r]]);
  end;
  writeln(ans+tmp);
 end;
 close(input);
 close(output);
end.