【BZOJ2653】middle（主席树，二分）

题意：一个长度为n的序列a，设其排过序之后为b，其中位数定义为b[n/2]，其中a,b从0开始标号,除法取下整。
　　给你一个长度为n的序列s。
　　回答Q个这样的询问：s的左端点在[a,b]之间,右端点在[c,d]之间的子序列中，最大的中位数。
　　其中a<b<c<d。
　　位置也从0开始标号。
　　我会使用一些方式强制你在线。

n<=20000,Q<=25000

思路:RYZ上课讲的题，第一次做这种类型的主席树，以前只会序列第K大，树上第K大，维护二维前缀和之类的……

这道题的精髓是用主席树保存每个点被更改后的N个版本

对于一段区间与一个数X，如果区间中的数a[i]>=x则b[i]=1，否则-1

易得：若某一段中b[i]总和>=0则必定可以从其中取出一段中位数为X的序列，则X可以作为答案

反之显然答案具有单调性，子段和最大的一段一定可以构造出最大的中位数

查询时判断queryr(a,b)+querysum(b+1,c-1)+queryl(c,d)是否>=0即可

剩下的二分X与最大子段和，最大左右子段和维护部分已经在各种各样的地方（NOI Plus模拟赛）做了不下10遍了

而且还有各种写法不同难度的，比如暴力，RMQ之类的

这题就是单点修改+线段树版本的

强制从0开始标号P党表示不爽

var t:array[0..8100000,0..1]of longint;
    root,lx,rx,sum:array[0..8100000]of longint;
    a,b,d:array[1..30000]of longint;
    n,que,i,j,cnt,l,r,last,lastans,mid:longint;

function max(x,y:longint):longint;
begin
 if x>y then exit(x);
 exit(y);
end;

procedure swap(var x,y:longint);
var t:longint;
begin
 t:=x; x:=y; y:=t;
end;

procedure qsort(l,r:longint);
var i,j,mid:longint;
begin
 i:=l; j:=r; mid:=a[(l+r)>>1];
 repeat
  while mid>a[i] do inc(i);
  while mid<a[j] do dec(j);
  if i<=j then
  begin
   swap(a[i],a[j]);
   swap(b[i],b[j]);
   inc(i); dec(j);
  end;
 until i>j;
 if l<j then qsort(l,j);
 if i<r then qsort(i,r);
end;

procedure sort;
var i,j:longint;
begin
 for i:=1 to 3 do
  for j:=1 to 4-i do
   if d[j]>d[j+1] then swap(d[j],d[j+1]);
end;

procedure pushup(p:longint);
var l,r:longint;
begin
 l:=t[p,0]; r:=t[p,1];
 lx[p]:=max(lx[l],sum[l]+lx[r]);
 rx[p]:=max(rx[r],sum[r]+rx[l]);
 sum[p]:=sum[l]+sum[r];
end;

procedure build(var p:longint;l,r:longint);
var mid:longint;
begin
 inc(cnt); p:=cnt;
 if l=r then
 begin
  lx[p]:=1; rx[p]:=1; sum[p]:=1;
  exit;
 end;
 mid:=(l+r)>>1;
 build(t[p,0],l,mid);
 build(t[p,1],mid+1,r);
 pushup(p);
end;

procedure update(l,r:longint;var p:longint;v,x:longint);
var mid:longint;
begin
 inc(cnt); t[cnt]:=t[p]; lx[cnt]:=lx[p]; rx[cnt]:=rx[p]; sum[cnt]:=sum[p];
 p:=cnt;
 if l=r then
 begin
  sum[p]:=x; lx[p]:=x; rx[p]:=x;
  exit;
 end;
 mid:=(l+r)>>1;
 if v<=mid then update(l,mid,t[p,0],v,x)
  else update(mid+1,r,t[p,1],v,x);
 pushup(p);
end;

function querysum(l,r,x,y,p:longint):longint;
var mid,s:longint;
begin
 if (l=x)and(r=y) then exit(sum[p]);
 mid:=(l+r)>>1;
 s:=0;
 if y<=mid then s:=querysum(l,mid,x,y,t[p,0])
  else if x>mid then s:=querysum(mid+1,r,x,y,t[p,1])
   else s:=querysum(l,mid,x,mid,t[p,0])+
           querysum(mid+1,r,mid+1,y,t[p,1]);
 exit(s);
end;

function queryleft(l,r,x,y,p:longint):longint;
var mid,s:longint;
begin
 if (l=x)and(r=y) then exit(lx[p]);
 mid:=(l+r)>>1;
 s:=0;
 if y<=mid then s:=queryleft(l,mid,x,y,t[p,0])
  else if x>mid then s:=queryleft(mid+1,r,x,y,t[p,1])
   else s:=max(queryleft(l,mid,x,mid,t[p,0]),
               querysum(l,mid,x,mid,t[p,0])+
               queryleft(mid+1,r,mid+1,y,t[p,1]));
 exit(s);
end;

function queryright(l,r,x,y,p:longint):longint;
var mid,s:longint;
begin
 if (l=x)and(r=y) then exit(rx[p]);
 mid:=(l+r)>>1;
 s:=0;
 if y<=mid then s:=queryright(l,mid,x,y,t[p,0])
  else if x>mid then s:=queryright(mid+1,r,x,y,t[p,1])
   else s:=max(queryright(mid+1,r,mid+1,y,t[p,1]),
               querysum(mid+1,r,mid+1,y,t[p,1])+
               queryright(l,mid,x,mid,t[p,0]));
 exit(s);
end;

function isok(k,a,b,c,d:longint):boolean;
var s:longint;
begin
 s:=0;
 if b+1<=c-1 then s:=querysum(0,n-1,b+1,c-1,root[k]);
 s:=s+queryright(0,n-1,a,b,root[k]);
 s:=s+queryleft(0,n-1,c,d,root[k]);
 exit(s>=0);
end;

begin

 read(n);
 for i:=1 to n do
 begin
  read(a[i]); b[i]:=i;
 end;
 qsort(1,n);

 build(root[0],0,n-1);
 for i:=1 to n do
 begin
  root[i]:=root[i-1];
  update(0,n-1,root[i],b[i]-1,-1);
 end;
 read(que);
 for i:=1 to que do
 begin
  for j:=1 to 4 do read(d[j]);
  for j:=1 to 4 do d[j]:=(d[j]+lastans) mod n;
  sort;
  l:=0; r:=n; last:=0;
  while l<=r do
  begin
   mid:=(l+r)>>1;
   if isok(mid,d[1],d[2],d[3],d[4]) then begin last:=mid; l:=mid+1; end
    else r:=mid-1;
  end;
  lastans:=a[last+1];
  writeln(lastans);
 end;

end.